master
1@echo off
2rem ***************************************************************************
3rem * _ _ ____ _
4rem * Project ___| | | | _ \| |
5rem * / __| | | | |_) | |
6rem * | (__| |_| | _ <| |___
7rem * \___|\___/|_| \_\_____|
8rem *
9rem * Copyright (C) Steve Holme, <steve_holme@hotmail.com>.
10rem *
11rem * This software is licensed as described in the file COPYING, which
12rem * you should have received as part of this distribution. The terms
13rem * are also available at https://curl.se/docs/copyright.html.
14rem *
15rem * You may opt to use, copy, modify, merge, publish, distribute and/or sell
16rem * copies of the Software, and permit persons to whom the Software is
17rem * furnished to do so, under the terms of the COPYING file.
18rem *
19rem * This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
20rem * KIND, either express or implied.
21rem *
22rem * SPDX-License-Identifier: curl
23rem *
24rem ***************************************************************************
26:begin
27 rem Check we are running on a Windows NT derived OS
28 if not "%OS%" == "Windows_NT" goto nodos
30 rem Set our variables
31 setlocal ENABLEEXTENSIONS
32 set VERSION=ALL
33 set MODE=GENERATE
35 rem Check we are not running on a network drive
36 if "%~d0."=="\\." goto nonetdrv
38 rem Switch to this batch file's directory
39 cd /d "%~0\.." 1>NUL 2>&1
41 rem Check we are running from a curl git repository
42 if not exist ..\..\GIT-INFO.md goto norepo
44:parseArgs
45 if "%~1" == "" goto start
47 if /i "%~1" == "vc10" (
48 set VERSION=VC10
49 ) else if /i "%~1" == "vc11" (
50 set VERSION=VC11
51 ) else if /i "%~1" == "vc12" (
52 set VERSION=VC12
53 ) else if /i "%~1" == "-clean" (
54 set MODE=CLEAN
55 ) else if /i "%~1" == "-?" (
56 goto syntax
57 ) else if /i "%~1" == "/?" (
58 goto syntax
59 ) else if /i "%~1" == "-h" (
60 goto syntax
61 ) else if /i "%~1" == "-help" (
62 goto syntax
63 ) else if /i "%~1" == "--help" (
64 goto syntax
65 ) else (
66 goto unknown
67 )
69 shift & goto parseArgs
71:start
72 if "%VERSION%" == "VC10" goto vc10
73 if "%VERSION%" == "VC11" goto vc11
74 if "%VERSION%" == "VC12" goto vc12
76:vc10
77 if "%MODE%" == "GENERATE" (
78 call :generate_proj VC10
79 ) else (
80 call :clean_proj VC10
81 )
83 if not "%VERSION%" == "ALL" goto success
85:vc11
86 if "%MODE%" == "GENERATE" (
87 call :generate_proj VC11
88 ) else (
89 call :clean_proj VC11
90 )
92 if not "%VERSION%" == "ALL" goto success
94:vc12
95 if "%MODE%" == "GENERATE" (
96 call :generate_proj VC12
97 ) else (
98 call :clean_proj VC12
99 )
101 goto success
103rem Main project generate function.
104rem
105rem %1 - version
106rem %2 - Input template file
107rem %3 - Output project file
108rem
109:generate_proj
110 echo.
111 echo Generating %1 project files
112 if not exist %1\lib md %1\lib
113 if not exist %1\src md %1\src
114 call :generate %1 tmpl\curl-all.sln %1\curl-all.sln
115 call :generate %1 tmpl\curl.sln %1\src\curl.sln
116 call :generate %1 tmpl\curl.vcxproj %1\src\curl.vcxproj
117 call :generate %1 tmpl\curl.vcxproj.filters %1\src\curl.vcxproj.filters
118 call :generate %1 tmpl\libcurl.sln %1\lib\libcurl.sln
119 call :generate %1 tmpl\libcurl.vcxproj %1\lib\libcurl.vcxproj
120 call :generate %1 tmpl\libcurl.vcxproj.filters %1\lib\libcurl.vcxproj.filters
122 exit /B
124rem Main project clean function.
125rem
126rem %1 - version
127rem
128:clean_proj
129 echo.
130 echo Removing %1 project files
131 call :clean %1\curl-all.sln
132 call :clean %1\src\curl.sln
133 call :clean %1\src\curl.vcxproj
134 call :clean %1\src\curl.vcxproj.filters
135 call :clean %1\lib\libcurl.sln
136 call :clean %1\lib\libcurl.vcxproj
137 call :clean %1\lib\libcurl.vcxproj.filters
139 exit /B
141rem Main file generate function.
142rem
143rem %1 - version
144rem %2 - Input template file
145rem %3 - Output project file
146rem
147:generate
148 if not exist %2 (
149 echo.
150 echo Error: Cannot open %2
151 exit /B
152 )
154 if exist %3 (
155 del %3
156 )
158 set "S01=$FORMATVER"
159 set "S02=$PLATFORMTOOLSET"
160 set "S03=$SUBDIR"
161 set "S04=$TOOLSVER"
163 if "%1" == "VC10" (
164 set "R01=11.00"
165 set "R02=v100"
166 set "R03=VC10"
167 set "R04=4.0"
168 ) else if "%1" == "VC11" (
169 set "R01=12.00"
170 set "R02=v110"
171 set "R03=VC11"
172 set "R04=4.0"
173 ) else if "%1" == "VC12" (
174 set "R01=12.00"
175 set "R02=v120"
176 set "R03=VC12"
177 set "R04=12.0"
178 )
180 echo * %CD%\%3
181 for /f "usebackq delims=" %%i in (`"findstr /n ^^ %2"`) do (
182 set "var=%%i"
183 setlocal enabledelayedexpansion
184 set "var=!var:%S01%=%R01%!"
185 set "var=!var:%S02%=%R02%!"
186 set "var=!var:%S03%=%R03%!"
187 set "var=!var:%S04%=%R04%!"
188 if "%CURL_CI%" NEQ "" set "var=!var:_DEBUG;=_DEBUG;CURL_DEBUG_MSVC_CRTDBG;!"
190 set "var=!var:*:=!"
192 if "!var!" == "CURL_SRC_C_FILES" (
193 for /f "delims=" %%c in ('dir /b ..\..\src\*.c') do (
194 if /i "%%c" NEQ "curlinfo.c" call :element src "%%c" %3
195 )
196 ) else if "!var!" == "CURL_SRC_H_FILES" (
197 for /f "delims=" %%h in ('dir /b ..\..\src\*.h') do call :element src "%%h" %3
198 ) else if "!var!" == "CURL_SRC_RC_FILES" (
199 for /f "delims=" %%r in ('dir /b ..\..\src\*.rc') do call :element src "%%r" %3
200 ) else if "!var!" == "CURL_SRC_X_H_FILES" (
201 call :element lib "config-win32.h" %3
202 call :element lib "curl_setup.h" %3
203 ) else if "!var!" == "CURL_LIB_C_FILES" (
204 for /f "delims=" %%c in ('dir /b ..\..\lib\*.c') do call :element lib "%%c" %3
205 ) else if "!var!" == "CURL_LIB_H_FILES" (
206 for /f "delims=" %%h in ('dir /b ..\..\include\curl\*.h') do call :element include\curl "%%h" %3
207 for /f "delims=" %%h in ('dir /b ..\..\lib\*.h') do call :element lib "%%h" %3
208 ) else if "!var!" == "CURL_LIB_RC_FILES" (
209 for /f "delims=" %%r in ('dir /b ..\..\lib\*.rc') do call :element lib "%%r" %3
210 ) else if "!var!" == "CURL_LIB_CURLX_C_FILES" (
211 for /f "delims=" %%c in ('dir /b ..\..\lib\curlx\*.c') do call :element lib\curlx "%%c" %3
212 ) else if "!var!" == "CURL_LIB_CURLX_H_FILES" (
213 for /f "delims=" %%h in ('dir /b ..\..\lib\curlx\*.h') do call :element lib\curlx "%%h" %3
214 ) else if "!var!" == "CURL_LIB_VAUTH_C_FILES" (
215 for /f "delims=" %%c in ('dir /b ..\..\lib\vauth\*.c') do call :element lib\vauth "%%c" %3
216 ) else if "!var!" == "CURL_LIB_VAUTH_H_FILES" (
217 for /f "delims=" %%h in ('dir /b ..\..\lib\vauth\*.h') do call :element lib\vauth "%%h" %3
218 ) else if "!var!" == "CURL_LIB_VDNS_C_FILES" (
219 for /f "delims=" %%c in ('dir /b ..\..\lib\vdns\*.c') do call :element lib\vdns "%%c" %3
220 ) else if "!var!" == "CURL_LIB_VDNS_H_FILES" (
221 for /f "delims=" %%h in ('dir /b ..\..\lib\vdns\*.h') do call :element lib\vdns "%%h" %3
222 ) else if "!var!" == "CURL_LIB_VQUIC_C_FILES" (
223 for /f "delims=" %%c in ('dir /b ..\..\lib\vquic\*.c') do call :element lib\vquic "%%c" %3
224 ) else if "!var!" == "CURL_LIB_VQUIC_H_FILES" (
225 for /f "delims=" %%h in ('dir /b ..\..\lib\vquic\*.h') do call :element lib\vquic "%%h" %3
226 ) else if "!var!" == "CURL_LIB_VSSH_C_FILES" (
227 for /f "delims=" %%c in ('dir /b ..\..\lib\vssh\*.c') do call :element lib\vssh "%%c" %3
228 ) else if "!var!" == "CURL_LIB_VSSH_H_FILES" (
229 for /f "delims=" %%h in ('dir /b ..\..\lib\vssh\*.h') do call :element lib\vssh "%%h" %3
230 ) else if "!var!" == "CURL_LIB_VTLS_C_FILES" (
231 for /f "delims=" %%c in ('dir /b ..\..\lib\vtls\*.c') do call :element lib\vtls "%%c" %3
232 ) else if "!var!" == "CURL_LIB_VTLS_H_FILES" (
233 for /f "delims=" %%h in ('dir /b ..\..\lib\vtls\*.h') do call :element lib\vtls "%%h" %3
234 ) else if "!var!" == "CURL_SRC_TOOLX_C_FILES" (
235 for /f "delims=" %%c in ('dir /b ..\..\src\toolx\*.c') do call :element src\toolx "%%c" %3
236 ) else if "!var!" == "CURL_SRC_TOOLX_H_FILES" (
237 for /f "delims=" %%h in ('dir /b ..\..\src\toolx\*.h') do call :element src\toolx "%%h" %3
238 ) else (
239 echo.!var!>> %3
240 )
242 endlocal
243 )
244 exit /B
246rem Generates a single file xml element.
247rem
248rem %1 - Directory (src, lib, lib\vauth, lib\vquic, lib\vssh, lib\vtls)
249rem %2 - Source filename
250rem %3 - Output project file
251rem
252:element
253 set "SPACES= "
255 call :extension %2 ext
257 if "%ext%" == "c" (
258 echo %SPACES%^<ClCompile Include=^"..\..\..\..\%1\%~2^" /^>>> %3
259 ) else if "%ext%" == "h" (
260 echo %SPACES%^<ClInclude Include=^"..\..\..\..\%1\%~2^" /^>>> %3
261 ) else if "%ext%" == "rc" (
262 echo %SPACES%^<ResourceCompile Include=^"..\..\..\..\%1\%~2^" /^>>> %3
263 )
265 exit /B
267rem Returns the extension for a given filename.
268rem
269rem %1 - The filename
270rem %2 - The return value
271rem
272:extension
273 set fname=%~1
274 set ename=
275:loop1
276 if "%fname%"=="" (
277 set %2=
278 exit /B
279 )
281 if not "%fname:~-1%"=="." (
282 set ename=%fname:~-1%%ename%
283 set fname=%fname:~0,-1%
284 goto loop1
285 )
287 set %2=%ename%
288 exit /B
290rem Removes the given project file.
291rem
292rem %1 - The filename
293rem
294:clean
295 echo * %CD%\%1
297 if exist %1 (
298 del %1
299 )
301 exit /B
303:syntax
304 rem Display the help
305 echo.
306 echo Usage: generate [what] [-clean]
307 echo.
308 echo What to generate:
309 echo.
310 echo vc10 - Use Visual Studio 2010
311 echo vc11 - Use Visual Studio 2012
312 echo vc12 - Use Visual Studio 2013
313 echo.
314 echo Only legacy Visual Studio project files can be generated.
315 echo.
316 echo To generate recent versions of Visual Studio project files use cmake.
317 echo Refer to INSTALL-CMAKE.md in the docs directory.
318 echo.
319 echo -clean - Removes the project files
320 goto error
322:unknown
323 echo.
324 echo Error: Unknown argument '%1'
325 goto error
327:nodos
328 echo.
329 echo Error: Only a Windows NT based Operating System is supported
330 goto error
332:nonetdrv
333 echo.
334 echo Error: This batch file cannot run from a network drive
335 goto error
337:norepo
338 echo.
339 echo Error: This batch file should only be used from a curl git repository
340 goto error
342:seterr
343 rem Set the caller's errorlevel.
344 rem %1[opt]: Errorlevel as integer.
345 rem If %1 is empty the errorlevel is set to 0.
346 rem If %1 is not empty and not an integer the errorlevel is set to 1.
347 setlocal
348 set EXITCODE=%~1
349 if not defined EXITCODE set EXITCODE=0
350 echo %EXITCODE%|findstr /r "[^0-9\-]" 1>NUL 2>&1
351 if %ERRORLEVEL% EQU 0 set EXITCODE=1
352 exit /b %EXITCODE%
354:error
355 if "%OS%" == "Windows_NT" endlocal
356 exit /B 1
358:success
359 endlocal
360 exit /B 0
Diagnostics4 git calls · 211 ms
CallStatusSizeTime0211 ms
discover200152 B3 ms
git.upload-pack discover http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=ls-refs git.upstream.dur_ms=3 git.response.bytes=152 git.server.agent=gitty/1.0 git.server.object_format=sha1 git.server.caps=agent ls-refs fetch object-format git.server.fetch=shallow filter sideband-all git.protocol.version=2 git.pkt.frames=8 git.pkt.data=6 git.pkt.flush=2 git.pkt.delim=0 git.pkt.bytes=152 git.pkt.payload.max=34
ls-refs200149 B · hit3 ms
git.upload-pack ls-refs http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=ls-refs git.upstream.dur_ms=3 git.response.bytes=149 git.response.cache=HIT git.response.duration_ms=3 git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=149 git.pkt.payload.max=78 git.ls_refs.count=2 git.ls_refs.head=refs/heads/master
fetchblob:none · deepen 10200287 KiB · hit24 ms
git.upload-pack fetch http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=2 git.response.bytes=293470 git.response.cache=HIT git.response.duration_ms=24 git.fetch.filter=blob:none git.fetch.filter.requested=tree:0 git.fetch.filter.fallback=blob:none git.fetch.filter.learned=false git.fetch.wants=31c911efe5652725e930f4d2e60c9060e5f6646d git.fetch.haves.count=0 git.fetch.deepen=10 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=10 git.pkt.data=8 git.pkt.flush=1 git.pkt.delim=1 git.pkt.bytes=293470 git.pkt.payload.max=65516 git.sideband.band1.bytes=293354 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0 git.pack.objects=87 git.pack.bytes=293354 git.pack.ofs_delta=0 git.pack.ref_delta=1 git.pack.chain.max=1 git.pack.trailer=6a646bcda6740bab42e321b51998b52ea15146c0 git.pack.full=86Open pack map
fetch2003.0 KiB184 ms
git.upload-pack fetch http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=184 git.response.bytes=3031 git.response.cache=MISS git.response.duration_ms=184 git.fetch.wants=f0a78f25132997b153aeb8e3ba346f4d1616c329 git.fetch.haves.count=0 git.fetch.deepen=0 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=3031 git.pkt.payload.max=3010 git.sideband.band1.bytes=3009 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0
Each row is one HTTP round trip ply made to the git server for this page, on one timeline. discover asks what the server speaks, ls-refs lists branch tips, fetch brings objects by id. A hit was served by Workers Cache. Tap a row for its wire details.
- Remote
- https://5ad2236b39de4c8bd8f6270ea63f3ea9.artifacts.cloudflare.net/git/public-v0/curl.git
- Ref
- refs/heads/master
- Commit
- 31c911efe5652725e930f4d2e60c9060e5f6646d
- cf-ray
- a5e2ccc4ed3e7929
- Request
- 2048998f…
- Protocol
- v2 · sha1
- Agent
- gitty/1.0
- Filter
- advertised
- Fetch
- shallow filter sideband-all
- Capabilities
- agent ls-refs fetch object-format