master
1#***************************************************************************
2# _ _ ____ _
3# Project ___| | | | _ \| |
4# / __| | | | |_) | |
5# | (__| |_| | _ <| |___
6# \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
13#
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
17#
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
20#
21# SPDX-License-Identifier: curl
22#
23#***************************************************************************
25AC_DEFUN([CURL_WITH_WOLFSSL], [
26dnl ----------------------------------------------------
27dnl check for wolfSSL
28dnl ----------------------------------------------------
30case "$OPT_WOLFSSL" in
31 yes|no)
32 wolfpkg=""
33 ;;
34 *)
35 wolfpkg="$OPT_WOLFSSL/lib/pkgconfig"
36 ;;
37esac
39if test "$OPT_WOLFSSL" != "no"; then
40 _cppflags=$CPPFLAGS
41 _ldflags=$LDFLAGS
42 _ldflagspc=$LDFLAGSPC
44 ssl_msg=
46 if test "$OPT_WOLFSSL" = "yes"; then
47 OPT_WOLFSSL=""
48 fi
50 dnl try pkg-config magic
51 CURL_CHECK_PKGCONFIG(wolfssl, [$wolfpkg])
52 AC_MSG_NOTICE([Check directory $wolfpkg])
54 addld=""
55 addlib=""
56 addcflags=""
57 if test "$PKGCONFIG" != "no"; then
58 addlib=`CURL_EXPORT_PCDIR([$wolfpkg])
59 $PKGCONFIG --libs-only-l wolfssl`
60 addld=`CURL_EXPORT_PCDIR([$wolfpkg])
61 $PKGCONFIG --libs-only-L wolfssl`
62 addcflags=`CURL_EXPORT_PCDIR([$wolfpkg])
63 $PKGCONFIG --cflags-only-I wolfssl`
64 version=`CURL_EXPORT_PCDIR([$wolfpkg])
65 $PKGCONFIG --modversion wolfssl`
66 wolfssllibpath=`echo $addld | $SED -e 's/^-L//'`
67 else
68 addlib=-lwolfssl
69 dnl use system defaults if user does not supply a path
70 if test -n "$OPT_WOLFSSL"; then
71 addld=-L$OPT_WOLFSSL/lib$libsuff
72 addcflags=-I$OPT_WOLFSSL/include
73 wolfssllibpath=$OPT_WOLFSSL/lib$libsuff
74 fi
75 fi
77 if test "$curl_cv_apple" = "yes"; then
78 addlib="$addlib -framework Security -framework CoreFoundation"
79 elif test "$curl_cv_native_windows" = "yes"; then
80 addlib="$addlib -lcrypt32"
81 else
82 addlib="$addlib -lm"
83 fi
85 if test "$USE_WOLFSSL" != "yes"; then
86 CPPFLAGS="$CPPFLAGS -DWOLFSSL_OPTIONS_IGNORE_SYS"
88 LDFLAGS="$LDFLAGS $addld"
89 LDFLAGSPC="$LDFLAGSPC $addld"
90 AC_MSG_NOTICE([Add $addld to LDFLAGS])
91 if test "$addcflags" != "-I/usr/include"; then
92 CPPFLAGS="$CPPFLAGS $addcflags"
93 AC_MSG_NOTICE([Add $addcflags to CPPFLAGS])
94 fi
96 my_ac_save_LIBS="$LIBS"
97 LIBS="$addlib $LIBS"
98 AC_MSG_NOTICE([Add $addlib to LIBS])
100 AC_MSG_CHECKING([for wolfSSL_Init in -lwolfssl])
101 AC_LINK_IFELSE([
102 AC_LANG_PROGRAM([[
103 #include <wolfssl/options.h>
104 #include <wolfssl/ssl.h>
105 ]],[[
106 return wolfSSL_Init();
107 ]])
108 ],[
109 AC_MSG_RESULT(yes)
110 AC_DEFINE(USE_WOLFSSL, 1, [if wolfSSL is enabled])
111 WOLFSSL_ENABLED=1
112 USE_WOLFSSL="yes"
113 ssl_msg="wolfSSL"
114 test "wolfssl" != "$DEFAULT_SSL_BACKEND" || VALID_DEFAULT_SSL_BACKEND=yes
115 ],
116 [
117 AC_MSG_RESULT(no)
118 CPPFLAGS=$_cppflags
119 LDFLAGS=$_ldflags
120 LDFLAGSPC=$_ldflagspc
121 wolfssllibpath=""
122 ])
123 LIBS="$my_ac_save_LIBS"
124 fi
126 if test "$USE_WOLFSSL" = "yes"; then
127 AC_MSG_NOTICE([detected wolfSSL])
128 check_for_ca_bundle=1
130 LIBS="$addlib $LIBS"
132 dnl is this wolfSSL providing the original QUIC API?
133 AC_CHECK_FUNCS([wolfSSL_set_quic_use_legacy_codepoint], [QUIC_ENABLED=yes])
135 dnl wolfSSL needs configure --enable-opensslextra to have *get_peer*
136 dnl wc_Des_EcbEncrypt is needed for NTLM support.
137 dnl if wolfSSL_BIO_set_shutdown is present, we have the full BIO feature set
138 AC_CHECK_FUNCS(wolfSSL_get_peer_certificate \
139 wolfSSL_UseALPN \
140 wolfSSL_BIO_new \
141 wolfSSL_BIO_set_shutdown \
142 wc_Des_EcbEncrypt)
144 dnl if this symbol is present, we want the include path to include the
145 dnl OpenSSL API root as well
146 if test "$ac_cv_func_wc_Des_EcbEncrypt" = "yes"; then
147 HAVE_WC_DES_ECBENCRYPT=1
148 fi
150 dnl if this symbol is present, we can make use of BIO filter chains
151 if test "$ac_cv_func_wolfSSL_BIO_new" = "yes"; then
152 HAVE_WOLFSSL_BIO_NEW=1
153 fi
155 if test -n "$wolfssllibpath"; then
156 dnl when shared libs were found in a path that the runtime
157 dnl linker does not search through, we need to add it to
158 dnl CURL_LIBRARY_PATH to prevent further configure tests to fail
159 dnl due to this
160 if test "$cross_compiling" != "yes"; then
161 CURL_LIBRARY_PATH="$CURL_LIBRARY_PATH:$wolfssllibpath"
162 export CURL_LIBRARY_PATH
163 AC_MSG_NOTICE([Added $wolfssllibpath to CURL_LIBRARY_PATH])
164 fi
165 fi
166 LIBCURL_PC_REQUIRES_PRIVATE="$LIBCURL_PC_REQUIRES_PRIVATE wolfssl"
167 else
168 AC_MSG_ERROR([--with-wolfssl but wolfSSL was not found or does not work])
169 fi
171 test -z "$ssl_msg" || ssl_backends="${ssl_backends:+$ssl_backends, }$ssl_msg"
172fi dnl wolfSSL not disabled
173])
Diagnostics4 git calls · 27 ms
CallStatusSizeTime027 ms
discover200152 B2 ms
git.upload-pack discover http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=2 git.response.bytes=152 git.server.agent=gitty/1.0 git.server.object_format=sha1 git.server.caps=agent ls-refs fetch object-format git.server.fetch=shallow filter sideband-all git.protocol.version=2 git.pkt.frames=8 git.pkt.data=6 git.pkt.flush=2 git.pkt.delim=0 git.pkt.bytes=152 git.pkt.payload.max=34
ls-refs200149 B · hit2 ms
git.upload-pack ls-refs http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=ls-refs git.upstream.dur_ms=2 git.response.bytes=149 git.response.cache=HIT git.response.duration_ms=2 git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=149 git.pkt.payload.max=78 git.ls_refs.count=2 git.ls_refs.head=refs/heads/master
fetchblob:none · deepen 10200287 KiB · hit3 ms
git.upload-pack fetch http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=22 git.response.bytes=293470 git.response.cache=HIT git.response.duration_ms=3 git.fetch.filter=blob:none git.fetch.filter.requested=tree:0 git.fetch.filter.fallback=blob:none git.fetch.filter.learned=false git.fetch.wants=31c911efe5652725e930f4d2e60c9060e5f6646d git.fetch.haves.count=0 git.fetch.deepen=10 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=10 git.pkt.data=8 git.pkt.flush=1 git.pkt.delim=1 git.pkt.bytes=293470 git.pkt.payload.max=65516 git.sideband.band1.bytes=293354 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0 git.pack.objects=87 git.pack.bytes=293354 git.pack.ofs_delta=0 git.pack.ref_delta=1 git.pack.chain.max=1 git.pack.trailer=6a646bcda6740bab42e321b51998b52ea15146c0 git.pack.full=86Open pack map
fetch2002.2 KiB · hit22 ms
git.upload-pack fetch http.response.status_code=200 git.response.bytes=2234 git.response.cache=HIT git.response.duration_ms=22 git.fetch.wants=29ae6b0c6cfdc845e7d5270b72559a5a59e8b80b git.fetch.haves.count=0 git.fetch.deepen=0 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=2234 git.pkt.payload.max=2213 git.sideband.band1.bytes=2212 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0
Each row is one HTTP round trip ply made to the git server for this page, on one timeline. discover asks what the server speaks, ls-refs lists branch tips, fetch brings objects by id. A hit was served by Workers Cache. Tap a row for its wire details.
- Remote
- https://5ad2236b39de4c8bd8f6270ea63f3ea9.artifacts.cloudflare.net/git/public-v0/curl.git
- Ref
- refs/heads/master
- Commit
- 31c911efe5652725e930f4d2e60c9060e5f6646d
- cf-ray
- a5e32fa45deb8821
- Request
- a319d1d4…
- Protocol
- v2 · sha1
- Agent
- gitty/1.0
- Filter
- advertised
- Fetch
- shallow filter sideband-all
- Capabilities
- agent ls-refs fetch object-format