master
1#---------------------------------------------------------------------------
2#
3# zz40-xc-ovr.m4
4#
5# Copyright (C) Daniel Stenberg, <daniel@haxx.se>
6#
7# Permission to use, copy, modify, and distribute this software for any
8# purpose with or without fee is hereby granted, provided that the above
9# copyright notice and this permission notice appear in all copies.
10#
11# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
12# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
13# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
14# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
15# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
16# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
17# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
18#
19# SPDX-License-Identifier: ISC
20#
21#---------------------------------------------------------------------------
23dnl The funny name of this file is intentional in order to make it
24dnl sort alphabetically after any libtool, autoconf or automake
25dnl provided .m4 macro file that might get copied into this same
26dnl subdirectory. This allows that macro (re)definitions from this
27dnl file may override those provided in other files.
30dnl Version macros
31dnl -------------------------------------------------
32dnl Public macros.
34m4_define([XC_CONFIGURE_PREAMBLE_VER_MAJOR],[1])
35m4_define([XC_CONFIGURE_PREAMBLE_VER_MINOR],[0])
38dnl _XC_CFG_PRE_PREAMBLE
39dnl -------------------------------------------------
40dnl Private macro.
42AC_DEFUN([_XC_CFG_PRE_PREAMBLE],
43[
44## -------------------------------- ##
45@%:@@%:@ [XC_CONFIGURE_PREAMBLE] ver: []dnl
46XC_CONFIGURE_PREAMBLE_VER_MAJOR.[]dnl
47XC_CONFIGURE_PREAMBLE_VER_MINOR ##
48## -------------------------------- ##
50xc_configure_preamble_ver_major='XC_CONFIGURE_PREAMBLE_VER_MAJOR'
51xc_configure_preamble_ver_minor='XC_CONFIGURE_PREAMBLE_VER_MINOR'
53dnl
54dnl Set IFS to space, tab and newline.
55dnl
57xc_space=' '
58xc_tab=' '
59xc_newline='
60'
61IFS="$xc_space$xc_tab$xc_newline"
63dnl
64dnl Set internationalization behavior variables.
65dnl
67LANG='C'
68LC_ALL='C'
69LANGUAGE='C'
70export LANG
71export LC_ALL
72export LANGUAGE
74dnl
75dnl Some useful variables.
76dnl
78xc_msg_warn='configure: WARNING:'
79xc_msg_abrt='Can not continue.'
80xc_msg_err='configure: error:'
81])
84dnl _XC_CFG_PRE_BASIC_CHK_CMD_ECHO
85dnl -------------------------------------------------
86dnl Private macro.
87dnl
88dnl Emits shell code that verifies that 'echo' command
89dnl is available, otherwise aborts execution.
91AC_DEFUN([_XC_CFG_PRE_BASIC_CHK_CMD_ECHO],
92[
93AC_REQUIRE([_XC_CFG_PRE_PREAMBLE])
94dnl
95dnl Verify that 'echo' command is available, otherwise abort.
96dnl
98xc_tst_str='unknown'
99(`echo "$xc_tst_str" >/dev/null 2>&1`) && xc_tst_str='success'
100case "x$xc_tst_str" in @%:@ ((
101 xsuccess)
102 :
103 ;;
104 *)
105 dnl Try built-in echo, and fail.
106 echo "$xc_msg_err 'echo' command not found. $xc_msg_abrt" >&2
107 exit 1
108 ;;
109esac
110])
113dnl _XC_CFG_PRE_BASIC_CHK_CMD_TEST
114dnl -------------------------------------------------
115dnl Private macro.
116dnl
117dnl Emits shell code that verifies that 'test' command
118dnl is available, otherwise aborts execution.
120AC_DEFUN([_XC_CFG_PRE_BASIC_CHK_CMD_TEST],
121[
122AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_CMD_ECHO])
123dnl
124dnl Verify that 'test' command is available, otherwise abort.
125dnl
127xc_tst_str='unknown'
128(`test -n "$xc_tst_str" >/dev/null 2>&1`) && xc_tst_str='success'
129case "x$xc_tst_str" in @%:@ ((
130 xsuccess)
131 :
132 ;;
133 *)
134 echo "$xc_msg_err 'test' command not found. $xc_msg_abrt" >&2
135 exit 1
136 ;;
137esac
138])
141dnl _XC_CFG_PRE_BASIC_CHK_VAR_PATH
142dnl -------------------------------------------------
143dnl Private macro.
144dnl
145dnl Emits shell code that verifies that 'PATH' variable
146dnl is set, otherwise aborts execution.
148AC_DEFUN([_XC_CFG_PRE_BASIC_CHK_VAR_PATH],
149[
150AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_CMD_TEST])
151dnl
152dnl Verify that 'PATH' variable is set, otherwise abort.
153dnl
155xc_tst_str='unknown'
156(`test -n "$PATH" >/dev/null 2>&1`) && xc_tst_str='success'
157case "x$xc_tst_str" in @%:@ ((
158 xsuccess)
159 :
160 ;;
161 *)
162 echo "$xc_msg_err 'PATH' variable not set. $xc_msg_abrt" >&2
163 exit 1
164 ;;
165esac
166])
169dnl _XC_CFG_PRE_BASIC_CHK_CMD_EXPR
170dnl -------------------------------------------------
171dnl Private macro.
172dnl
173dnl Emits shell code that verifies that 'expr' command
174dnl is available, otherwise aborts execution.
176AC_DEFUN([_XC_CFG_PRE_BASIC_CHK_CMD_EXPR],
177[
178AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_VAR_PATH])
179dnl
180dnl Verify that 'expr' command is available, otherwise abort.
181dnl
183xc_tst_str='unknown'
184xc_tst_str=`expr "$xc_tst_str" : '.*' 2>/dev/null`
185case "x$xc_tst_str" in @%:@ ((
186 x7)
187 :
188 ;;
189 *)
190 echo "$xc_msg_err 'expr' command not found. $xc_msg_abrt" >&2
191 exit 1
192 ;;
193esac
194])
197dnl _XC_CFG_PRE_BASIC_CHK_UTIL_SED
198dnl -------------------------------------------------
199dnl Private macro.
200dnl
201dnl Emits shell code that verifies that 'sed' utility
202dnl is found within 'PATH', otherwise aborts execution.
203dnl
204dnl This 'sed' is required in order to allow configure
205dnl script bootstrapping itself. No fancy testing for a
206dnl proper 'sed' this early, that should be done later.
208AC_DEFUN([_XC_CFG_PRE_BASIC_CHK_UTIL_SED],
209[
210AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_VAR_PATH])
211dnl
212dnl Verify that 'sed' utility is found within 'PATH', otherwise abort.
213dnl
215xc_tst_str='unknown'
216xc_tst_str=`echo "$xc_tst_str" 2>/dev/null \
217 | sed -e 's:unknown:success:' 2>/dev/null`
218case "x$xc_tst_str" in @%:@ ((
219 xsuccess)
220 :
221 ;;
222 *)
223 echo "$xc_msg_err 'sed' utility not found in 'PATH'. $xc_msg_abrt" >&2
224 exit 1
225 ;;
226esac
227])
230dnl _XC_CFG_PRE_BASIC_CHK_UTIL_GREP
231dnl -------------------------------------------------
232dnl Private macro.
233dnl
234dnl Emits shell code that verifies that 'grep' utility
235dnl is found within 'PATH', otherwise aborts execution.
236dnl
237dnl This 'grep' is required in order to allow configure
238dnl script bootstrapping itself. No fancy testing for a
239dnl proper 'grep' this early, that should be done later.
241AC_DEFUN([_XC_CFG_PRE_BASIC_CHK_UTIL_GREP],
242[
243AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_VAR_PATH])
244dnl
245dnl Verify that 'grep' utility is found within 'PATH', otherwise abort.
246dnl
248xc_tst_str='unknown'
249(`echo "$xc_tst_str" 2>/dev/null \
250 | grep 'unknown' >/dev/null 2>&1`) && xc_tst_str='success'
251case "x$xc_tst_str" in @%:@ ((
252 xsuccess)
253 :
254 ;;
255 *)
256 echo "$xc_msg_err 'grep' utility not found in 'PATH'. $xc_msg_abrt" >&2
257 exit 1
258 ;;
259esac
260])
263dnl _XC_CFG_PRE_BASIC_CHK_UTIL_TR
264dnl -------------------------------------------------
265dnl Private macro.
266dnl
267dnl Emits shell code that verifies that 'tr' utility
268dnl is found within 'PATH', otherwise aborts execution.
270AC_DEFUN([_XC_CFG_PRE_BASIC_CHK_UTIL_TR],
271[
272AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_VAR_PATH])
273dnl
274dnl Verify that 'tr' utility is found within 'PATH', otherwise abort.
275dnl
277xc_tst_str="${xc_tab}98s7u6c5c4e3s2s10"
278xc_tst_str=`echo "$xc_tst_str" 2>/dev/null \
279 | tr -d "0123456789$xc_tab" 2>/dev/null`
280case "x$xc_tst_str" in @%:@ ((
281 xsuccess)
282 :
283 ;;
284 *)
285 echo "$xc_msg_err 'tr' utility not found in 'PATH'. $xc_msg_abrt" >&2
286 exit 1
287 ;;
288esac
289])
292dnl _XC_CFG_PRE_BASIC_CHK_UTIL_WC
293dnl -------------------------------------------------
294dnl Private macro.
295dnl
296dnl Emits shell code that verifies that 'wc' utility
297dnl is found within 'PATH', otherwise aborts execution.
299AC_DEFUN([_XC_CFG_PRE_BASIC_CHK_UTIL_WC],
300[
301AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_UTIL_TR])
302dnl
303dnl Verify that 'wc' utility is found within 'PATH', otherwise abort.
304dnl
306xc_tst_str='unknown unknown unknown unknown'
307xc_tst_str=`echo "$xc_tst_str" 2>/dev/null \
308 | wc -w 2>/dev/null | tr -d "$xc_space$xc_tab" 2>/dev/null`
309case "x$xc_tst_str" in @%:@ ((
310 x4)
311 :
312 ;;
313 *)
314 echo "$xc_msg_err 'wc' utility not found in 'PATH'. $xc_msg_abrt" >&2
315 exit 1
316 ;;
317esac
318])
321dnl _XC_CFG_PRE_BASIC_CHK_UTIL_CAT
322dnl -------------------------------------------------
323dnl Private macro.
324dnl
325dnl Emits shell code that verifies that 'cat' utility
326dnl is found within 'PATH', otherwise aborts execution.
328AC_DEFUN([_XC_CFG_PRE_BASIC_CHK_UTIL_CAT],
329[
330AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_UTIL_WC])
331dnl
332dnl Verify that 'cat' utility is found within 'PATH', otherwise abort.
333dnl
335xc_tst_str='unknown'
336xc_tst_str=`cat <<_EOT 2>/dev/null \
337 | wc -l 2>/dev/null | tr -d "$xc_space$xc_tab" 2>/dev/null
338unknown
339unknown
340unknown
341_EOT`
342case "x$xc_tst_str" in @%:@ ((
343 x3)
344 :
345 ;;
346 *)
347 echo "$xc_msg_err 'cat' utility not found in 'PATH'. $xc_msg_abrt" >&2
348 exit 1
349 ;;
350esac
351])
354dnl _XC_CFG_PRE_CHECK_PATH_SEPARATOR
355dnl -------------------------------------------------
356dnl Private macro.
357dnl
358dnl Emits shell code that computes the path separator
359dnl and stores the result in 'PATH_SEPARATOR', unless
360dnl the user has already set it with a non-empty value.
361dnl
362dnl This path separator is the symbol used to separate
363dnl or differentiate paths inside the 'PATH' environment
364dnl variable.
365dnl
366dnl Non-empty user provided 'PATH_SEPARATOR' always
367dnl overrides the auto-detected one.
369AC_DEFUN([_XC_CFG_PRE_CHECK_PATH_SEPARATOR],
370[
371AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_CMD_EXPR])
372dnl
373dnl Auto-detect and set 'PATH_SEPARATOR', unless it is already non-empty set.
374dnl
376dnl Directory count in 'PATH' when using a colon separator.
377xc_tst_dirs_col='x'
378xc_tst_prev_IFS=$IFS; IFS=':'
379for xc_tst_dir in $PATH; do
380 IFS=$xc_tst_prev_IFS
381 xc_tst_dirs_col="x$xc_tst_dirs_col"
382done
383IFS=$xc_tst_prev_IFS
384xc_tst_dirs_col=`expr "$xc_tst_dirs_col" : '.*'`
386dnl Directory count in 'PATH' when using a semicolon separator.
387xc_tst_dirs_sem='x'
388xc_tst_prev_IFS=$IFS; IFS=';'
389for xc_tst_dir in $PATH; do
390 IFS=$xc_tst_prev_IFS
391 xc_tst_dirs_sem="x$xc_tst_dirs_sem"
392done
393IFS=$xc_tst_prev_IFS
394xc_tst_dirs_sem=`expr "$xc_tst_dirs_sem" : '.*'`
396if test "$xc_tst_dirs_sem" -eq "$xc_tst_dirs_col"; then
397 dnl When both counting methods give the same result we do not want to
398 dnl chose one over the other, and consider auto-detection not possible.
399 if test -z "$PATH_SEPARATOR"; then
400 dnl User should provide the correct 'PATH_SEPARATOR' definition.
401 dnl Until then, guess that it is colon!
402 echo "$xc_msg_warn path separator not determined, guessing colon" >&2
403 PATH_SEPARATOR=':'
404 fi
405else
406 dnl Separator with the greater directory count is the auto-detected one.
407 if test "$xc_tst_dirs_sem" -gt "$xc_tst_dirs_col"; then
408 xc_tst_auto_separator=';'
409 else
410 xc_tst_auto_separator=':'
411 fi
412 if test -z "$PATH_SEPARATOR"; then
413 dnl Use the auto-detected one when not already set.
414 PATH_SEPARATOR=$xc_tst_auto_separator
415 elif test "x$PATH_SEPARATOR" != "x$xc_tst_auto_separator"; then
416 echo "$xc_msg_warn 'PATH_SEPARATOR' does not match auto-detected one." >&2
417 fi
418fi
419xc_PATH_SEPARATOR=$PATH_SEPARATOR
420AC_SUBST([PATH_SEPARATOR])
421])
424dnl _XC_CFG_PRE_POSTLUDE
425dnl -------------------------------------------------
426dnl Private macro.
428AC_DEFUN([_XC_CFG_PRE_POSTLUDE],
429[
430AC_REQUIRE([_XC_CFG_PRE_PREAMBLE])
431AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_CMD_ECHO])
432AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_CMD_TEST])
433AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_VAR_PATH])
434AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_CMD_EXPR])
435AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_UTIL_SED])
436AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_UTIL_GREP])
437AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_UTIL_TR])
438AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_UTIL_WC])
439AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_UTIL_CAT])
440AC_REQUIRE([_XC_CFG_PRE_CHECK_PATH_SEPARATOR])
442xc_configure_preamble_result='yes'
443])
446dnl XC_CONFIGURE_PREAMBLE
447dnl -------------------------------------------------
448dnl Public macro.
449dnl
450dnl This macro emits shell code which does some
451dnl basic checks related with the availability
452dnl of some commands and utilities needed to allow
453dnl configure script bootstrapping itself when using
454dnl these to figure out other settings. Also emits
455dnl code that performs PATH_SEPARATOR auto-detection
456dnl and sets its value unless it is already set with
457dnl a non-empty value.
458dnl
459dnl These basic checks are intended to be placed and
460dnl executed as early as possible in the resulting
461dnl configure script, and as such these must be pure
462dnl and portable shell code.
463dnl
464dnl This macro may be used directly, or indirectly
465dnl when using other macros that AC_REQUIRE it such
466dnl as XC_CHECK_PATH_SEPARATOR.
467dnl
468dnl Currently the mechanism used to ensure that this
469dnl macro expands early enough in generated configure
470dnl script is making it override autoconf and libtool
471dnl PATH_SEPARATOR check.
473AC_DEFUN([XC_CONFIGURE_PREAMBLE],
474[
475AC_PREREQ([2.50])
477AC_BEFORE([$0],[_XC_CFG_PRE_PREAMBLE])
478AC_BEFORE([$0],[_XC_CFG_PRE_BASIC_CHK_CMD_ECHO])
479AC_BEFORE([$0],[_XC_CFG_PRE_BASIC_CHK_CMD_TEST])
480AC_BEFORE([$0],[_XC_CFG_PRE_BASIC_CHK_VAR_PATH])
481AC_BEFORE([$0],[_XC_CFG_PRE_BASIC_CHK_CMD_EXPR])
482AC_BEFORE([$0],[_XC_CFG_PRE_BASIC_CHK_UTIL_SED])
483AC_BEFORE([$0],[_XC_CFG_PRE_BASIC_CHK_UTIL_GREP])
484AC_BEFORE([$0],[_XC_CFG_PRE_BASIC_CHK_UTIL_TR])
485AC_BEFORE([$0],[_XC_CFG_PRE_BASIC_CHK_UTIL_WC])
486AC_BEFORE([$0],[_XC_CFG_PRE_BASIC_CHK_UTIL_CAT])
487AC_BEFORE([$0],[_XC_CFG_PRE_CHECK_PATH_SEPARATOR])
488AC_BEFORE([$0],[_XC_CFG_PRE_POSTLUDE])
490AC_BEFORE([$0],[AC_CHECK_TOOL])
491AC_BEFORE([$0],[AC_CHECK_PROG])
492AC_BEFORE([$0],[AC_CHECK_TOOLS])
493AC_BEFORE([$0],[AC_CHECK_PROGS])
495AC_BEFORE([$0],[AC_PATH_TOOL])
496AC_BEFORE([$0],[AC_PATH_PROG])
497AC_BEFORE([$0],[AC_PATH_PROGS])
499AC_BEFORE([$0],[AC_PROG_SED])
500AC_BEFORE([$0],[AC_PROG_GREP])
501AC_BEFORE([$0],[AC_PROG_LN_S])
502AC_BEFORE([$0],[AC_PROG_MKDIR_P])
503AC_BEFORE([$0],[AC_PROG_INSTALL])
504AC_BEFORE([$0],[AC_PROG_MAKE_SET])
505AC_BEFORE([$0],[AC_PROG_LIBTOOL])
507AC_BEFORE([$0],[LT_INIT])
508AC_BEFORE([$0],[AM_INIT_AUTOMAKE])
509AC_BEFORE([$0],[AC_LIBTOOL_WIN32_DLL])
511AC_REQUIRE([_XC_CFG_PRE_PREAMBLE])
512AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_CMD_ECHO])
513AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_CMD_TEST])
514AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_VAR_PATH])
515AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_CMD_EXPR])
516AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_UTIL_SED])
517AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_UTIL_GREP])
518AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_UTIL_TR])
519AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_UTIL_WC])
520AC_REQUIRE([_XC_CFG_PRE_BASIC_CHK_UTIL_CAT])
521AC_REQUIRE([_XC_CFG_PRE_CHECK_PATH_SEPARATOR])
522AC_REQUIRE([_XC_CFG_PRE_POSTLUDE])
524m4_pattern_forbid([^_*XC])
525m4_define([$0],[])
526])
529dnl Override autoconf and libtool PATH_SEPARATOR check
530dnl -------------------------------------------------
531dnl Macros overriding.
532dnl
533dnl This is done to ensure that the same check is
534dnl used across different autoconf versions and to
535dnl allow expansion of XC_CONFIGURE_PREAMBLE macro
536dnl early enough in the generated configure script.
538dnl
539dnl Override when using autoconf 2.53 and newer.
540dnl
542m4_ifdef([_AS_PATH_SEPARATOR_PREPARE],
543[
544m4_undefine([_AS_PATH_SEPARATOR_PREPARE])
545m4_defun([_AS_PATH_SEPARATOR_PREPARE],
546[
547AC_REQUIRE([XC_CONFIGURE_PREAMBLE])
548m4_define([$0],[])
549])
550])
552dnl
553dnl Override when using autoconf 2.50 to 2.52
554dnl
556m4_ifdef([_AC_INIT_PREPARE_FS_SEPARATORS],
557[
558m4_undefine([_AC_INIT_PREPARE_FS_SEPARATORS])
559m4_defun([_AC_INIT_PREPARE_FS_SEPARATORS],
560[
561AC_REQUIRE([XC_CONFIGURE_PREAMBLE])
562ac_path_separator=$PATH_SEPARATOR
563m4_define([$0],[])
564])
565])
567dnl
568dnl Override when using libtool 1.4.2
569dnl
571m4_ifdef([_LT_AC_LIBTOOL_SYS_PATH_SEPARATOR],
572[
573m4_undefine([_LT_AC_LIBTOOL_SYS_PATH_SEPARATOR])
574m4_defun([_LT_AC_LIBTOOL_SYS_PATH_SEPARATOR],
575[
576AC_REQUIRE([XC_CONFIGURE_PREAMBLE])
577lt_cv_sys_path_separator=$PATH_SEPARATOR
578m4_define([$0],[])
579])
580])
583dnl XC_CHECK_PATH_SEPARATOR
584dnl -------------------------------------------------
585dnl Public macro.
586dnl
587dnl Usage of this macro ensures that generated configure
588dnl script uses the same PATH_SEPARATOR check irrespective
589dnl of autoconf or libtool version being used to generate
590dnl configure script.
591dnl
592dnl Emits shell code that computes the path separator
593dnl and stores the result in 'PATH_SEPARATOR', unless
594dnl the user has already set it with a non-empty value.
595dnl
596dnl This path separator is the symbol used to separate
597dnl or differentiate paths inside the 'PATH' environment
598dnl variable.
599dnl
600dnl Non-empty user provided 'PATH_SEPARATOR' always
601dnl overrides the auto-detected one.
602dnl
603dnl Strictly speaking the check is done in two steps. The
604dnl first, which does the actual check, takes place in
605dnl XC_CONFIGURE_PREAMBLE macro and happens early in
606dnl generated configure script. The second one shows and
607dnl logs the result of the check into config.log at a later
608dnl configure stage. Placement of this second stage in
609dnl generated configure script is done where first
610dnl direct or indirect usage of this macro happens.
612AC_DEFUN([XC_CHECK_PATH_SEPARATOR],
613[
614AC_PREREQ([2.50])
616AC_BEFORE([$0],[AC_CHECK_TOOL])
617AC_BEFORE([$0],[AC_CHECK_PROG])
618AC_BEFORE([$0],[AC_CHECK_TOOLS])
619AC_BEFORE([$0],[AC_CHECK_PROGS])
621AC_BEFORE([$0],[AC_PATH_TOOL])
622AC_BEFORE([$0],[AC_PATH_PROG])
623AC_BEFORE([$0],[AC_PATH_PROGS])
625AC_BEFORE([$0],[AC_PROG_SED])
626AC_BEFORE([$0],[AC_PROG_GREP])
627AC_BEFORE([$0],[AC_PROG_LN_S])
628AC_BEFORE([$0],[AC_PROG_MKDIR_P])
629AC_BEFORE([$0],[AC_PROG_INSTALL])
630AC_BEFORE([$0],[AC_PROG_MAKE_SET])
631AC_BEFORE([$0],[AC_PROG_LIBTOOL])
633AC_BEFORE([$0],[LT_INIT])
634AC_BEFORE([$0],[AM_INIT_AUTOMAKE])
635AC_BEFORE([$0],[AC_LIBTOOL_WIN32_DLL])
637AC_REQUIRE([XC_CONFIGURE_PREAMBLE])
639dnl
640dnl Check that 'XC_CONFIGURE_PREAMBLE' has already run.
641dnl
643if test -z "$xc_configure_preamble_result"; then
644 AC_MSG_ERROR([xc_configure_preamble_result not set (internal problem)])
645fi
647dnl
648dnl Check that 'PATH_SEPARATOR' has already been set.
649dnl
651if test -z "$xc_PATH_SEPARATOR"; then
652 AC_MSG_ERROR([xc_PATH_SEPARATOR not set (internal problem)])
653fi
654if test -z "$PATH_SEPARATOR"; then
655 AC_MSG_ERROR([PATH_SEPARATOR not set (internal or config.site problem)])
656fi
657AC_MSG_CHECKING([for path separator])
658AC_MSG_RESULT([$PATH_SEPARATOR])
659if test "x$PATH_SEPARATOR" != "x$xc_PATH_SEPARATOR"; then
660 AC_MSG_CHECKING([for initial path separator])
661 AC_MSG_RESULT([$xc_PATH_SEPARATOR])
662 AC_MSG_ERROR([path separator mismatch (internal or config.site problem)])
663fi
665m4_pattern_forbid([^_*XC])
666m4_define([$0],[])
667])
Diagnostics4 git calls · 25 ms
CallStatusSizeTime025 ms
discover200152 B3 ms
git.upload-pack discover http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=2 git.response.bytes=152 git.server.agent=gitty/1.0 git.server.object_format=sha1 git.server.caps=agent ls-refs fetch object-format git.server.fetch=shallow filter sideband-all git.protocol.version=2 git.pkt.frames=8 git.pkt.data=6 git.pkt.flush=2 git.pkt.delim=0 git.pkt.bytes=152 git.pkt.payload.max=34
ls-refs200149 B · hit3 ms
git.upload-pack ls-refs http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=ls-refs git.upstream.dur_ms=3 git.response.bytes=149 git.response.cache=HIT git.response.duration_ms=3 git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=149 git.pkt.payload.max=78 git.ls_refs.count=2 git.ls_refs.head=refs/heads/master
fetchblob:none · deepen 10200287 KiB · hit4 ms
git.upload-pack fetch http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=18 git.response.bytes=293470 git.response.cache=HIT git.response.duration_ms=4 git.fetch.filter=blob:none git.fetch.filter.requested=tree:0 git.fetch.filter.fallback=blob:none git.fetch.filter.learned=false git.fetch.wants=31c911efe5652725e930f4d2e60c9060e5f6646d git.fetch.haves.count=0 git.fetch.deepen=10 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=10 git.pkt.data=8 git.pkt.flush=1 git.pkt.delim=1 git.pkt.bytes=293470 git.pkt.payload.max=65516 git.sideband.band1.bytes=293354 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0 git.pack.objects=87 git.pack.bytes=293354 git.pack.ofs_delta=0 git.pack.ref_delta=1 git.pack.chain.max=1 git.pack.trailer=6a646bcda6740bab42e321b51998b52ea15146c0 git.pack.full=86Open pack map
fetch2004.2 KiB · hit18 ms
git.upload-pack fetch http.response.status_code=200 git.response.bytes=4301 git.response.cache=HIT git.response.duration_ms=18 git.fetch.wants=2713dcc8cb52753217a4078061eb47224bea19af git.fetch.haves.count=0 git.fetch.deepen=0 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=4301 git.pkt.payload.max=4280 git.sideband.band1.bytes=4279 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0
Each row is one HTTP round trip ply made to the git server for this page, on one timeline. discover asks what the server speaks, ls-refs lists branch tips, fetch brings objects by id. A hit was served by Workers Cache. Tap a row for its wire details.
- Remote
- https://5ad2236b39de4c8bd8f6270ea63f3ea9.artifacts.cloudflare.net/git/public-v0/curl.git
- Ref
- refs/heads/master
- Commit
- 31c911efe5652725e930f4d2e60c9060e5f6646d
- cf-ray
- a5e3a80eadd02a83
- Request
- bc76eccc…
- Protocol
- v2 · sha1
- Agent
- gitty/1.0
- Filter
- advertised
- Fetch
- shallow filter sideband-all
- Capabilities
- agent ls-refs fetch object-format