Artifactspublic-v0

curl

master
ply4 git calls27 ms289 KiB3 cachedprotocol v2
472 lines13 KiBRaw
1#***************************************************************************
2# _ _ ____ _
3# Project ___| | | | _ \| |
4# / __| | | | |_) | |
5# | (__| |_| | _ <| |___
6# \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
21# SPDX-License-Identifier: curl
23#***************************************************************************
25dnl File version for 'aclocal' use. Keep it a single number.
26dnl serial 10
28dnl Note 1
29dnl ------
30dnl None of the CURL_CHECK_NEED_REENTRANT_* macros shall use HAVE_FOO_H to
31dnl conditionally include header files. These macros are used early in the
32dnl configure process much before header file availability is known.
35dnl CURL_CHECK_NEED_REENTRANT_ERRNO
36dnl -------------------------------------------------
37dnl Checks if the preprocessor _REENTRANT definition
38dnl makes errno available as a preprocessor macro.
40AC_DEFUN([CURL_CHECK_NEED_REENTRANT_ERRNO], [
41 AC_COMPILE_IFELSE([
42 AC_LANG_PROGRAM([[
43 #include <errno.h>
44 ]],[[
45 if(0 != errno)
46 return 1;
47 ]])
48 ],[
49 tmp_errno="yes"
50 ],[
51 tmp_errno="no"
52 ])
53 if test "$tmp_errno" = "yes"; then
54 AC_COMPILE_IFELSE([
55 AC_LANG_PROGRAM([[
56 #include <errno.h>
57 ]],[[
58 #ifdef errno
59 int dummy = 1;
60 (void)dummy;
61 #else
62 #error force compilation error
63 #endif
64 ]])
65 ],[
66 tmp_errno="errno_macro_defined"
67 ],[
68 AC_COMPILE_IFELSE([
69 AC_LANG_PROGRAM([[
70 #define _REENTRANT
71 #include <errno.h>
72 ]],[[
73 #ifdef errno
74 int dummy = 1;
75 (void)dummy;
76 #else
77 #error force compilation error
78 #endif
79 ]])
80 ],[
81 tmp_errno="errno_macro_needs_reentrant"
82 tmp_need_reentrant="yes"
83 ])
84 ])
85 fi
86])
89dnl CURL_CHECK_NEED_REENTRANT_GMTIME_R
90dnl -------------------------------------------------
91dnl Checks if the preprocessor _REENTRANT definition
92dnl makes function gmtime_r compiler visible.
94AC_DEFUN([CURL_CHECK_NEED_REENTRANT_GMTIME_R], [
95 AC_LINK_IFELSE([
96 AC_LANG_FUNC_LINK_TRY([gmtime_r])
97 ],[
98 tmp_gmtime_r="yes"
99 ],[
100 tmp_gmtime_r="no"
101 ])
102 if test "$tmp_gmtime_r" = "yes"; then
103 AC_EGREP_CPP([gmtime_r],[
104 #include <sys/types.h>
105 #include <time.h>
106 ],[
107 tmp_gmtime_r="proto_declared"
108 ],[
109 AC_EGREP_CPP([gmtime_r],[
110 #define _REENTRANT
111 #include <sys/types.h>
112 #include <time.h>
113 ],[
114 tmp_gmtime_r="proto_needs_reentrant"
115 tmp_need_reentrant="yes"
116 ])
117 ])
118 fi
119])
122dnl CURL_CHECK_NEED_REENTRANT_LOCALTIME_R
123dnl -------------------------------------------------
124dnl Checks if the preprocessor _REENTRANT definition
125dnl makes function localtime_r compiler visible.
127AC_DEFUN([CURL_CHECK_NEED_REENTRANT_LOCALTIME_R], [
128 AC_LINK_IFELSE([
129 AC_LANG_FUNC_LINK_TRY([localtime_r])
130 ],[
131 tmp_localtime_r="yes"
132 ],[
133 tmp_localtime_r="no"
134 ])
135 if test "$tmp_localtime_r" = "yes"; then
136 AC_EGREP_CPP([localtime_r],[
137 #include <sys/types.h>
138 #include <time.h>
139 ],[
140 tmp_localtime_r="proto_declared"
141 ],[
142 AC_EGREP_CPP([localtime_r],[
143 #define _REENTRANT
144 #include <sys/types.h>
145 #include <time.h>
146 ],[
147 tmp_localtime_r="proto_needs_reentrant"
148 tmp_need_reentrant="yes"
149 ])
150 ])
151 fi
152])
155dnl CURL_CHECK_NEED_REENTRANT_STRERROR_R
156dnl -------------------------------------------------
157dnl Checks if the preprocessor _REENTRANT definition
158dnl makes function strerror_r compiler visible.
160AC_DEFUN([CURL_CHECK_NEED_REENTRANT_STRERROR_R], [
161 AC_LINK_IFELSE([
162 AC_LANG_FUNC_LINK_TRY([strerror_r])
163 ],[
164 tmp_strerror_r="yes"
165 ],[
166 tmp_strerror_r="no"
167 ])
168 if test "$tmp_strerror_r" = "yes"; then
169 AC_EGREP_CPP([strerror_r],[
170 #include <sys/types.h>
171 #include <string.h>
172 ],[
173 tmp_strerror_r="proto_declared"
174 ],[
175 AC_EGREP_CPP([strerror_r],[
176 #define _REENTRANT
177 #include <sys/types.h>
178 #include <string.h>
179 ],[
180 tmp_strerror_r="proto_needs_reentrant"
181 tmp_need_reentrant="yes"
182 ])
183 ])
184 fi
185])
188dnl CURL_CHECK_NEED_REENTRANT_GETHOSTBYNAME_R
189dnl -------------------------------------------------
190dnl Checks if the preprocessor _REENTRANT definition
191dnl makes function gethostbyname_r compiler visible.
193AC_DEFUN([CURL_CHECK_NEED_REENTRANT_GETHOSTBYNAME_R], [
194 AC_LINK_IFELSE([
195 AC_LANG_FUNC_LINK_TRY([gethostbyname_r])
196 ],[
197 tmp_gethostbyname_r="yes"
198 ],[
199 tmp_gethostbyname_r="no"
200 ])
201 if test "$tmp_gethostbyname_r" = "yes"; then
202 AC_EGREP_CPP([gethostbyname_r],[
203 #include <sys/types.h>
204 #include <netdb.h>
205 ],[
206 tmp_gethostbyname_r="proto_declared"
207 ],[
208 AC_EGREP_CPP([gethostbyname_r],[
209 #define _REENTRANT
210 #include <sys/types.h>
211 #include <netdb.h>
212 ],[
213 tmp_gethostbyname_r="proto_needs_reentrant"
214 tmp_need_reentrant="yes"
215 ])
216 ])
217 fi
218])
221dnl CURL_CHECK_NEED_REENTRANT_GETPROTOBYNAME_R
222dnl -------------------------------------------------
223dnl Checks if the preprocessor _REENTRANT definition
224dnl makes function getprotobyname_r compiler visible.
226AC_DEFUN([CURL_CHECK_NEED_REENTRANT_GETPROTOBYNAME_R], [
227 AC_LINK_IFELSE([
228 AC_LANG_FUNC_LINK_TRY([getprotobyname_r])
229 ],[
230 tmp_getprotobyname_r="yes"
231 ],[
232 tmp_getprotobyname_r="no"
233 ])
234 if test "$tmp_getprotobyname_r" = "yes"; then
235 AC_EGREP_CPP([getprotobyname_r],[
236 #include <sys/types.h>
237 #include <netdb.h>
238 ],[
239 tmp_getprotobyname_r="proto_declared"
240 ],[
241 AC_EGREP_CPP([getprotobyname_r],[
242 #define _REENTRANT
243 #include <sys/types.h>
244 #include <netdb.h>
245 ],[
246 tmp_getprotobyname_r="proto_needs_reentrant"
247 tmp_need_reentrant="yes"
248 ])
249 ])
250 fi
251])
254dnl CURL_CHECK_NEED_REENTRANT_FUNCTIONS_R
255dnl -------------------------------------------------
256dnl Checks if the preprocessor _REENTRANT definition
257dnl makes several _r functions compiler visible.
258dnl Internal macro for CURL_CONFIGURE_REENTRANT.
260AC_DEFUN([CURL_CHECK_NEED_REENTRANT_FUNCTIONS_R], [
261 if test "$tmp_need_reentrant" = "no"; then
262 CURL_CHECK_NEED_REENTRANT_GMTIME_R
263 fi
264 if test "$tmp_need_reentrant" = "no"; then
265 CURL_CHECK_NEED_REENTRANT_LOCALTIME_R
266 fi
267 if test "$tmp_need_reentrant" = "no"; then
268 CURL_CHECK_NEED_REENTRANT_STRERROR_R
269 fi
270 if test "$tmp_need_reentrant" = "no"; then
271 CURL_CHECK_NEED_REENTRANT_GETHOSTBYNAME_R
272 fi
273 if test "$tmp_need_reentrant" = "no"; then
274 CURL_CHECK_NEED_REENTRANT_GETPROTOBYNAME_R
275 fi
276])
279dnl CURL_CHECK_NEED_REENTRANT_SYSTEM
280dnl -------------------------------------------------
281dnl Checks if the preprocessor _REENTRANT definition
282dnl must be unconditionally done for this platform.
283dnl Internal macro for CURL_CONFIGURE_REENTRANT.
285AC_DEFUN([CURL_CHECK_NEED_REENTRANT_SYSTEM], [
286 case $host_os in
287 solaris*)
288 tmp_need_reentrant="yes"
289 ;;
290 *)
291 tmp_need_reentrant="no"
292 ;;
293 esac
294])
297dnl CURL_CHECK_NEED_THREAD_SAFE_SYSTEM
298dnl -------------------------------------------------
299dnl Checks if the preprocessor _THREAD_SAFE definition
300dnl must be unconditionally done for this platform.
301dnl Internal macro for CURL_CONFIGURE_THREAD_SAFE.
303AC_DEFUN([CURL_CHECK_NEED_THREAD_SAFE_SYSTEM], [
304 case $host_os in
305 aix[[123]].* | aix4.[[012]].*)
306 dnl aix 4.2 and older
307 tmp_need_thread_safe="no"
308 ;;
309 aix*)
310 dnl AIX 4.3 and newer
311 tmp_need_thread_safe="yes"
312 ;;
313 *)
314 tmp_need_thread_safe="no"
315 ;;
316 esac
317])
320dnl CURL_CONFIGURE_FROM_NOW_ON_WITH_REENTRANT
321dnl -------------------------------------------------
322dnl This macro ensures that configuration tests done
323dnl after this execute with preprocessor symbol _REENTRANT
324dnl defined. This macro also ensures that the generated
325dnl config file defines NEED_REENTRANT and that in turn
326dnl curl_setup.h defines _REENTRANT.
327dnl Internal macro for CURL_CONFIGURE_REENTRANT.
329AC_DEFUN([CURL_CONFIGURE_FROM_NOW_ON_WITH_REENTRANT], [
330AC_DEFINE(NEED_REENTRANT, 1,
331 [Define to 1 if _REENTRANT preprocessor symbol must be defined.])
332cat >>confdefs.h <<_EOF
333#ifndef _REENTRANT
334# define _REENTRANT
335#endif
336_EOF
337])
340dnl CURL_CONFIGURE_FROM_NOW_ON_WITH_THREAD_SAFE
341dnl -------------------------------------------------
342dnl This macro ensures that configuration tests done
343dnl after this execute with preprocessor symbol_THREAD_SAFE
344dnl defined. This macro also ensures that the generated
345dnl config file defines NEED_THREAD_SAFE and that in turn
346dnl curl_setup.h defines _THREAD_SAFE.
347dnl Internal macro for CURL_CONFIGURE_THREAD_SAFE.
349AC_DEFUN([CURL_CONFIGURE_FROM_NOW_ON_WITH_THREAD_SAFE], [
350AC_DEFINE(NEED_THREAD_SAFE, 1,
351 [Define to 1 if _THREAD_SAFE preprocessor symbol must be defined.])
352cat >>confdefs.h <<_EOF
353#ifndef _THREAD_SAFE
354# define _THREAD_SAFE
355#endif
356_EOF
357])
360dnl CURL_CONFIGURE_REENTRANT
361dnl -------------------------------------------------
362dnl This first checks if the preprocessor _REENTRANT
363dnl symbol is already defined. If it is not currently
364dnl defined a set of checks are performed to verify
365dnl if its definition is required to make visible to
366dnl the compiler a set of *_r functions. Finally, if
367dnl _REENTRANT is already defined or needed it takes
368dnl care of making adjustments necessary to ensure
369dnl that it is defined equally for further configure
370dnl tests and generated config file.
372AC_DEFUN([CURL_CONFIGURE_REENTRANT], [
373 AC_PREREQ([2.50])
375 AC_MSG_CHECKING([if _REENTRANT is already defined])
376 AC_COMPILE_IFELSE([
377 AC_LANG_PROGRAM([[
378 ]],[[
379 #ifdef _REENTRANT
380 int dummy = 1;
381 (void)dummy;
382 #else
383 #error force compilation error
384 #endif
385 ]])
386 ],[
387 AC_MSG_RESULT([yes])
388 tmp_reentrant_initially_defined="yes"
389 ],[
390 AC_MSG_RESULT([no])
391 tmp_reentrant_initially_defined="no"
392 ])
394 if test "$tmp_reentrant_initially_defined" = "no"; then
395 AC_MSG_CHECKING([if _REENTRANT is actually needed])
396 CURL_CHECK_NEED_REENTRANT_SYSTEM
397 if test "$tmp_need_reentrant" = "no"; then
398 CURL_CHECK_NEED_REENTRANT_ERRNO
399 fi
400 if test "$tmp_need_reentrant" = "no"; then
401 CURL_CHECK_NEED_REENTRANT_FUNCTIONS_R
402 fi
403 if test "$tmp_need_reentrant" = "yes"; then
404 AC_MSG_RESULT([yes])
405 else
406 AC_MSG_RESULT([no])
407 fi
408 fi
410 AC_MSG_CHECKING([if _REENTRANT is onwards defined])
411 if test "$tmp_reentrant_initially_defined" = "yes" ||
412 test "$tmp_need_reentrant" = "yes"; then
413 CURL_CONFIGURE_FROM_NOW_ON_WITH_REENTRANT
414 AC_MSG_RESULT([yes])
415 else
416 AC_MSG_RESULT([no])
417 fi
418])
421dnl CURL_CONFIGURE_THREAD_SAFE
422dnl -------------------------------------------------
423dnl This first checks if the preprocessor _THREAD_SAFE
424dnl symbol is already defined. If it is not currently
425dnl defined a set of checks are performed to verify
426dnl if its definition is required. Finally, if
427dnl _THREAD_SAFE is already defined or needed it takes
428dnl care of making adjustments necessary to ensure
429dnl that it is defined equally for further configure
430dnl tests and generated config file.
432AC_DEFUN([CURL_CONFIGURE_THREAD_SAFE], [
433 AC_PREREQ([2.50])
435 AC_MSG_CHECKING([if _THREAD_SAFE is already defined])
436 AC_COMPILE_IFELSE([
437 AC_LANG_PROGRAM([[
438 ]],[[
439 #ifdef _THREAD_SAFE
440 int dummy = 1;
441 (void)dummy;
442 #else
443 #error force compilation error
444 #endif
445 ]])
446 ],[
447 AC_MSG_RESULT([yes])
448 tmp_thread_safe_initially_defined="yes"
449 ],[
450 AC_MSG_RESULT([no])
451 tmp_thread_safe_initially_defined="no"
452 ])
454 if test "$tmp_thread_safe_initially_defined" = "no"; then
455 AC_MSG_CHECKING([if _THREAD_SAFE is actually needed])
456 CURL_CHECK_NEED_THREAD_SAFE_SYSTEM
457 if test "$tmp_need_thread_safe" = "yes"; then
458 AC_MSG_RESULT([yes])
459 else
460 AC_MSG_RESULT([no])
461 fi
462 fi
464 AC_MSG_CHECKING([if _THREAD_SAFE is onwards defined])
465 if test "$tmp_thread_safe_initially_defined" = "yes" ||
466 test "$tmp_need_thread_safe" = "yes"; then
467 CURL_CONFIGURE_FROM_NOW_ON_WITH_THREAD_SAFE
468 AC_MSG_RESULT([yes])
469 else
470 AC_MSG_RESULT([no])
471 fi
472])
Diagnostics4 git calls · 27 ms
CallStatusSizeTime027 ms
discover200152 B2 ms
git.upload-pack discover
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=fetch
git.upstream.dur_ms=2
git.response.bytes=152
git.server.agent=gitty/1.0
git.server.object_format=sha1
git.server.caps=agent ls-refs fetch object-format
git.server.fetch=shallow filter sideband-all
git.protocol.version=2
git.pkt.frames=8
git.pkt.data=6
git.pkt.flush=2
git.pkt.delim=0
git.pkt.bytes=152
git.pkt.payload.max=34
ls-refs200149 B · hit2 ms
git.upload-pack ls-refs
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=ls-refs
git.upstream.dur_ms=2
git.response.bytes=149
git.response.cache=HIT
git.response.duration_ms=2
git.protocol.version=2
git.pkt.frames=3
git.pkt.data=2
git.pkt.flush=1
git.pkt.delim=0
git.pkt.bytes=149
git.pkt.payload.max=78
git.ls_refs.count=2
git.ls_refs.head=refs/heads/master
fetchblob:none · deepen 10200287 KiB · hit3 ms
git.upload-pack fetch
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=fetch
git.upstream.dur_ms=22
git.response.bytes=293470
git.response.cache=HIT
git.response.duration_ms=3
git.fetch.filter=blob:none
git.fetch.filter.requested=tree:0
git.fetch.filter.fallback=blob:none
git.fetch.filter.learned=false
git.fetch.wants=31c911efe5652725e930f4d2e60c9060e5f6646d
git.fetch.haves.count=0
git.fetch.deepen=10
git.fetch.thin_pack=false
git.fetch.ofs_delta=true
git.protocol.version=2
git.pkt.frames=10
git.pkt.data=8
git.pkt.flush=1
git.pkt.delim=1
git.pkt.bytes=293470
git.pkt.payload.max=65516
git.sideband.band1.bytes=293354
git.sideband.band2.bytes=0
git.sideband.band3.bytes=0
git.pack.objects=87
git.pack.bytes=293354
git.pack.ofs_delta=0
git.pack.ref_delta=1
git.pack.chain.max=1
git.pack.trailer=6a646bcda6740bab42e321b51998b52ea15146c0
git.pack.full=86
Open pack map
fetch2002.6 KiB · hit22 ms
git.upload-pack fetch
http.response.status_code=200
git.response.bytes=2649
git.response.cache=HIT
git.response.duration_ms=22
git.fetch.wants=bf073e2ff6e319f6ed6c0ec5d25d9b2471ed2c70
git.fetch.haves.count=0
git.fetch.deepen=0
git.fetch.thin_pack=false
git.fetch.ofs_delta=true
git.protocol.version=2
git.pkt.frames=3
git.pkt.data=2
git.pkt.flush=1
git.pkt.delim=0
git.pkt.bytes=2649
git.pkt.payload.max=2628
git.sideband.band1.bytes=2627
git.sideband.band2.bytes=0
git.sideband.band3.bytes=0

Each row is one HTTP round trip ply made to the git server for this page, on one timeline. discover asks what the server speaks, ls-refs lists branch tips, fetch brings objects by id. A hit was served by Workers Cache. Tap a row for its wire details.

Remote
https://5ad2236b39de4c8bd8f6270ea63f3ea9.artifacts.cloudflare.net/git/public-v0/curl.git
Ref
refs/heads/master
Commit
31c911efe5652725e930f4d2e60c9060e5f6646d
cf-ray
a5e3734ade6722ce
Request
5ad53bb9…
Protocol
v2 · sha1
Agent
gitty/1.0
Filter
advertised
Fetch
shallow filter sideband-all
Capabilities
agent ls-refs fetch object-format