master
1 * curl header API: extract headers post transfer
2 *
3 h DFTACTGRP(*NO) ACTGRP(*NEW)
4 h OPTION(*NOSHOWCPY)
5 h BNDDIR('CURL')
6 *
7 **************************************************************************
8 * _ _ ____ _
9 * Project ___| | | | _ \| |
10 * / __| | | | |_) | |
11 * | (__| |_| | _ <| |___
12 * \___|\___/|_| \_\_____|
13 *
14 * Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
15 *
16 * This software is licensed as described in the file COPYING, which
17 * you should have received as part of this distribution. The terms
18 * are also available at https://curl.se/docs/copyright.html.
19 *
20 * You may opt to use, copy, modify, merge, publish, distribute and/or sell
21 * copies of the Software, and permit persons to whom the Software is
22 * furnished to do so, under the terms of the COPYING file.
23 *
24 * This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF
25 * ANY KIND, either express or implied.
26 *
27 * SPDX-License-Identifier: curl
28 *
29 **************************************************************************
30 *
31 /include H,CURL.INC
32 *
33 * Extract headers post transfer with the header API.
34 *
35 d pi
36 d url 120
37 *
38 d urllen s 10u 0 URL length
39 *
40 **************************************************************************
42 urllen = trimmed_length(url: %len(url));
44 // Do the curl stuff.
46 curl_global_init(CURL_GLOBAL_ALL);
47 main();
48 curl_global_cleanup();
49 *inlr = *on; // Exit
50 *
51 **************************************************************************
52 * Main procedure: do the curl job.
53 **************************************************************************
54 *
55 p main b
56 d main pi
57 *
58 d h s * Easy handle
59 d result s like(CURLcode) Curl return code
60 d inz(CURLE_OUT_OF_MEMORY)
61 d header ds likeds(curl_header) based(hp)
62 d strp1 s * Work string pointer
63 d strp2 s * Work string pointer
64 d inout s 52 For error display
66 // Create and fill curl handle.
68 h = curl_easy_init();
69 if h <> *NULL;
70 curl_easy_setopt_ccsid(h: CURLOPT_URL: %subst(url: 1: urllen): 0);
71 curl_easy_setopt(h: CURLOPT_FOLLOWLOCATION: 1);
72 curl_easy_setopt(h: CURLOPT_WRITEFUNCTION: %paddr(in_data_cb)); // Ignore input data
74 // Perform the request.
76 result = curl_easy_perform(h);
77 endif;
79 // Check for error and report if some.
81 if result <> CURLE_OK;
82 inout = %str(curl_easy_strerror_ccsid(result: 0));
83 dsply '' '*EXT' inout;
84 else;
85 if curl_easy_header_ccsid(h: 'Content-Type': 0: CURLH_HEADER: -1:
86 hp: 0) = CURLHE_OK;
87 strp2 = curl_to_ccsid(header.value: 0);
88 inout = 'Content-Type: ' + %str(strp2);
89 dsply inout;
90 curl_free(strp2);
91 endif;
92 dsply ' All server headers:';
93 hp = *NULL;
94 dow *on;
95 hp = curl_easy_nextheader(h: CURLH_HEADER: -1: hp);
96 if hp = *NULL;
97 leave;
98 endif;
99 strp1 = curl_to_ccsid(header.name: 0);
100 strp2 = curl_to_ccsid(header.value: 0);
101 inout = %str(strp1) + ': ' + %str(strp2) +
102 ' (' + %char(header.amount) + ')';
103 curl_free(strp2);
104 curl_free(strp1);
105 dsply inout;
106 enddo;
107 inout = 'Done';
108 dsply '' '*EXT' inout;
109 curl_easy_cleanup(h); // Release handle
110 endif;
111 p main e
112 *
113 **************************************************************************
114 * Dummy data input callback procedure.
115 **************************************************************************
116 *
117 p in_data_cb b
118 d in_data_cb pi 10u 0
119 d ptr * value Input data pointer
120 d size 10u 0 value Data element size
121 d nmemb 10u 0 value Data element count
122 d userdata * value User data pointer
123 *
124 return size * nmemb;
125 p in_data_cb e
126 *
127 **************************************************************************
128 * Get the length of right-trimmed string
129 **************************************************************************
130 *
131 p trimmed_length b
132 d trimmed_length pi 10u 0
133 d string 999999 const options(*varsize)
134 d length 10u 0 value
135 *
136 d len s 10u 0
137 *
138 len = %scan(X'00': string: 1: length); // Limit to null-terminated string
139 if len = 0;
140 len = length + 1;
141 endif;
142 if len <= 1;
143 return 0;
144 endif;
145 return %checkr(' ': string: len - 1); // Trim right
146 p trimmed_length e
Diagnostics4 git calls · 206 ms
CallStatusSizeTime0206 ms
discover200152 B3 ms
git.upload-pack discover http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=2 git.response.bytes=152 git.server.agent=gitty/1.0 git.server.object_format=sha1 git.server.caps=agent ls-refs fetch object-format git.server.fetch=shallow filter sideband-all git.protocol.version=2 git.pkt.frames=8 git.pkt.data=6 git.pkt.flush=2 git.pkt.delim=0 git.pkt.bytes=152 git.pkt.payload.max=34
ls-refs200149 B · hit3 ms
git.upload-pack ls-refs http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=ls-refs git.upstream.dur_ms=3 git.response.bytes=149 git.response.cache=HIT git.response.duration_ms=3 git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=149 git.pkt.payload.max=78 git.ls_refs.count=2 git.ls_refs.head=refs/heads/master
fetchblob:none · deepen 10200287 KiB · hit28 ms
git.upload-pack fetch http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=175 git.response.bytes=293470 git.response.cache=HIT git.response.duration_ms=28 git.fetch.filter=blob:none git.fetch.filter.requested=tree:0 git.fetch.filter.fallback=blob:none git.fetch.filter.learned=false git.fetch.wants=31c911efe5652725e930f4d2e60c9060e5f6646d git.fetch.haves.count=0 git.fetch.deepen=10 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=10 git.pkt.data=8 git.pkt.flush=1 git.pkt.delim=1 git.pkt.bytes=293470 git.pkt.payload.max=65516 git.sideband.band1.bytes=293354 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0 git.pack.objects=87 git.pack.bytes=293354 git.pack.ofs_delta=0 git.pack.ref_delta=1 git.pack.chain.max=1 git.pack.trailer=6a646bcda6740bab42e321b51998b52ea15146c0 git.pack.full=86Open pack map
fetch2001.9 KiB175 ms
git.upload-pack fetch http.response.status_code=200 git.response.bytes=1911 git.response.cache=MISS git.response.duration_ms=175 git.fetch.wants=f6ef80bbd4fbfd3a0dba7cdb4e4dd14336bd9c6b git.fetch.haves.count=0 git.fetch.deepen=0 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=1911 git.pkt.payload.max=1890 git.sideband.band1.bytes=1889 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0
Each row is one HTTP round trip ply made to the git server for this page, on one timeline. discover asks what the server speaks, ls-refs lists branch tips, fetch brings objects by id. A hit was served by Workers Cache. Tap a row for its wire details.
- Remote
- https://5ad2236b39de4c8bd8f6270ea63f3ea9.artifacts.cloudflare.net/git/public-v0/curl.git
- Ref
- refs/heads/master
- Commit
- 31c911efe5652725e930f4d2e60c9060e5f6646d
- cf-ray
- a5e2d10c2b6ccf3a
- Request
- cd69210c…
- Protocol
- v2 · sha1
- Agent
- gitty/1.0
- Filter
- advertised
- Fetch
- shallow filter sideband-all
- Capabilities
- agent ls-refs fetch object-format