master
1#***************************************************************************
2# _ _ ____ _
3# Project ___| | | | _ \| |
4# / __| | | | |_) | |
5# | (__| |_| | _ <| |___
6# \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
13#
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
17#
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
20#
21# SPDX-License-Identifier: curl
22#
23###########################################################################
25set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS "${CURL_DEBUG_MACROS}")
27set(_curl_cfiles_gen "")
28set(_curl_hfiles_gen "")
29set(_curl_definitions "")
31if(ENABLE_CURL_MANUAL AND (Perl_FOUND OR EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/tool_hugehelp.c"))
32 if(Perl_FOUND)
33 add_custom_command(OUTPUT "tool_hugehelp.c"
34 COMMAND ${CMAKE_COMMAND} -E echo "#include \"tool_setup.h\"" > "tool_hugehelp.c"
35 COMMAND ${CMAKE_COMMAND} -E echo "/* !checksrc! disable COPYRIGHT all */" >> "tool_hugehelp.c"
36 COMMAND ${CMAKE_COMMAND} -E echo "/* !checksrc! disable INCLUDEDUP all */" >> "tool_hugehelp.c"
37 COMMAND ${CMAKE_COMMAND} -E echo "/* !checksrc! disable LONGLINE all */" >> "tool_hugehelp.c"
38 COMMAND ${CMAKE_COMMAND} -E echo "#ifndef HAVE_LIBZ" >> "tool_hugehelp.c"
39 COMMAND "${PERL_EXECUTABLE}" "${CMAKE_CURRENT_SOURCE_DIR}/mkhelp.pl" < "${CURL_ASCIIPAGE}" >> "tool_hugehelp.c"
40 COMMAND ${CMAKE_COMMAND} -E echo "#else" >> "tool_hugehelp.c"
41 COMMAND "${PERL_EXECUTABLE}" "${CMAKE_CURRENT_SOURCE_DIR}/mkhelp.pl" -c < "${CURL_ASCIIPAGE}" >> "tool_hugehelp.c"
42 COMMAND ${CMAKE_COMMAND} -E echo "#endif /* HAVE_LIBZ */" >> "tool_hugehelp.c"
43 DEPENDS
44 generate-curl.1
45 "${CMAKE_CURRENT_SOURCE_DIR}/mkhelp.pl"
46 "${CMAKE_CURRENT_SOURCE_DIR}/tool_hugehelp.h"
47 "${CURL_ASCIIPAGE}"
48 VERBATIM)
49 else()
50 message(STATUS "Perl not found. Using the pre-built tool_hugehelp.c found in the source tree.")
51 endif()
52 list(APPEND _curl_cfiles_gen "tool_hugehelp.c")
53 list(APPEND _curl_hfiles_gen "tool_hugehelp.h")
54 list(APPEND _curl_definitions "USE_MANUAL")
55endif()
57if(CURL_CA_EMBED_SET)
58 if(Perl_FOUND)
59 add_custom_command(OUTPUT "tool_ca_embed.c"
60 COMMAND "${PERL_EXECUTABLE}" "${CMAKE_CURRENT_SOURCE_DIR}/mk-file-embed.pl" --var curl_ca_embed
61 < "${CURL_CA_EMBED}" > "tool_ca_embed.c"
62 DEPENDS
63 "${CMAKE_CURRENT_SOURCE_DIR}/mk-file-embed.pl"
64 "${CURL_CA_EMBED}"
65 VERBATIM)
66 list(APPEND _curl_cfiles_gen "tool_ca_embed.c")
67 list(APPEND _curl_definitions "CURL_CA_EMBED")
68 else()
69 message(WARNING "Perl not found. Cannot embed the CA bundle.")
70 endif()
71endif()
73# Get CURL_CFILES, CURL_HFILES, CURLX_CFILES, CURLX_HFILES, CURL_RCFILES variables
74curl_transform_makefile_inc("Makefile.inc" "${CMAKE_CURRENT_BINARY_DIR}/Makefile.inc.cmake")
75include("${CMAKE_CURRENT_BINARY_DIR}/Makefile.inc.cmake")
77source_group("curl source files" FILES ${CURL_CFILES} ${_curl_cfiles_gen})
78source_group("curl header files" FILES ${CURL_HFILES} ${_curl_hfiles_gen})
79source_group("curlx source files" FILES ${CURLX_CFILES})
80source_group("curlx header files" FILES ${CURLX_HFILES})
82set(_curlx_cfiles_lib ${CURLX_CFILES})
83set(_curlx_hfiles_lib ${CURLX_HFILES})
84if(LIB_SELECTED STREQUAL LIB_STATIC)
85 set(_curlx_cfiles_lib "")
86 set(_curlx_hfiles_lib "")
87endif()
89if(BUILD_STATIC_CURL)
90 set(CURLX_CFILES "")
91 set(CURLX_HFILES "")
92endif()
94set_property(DIRECTORY APPEND PROPERTY INCLUDE_DIRECTORIES
95 "${PROJECT_BINARY_DIR}/lib" # for "curl_config.h"
96 "${PROJECT_SOURCE_DIR}/lib" # for "curl_setup.h", curlx
97 "${CMAKE_CURRENT_SOURCE_DIR}" # for "tool_hugehelp.c"
98)
100# Build curl executable
101add_executable(${EXE_NAME} ${CURL_CFILES} ${CURL_HFILES} ${_curl_cfiles_gen} ${_curl_hfiles_gen} ${CURLX_CFILES} ${CURLX_HFILES})
102target_compile_definitions(${EXE_NAME} PRIVATE ${_curl_definitions})
103target_link_libraries(${EXE_NAME} ${LIB_SELECTED_FOR_EXE} ${CURL_LIBS})
104set_property(TARGET ${EXE_NAME} APPEND PROPERTY COMPILE_OPTIONS "${CURL_CFLAGS}")
105if(WIN32)
106 set_property(TARGET ${EXE_NAME} APPEND PROPERTY SOURCES ${CURL_RCFILES})
107endif()
109add_executable(${PROJECT_NAME}::${EXE_NAME} ALIAS ${EXE_NAME})
111add_executable(curlinfo EXCLUDE_FROM_ALL "curlinfo.c")
112target_link_libraries(curlinfo PRIVATE ${CURL_LIBS})
113set_target_properties(curlinfo PROPERTIES UNITY_BUILD OFF)
115# special libcurltool library for unittests
116add_library(curltool STATIC EXCLUDE_FROM_ALL ${CURL_CFILES} ${CURL_HFILES} ${_curlx_cfiles_lib} ${_curlx_hfiles_lib})
117target_compile_definitions(curltool PUBLIC "CURL_STATICLIB" "UNITTESTS")
118target_link_libraries(curltool PUBLIC ${CURL_LIBS})
119set_target_properties(curltool PROPERTIES UNITY_BUILD ON C_CLANG_TIDY "")
121if(CURL_HAS_LTO)
122 set_target_properties(${EXE_NAME} PROPERTIES INTERPROCEDURAL_OPTIMIZATION TRUE)
123endif()
124if(CURL_CLANG_TIDY)
125 set_target_properties(${EXE_NAME} PROPERTIES UNITY_BUILD OFF)
126endif()
127if(CURL_ANALYZER_CFLAGS)
128 set_target_properties(${EXE_NAME} PROPERTIES UNITY_BUILD OFF)
129 set_property(TARGET ${EXE_NAME} APPEND PROPERTY COMPILE_OPTIONS ${CURL_ANALYZER_CFLAGS})
130endif()
132if(ENABLE_UNICODE AND MINGW)
133 set_property(TARGET ${EXE_NAME} APPEND PROPERTY LINK_OPTIONS "-municode")
134endif()
136if(CURL_CODE_COVERAGE)
137 set_property(TARGET ${EXE_NAME} APPEND PROPERTY COMPILE_DEFINITIONS ${CURL_COVERAGE_MACROS})
138 set_property(TARGET ${EXE_NAME} APPEND PROPERTY COMPILE_OPTIONS ${CURL_COVERAGE_CFLAGS})
139 set_property(TARGET ${EXE_NAME} APPEND PROPERTY LINK_OPTIONS ${CURL_COVERAGE_LDFLAGS})
140endif()
142################################################################################
144if(CURL_ENABLE_EXPORT_TARGET)
145 if(NOT CURL_DISABLE_INSTALL)
146 install(TARGETS ${EXE_NAME} EXPORT ${TARGETS_EXPORT_NAME} DESTINATION ${CMAKE_INSTALL_BINDIR})
147 endif()
149 export(TARGETS ${EXE_NAME}
150 FILE "${PROJECT_BINARY_DIR}/curl-target.cmake"
151 NAMESPACE ${PROJECT_NAME}::
152 )
153endif()
Diagnostics4 git calls · 30 ms
CallStatusSizeTime030 ms
discover200152 B2 ms
git.upload-pack discover http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=2 git.response.bytes=152 git.server.agent=gitty/1.0 git.server.object_format=sha1 git.server.caps=agent ls-refs fetch object-format git.server.fetch=shallow filter sideband-all git.protocol.version=2 git.pkt.frames=8 git.pkt.data=6 git.pkt.flush=2 git.pkt.delim=0 git.pkt.bytes=152 git.pkt.payload.max=34
ls-refs200149 B2 ms
git.upload-pack ls-refs http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=ls-refs git.upstream.dur_ms=2 git.response.bytes=149 git.response.cache=UPDATING git.response.duration_ms=2 git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=149 git.pkt.payload.max=78 git.ls_refs.count=2 git.ls_refs.head=refs/heads/master
fetchblob:none · deepen 10200287 KiB · hit2 ms
git.upload-pack fetch http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=26 git.response.bytes=293470 git.response.cache=HIT git.response.duration_ms=2 git.fetch.filter=blob:none git.fetch.filter.requested=tree:0 git.fetch.filter.fallback=blob:none git.fetch.filter.learned=false git.fetch.wants=31c911efe5652725e930f4d2e60c9060e5f6646d git.fetch.haves.count=0 git.fetch.deepen=10 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=10 git.pkt.data=8 git.pkt.flush=1 git.pkt.delim=1 git.pkt.bytes=293470 git.pkt.payload.max=65516 git.sideband.band1.bytes=293354 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0 git.pack.objects=87 git.pack.bytes=293354 git.pack.ofs_delta=0 git.pack.ref_delta=1 git.pack.chain.max=1 git.pack.trailer=6a646bcda6740bab42e321b51998b52ea15146c0 git.pack.full=86Open pack map
fetch2002.1 KiB · hit26 ms
git.upload-pack fetch http.response.status_code=200 git.response.bytes=2133 git.response.cache=HIT git.response.duration_ms=26 git.fetch.wants=1f7683900927ee64929a4e498973ff6d9c2b42ef git.fetch.haves.count=0 git.fetch.deepen=0 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=2133 git.pkt.payload.max=2112 git.sideband.band1.bytes=2111 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0
Each row is one HTTP round trip ply made to the git server for this page, on one timeline. discover asks what the server speaks, ls-refs lists branch tips, fetch brings objects by id. A hit was served by Workers Cache. Tap a row for its wire details.
- Remote
- https://5ad2236b39de4c8bd8f6270ea63f3ea9.artifacts.cloudflare.net/git/public-v0/curl.git
- Ref
- refs/heads/master
- Commit
- 31c911efe5652725e930f4d2e60c9060e5f6646d
- cf-ray
- a5e2dbf93925c125
- Request
- bd1c2f91…
- Protocol
- v2 · sha1
- Agent
- gitty/1.0
- Filter
- advertised
- Fetch
- shallow filter sideband-all
- Capabilities
- agent ls-refs fetch object-format