Artifactspublic-v0

curl

master
ply4 git calls43 ms291 KiB3 cachedprotocol v2
355 lines15 KiBRaw
1#***************************************************************************
2# _ _ ____ _
3# Project ___| | | | _ \| |
4# / __| | | | |_) | |
5# | (__| |_| | _ <| |___
6# \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
21# SPDX-License-Identifier: curl
23###########################################################################
25set(LIBCURL_OUTPUT_NAME "${LIB_NAME}" CACHE STRING "Basename of the curl library")
27set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS ${CURL_DEBUG_MACROS} "BUILDING_LIBCURL")
29configure_file("curl_config-cmake.h.in" "${CMAKE_CURRENT_BINARY_DIR}/curl_config.h")
31# Get CSOURCES, HHEADERS, LIB_RCFILES variables
32curl_transform_makefile_inc("Makefile.inc" "${CMAKE_CURRENT_BINARY_DIR}/Makefile.inc.cmake")
33include("${CMAKE_CURRENT_BINARY_DIR}/Makefile.inc.cmake")
35list(APPEND HHEADERS "${CMAKE_CURRENT_BINARY_DIR}/curl_config.h")
37# The rest of the build
39set_property(DIRECTORY APPEND PROPERTY INCLUDE_DIRECTORIES
40 "${PROJECT_BINARY_DIR}/lib" # for "curl_config.h"
41 "${PROJECT_SOURCE_DIR}/lib"
44if(CURL_BUILD_TESTING)
45 # special libcurlu library for unittests
46 add_library(curlu STATIC EXCLUDE_FROM_ALL ${HHEADERS} ${CSOURCES})
47 target_compile_definitions(curlu PUBLIC "CURL_STATICLIB" "UNITTESTS")
48 target_link_libraries(curlu PUBLIC ${CURL_LIBS})
49 # There is plenty of parallelism when building the testdeps target.
50 # Override the curlu batch size with the maximum to optimize performance.
51 set_target_properties(curlu PROPERTIES UNITY_BUILD ON UNITY_BUILD_BATCH_SIZE 0 C_CLANG_TIDY "")
53 add_custom_command(OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/unitprotos.h"
54 WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
55 COMMAND ${PERL_EXECUTABLE} "${PROJECT_SOURCE_DIR}/scripts/extract-unit-protos"
56 ${CSOURCES} > "${CMAKE_CURRENT_BINARY_DIR}/unitprotos.h"
57 DEPENDS "${PROJECT_SOURCE_DIR}/scripts/extract-unit-protos" ${CSOURCES}
58 VERBATIM)
59 add_custom_target(curlu-unitprotos DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/unitprotos.h")
60endif()
62## Library definition
64if(NOT DEFINED IMPORT_LIB_SUFFIX)
65 # Suffix implib name with "_imp" by default, to avoid conflicting with
66 # the generated static "libcurl.lib" (typically with MSVC).
67 if(WIN32 AND BUILD_SHARED_LIBS AND
68 CMAKE_IMPORT_LIBRARY_SUFFIX STREQUAL CMAKE_STATIC_LIBRARY_SUFFIX)
69 set(IMPORT_LIB_SUFFIX "_imp")
70 else()
71 set(IMPORT_LIB_SUFFIX "")
72 endif()
73endif()
74if(NOT DEFINED STATIC_LIB_SUFFIX)
75 set(STATIC_LIB_SUFFIX "")
76endif()
78# Detect implib static lib filename collision
79if(WIN32 AND BUILD_STATIC_LIBS AND BUILD_SHARED_LIBS AND
80 "${IMPORT_LIB_SUFFIX}${CMAKE_IMPORT_LIBRARY_SUFFIX}" STREQUAL
81 "${STATIC_LIB_SUFFIX}${CMAKE_STATIC_LIBRARY_SUFFIX}")
82 message(FATAL_ERROR "Library suffix is the same ('${STATIC_LIB_SUFFIX}${CMAKE_STATIC_LIBRARY_SUFFIX}') "
83 "for the import and static '${LIBCURL_OUTPUT_NAME}' library. "
84 "Set IMPORT_LIB_SUFFIX and/or STATIC_LIB_SUFFIX to different values, "
85 "or disable building either the shared or static library to avoid the filename collision.")
86endif()
88# Whether to do a single compilation pass for libcurl sources and reuse these
89# objects to generate both static and shared target.
90if(NOT DEFINED SHARE_LIB_OBJECT)
91 # Enable it by default on platforms where PIC is the default for both shared
92 # and static and there is a way to tell the linker which libcurl symbols it
93 # should export (vs. marking these symbols exportable at compile-time).
94 if(WIN32)
95 set(SHARE_LIB_OBJECT ON)
96 else()
97 # On other platforms, make it an option disabled by default
98 set(SHARE_LIB_OBJECT OFF)
99 endif()
100endif()
102if(SHARE_LIB_OBJECT)
103 set(LIB_OBJECT "libcurl_object")
104 add_library(${LIB_OBJECT} OBJECT ${HHEADERS} ${CSOURCES})
105 if(WIN32)
106 # Define CURL_STATICLIB always, to disable __declspec(dllexport) for
107 # exported libcurl symbols. We handle exports via libcurl.def instead.
108 # Except with symbol hiding disabled or debug mode enabled, when we export
109 # _all_ symbols from libcurl DLL, without using libcurl.def.
110 set_property(TARGET ${LIB_OBJECT} APPEND PROPERTY COMPILE_DEFINITIONS "CURL_STATICLIB")
111 endif()
112 target_link_libraries(${LIB_OBJECT} PRIVATE ${CURL_LIBS})
113 set_target_properties(${LIB_OBJECT} PROPERTIES POSITION_INDEPENDENT_CODE ON)
114 set_property(TARGET ${LIB_OBJECT} APPEND PROPERTY COMPILE_OPTIONS "${CURL_CFLAGS}")
115 if(CURL_HIDES_PRIVATE_SYMBOLS)
116 set_property(TARGET ${LIB_OBJECT} APPEND PROPERTY COMPILE_OPTIONS "${CURL_CFLAG_SYMBOLS_HIDE}")
117 set_property(TARGET ${LIB_OBJECT} APPEND PROPERTY COMPILE_DEFINITIONS "CURL_HIDDEN_SYMBOLS")
118 endif()
119 if(CURL_HAS_LTO)
120 if(CMAKE_CONFIGURATION_TYPES)
121 set_target_properties(${LIB_OBJECT} PROPERTIES
122 INTERPROCEDURAL_OPTIMIZATION_RELEASE TRUE
123 INTERPROCEDURAL_OPTIMIZATION_RELWITHDEBINFO TRUE)
124 else()
125 set_target_properties(${LIB_OBJECT} PROPERTIES INTERPROCEDURAL_OPTIMIZATION TRUE)
126 endif()
127 endif()
128 if(CURL_CLANG_TIDY)
129 set_target_properties(${LIB_OBJECT} PROPERTIES UNITY_BUILD OFF)
130 endif()
131 if(CURL_ANALYZER_CFLAGS)
132 set_target_properties(${LIB_OBJECT} PROPERTIES UNITY_BUILD OFF)
133 set_property(TARGET ${LIB_OBJECT} APPEND PROPERTY COMPILE_OPTIONS ${CURL_ANALYZER_CFLAGS})
134 endif()
135 if(CURL_CODE_COVERAGE)
136 set_property(TARGET ${LIB_OBJECT} APPEND PROPERTY COMPILE_DEFINITIONS ${CURL_COVERAGE_MACROS})
137 set_property(TARGET ${LIB_OBJECT} APPEND PROPERTY COMPILE_OPTIONS ${CURL_COVERAGE_CFLAGS})
138 endif()
140 target_include_directories(${LIB_OBJECT} INTERFACE
141 "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"
142 "$<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>")
144 set(LIB_SOURCE $<TARGET_OBJECTS:${LIB_OBJECT}>)
145else()
146 set(LIB_SOURCE ${HHEADERS} ${CSOURCES})
147endif()
149# We want it to be called libcurl on all platforms
150if(BUILD_STATIC_LIBS)
151 list(APPEND libcurl_export ${LIB_STATIC})
152 add_library(${LIB_STATIC} STATIC ${LIB_SOURCE})
153 add_library(${PROJECT_NAME}::${LIB_STATIC} ALIAS ${LIB_STATIC})
154 if(WIN32)
155 set_property(TARGET ${LIB_STATIC} APPEND PROPERTY COMPILE_DEFINITIONS "CURL_STATICLIB")
156 endif()
157 target_link_libraries(${LIB_STATIC} PRIVATE ${CURL_LIBS})
158 # Remove the "lib" prefix since the library is already named "libcurl".
159 set_target_properties(${LIB_STATIC} PROPERTIES
160 PREFIX "" OUTPUT_NAME "${LIBCURL_OUTPUT_NAME}"
161 SUFFIX "${STATIC_LIB_SUFFIX}${CMAKE_STATIC_LIBRARY_SUFFIX}"
162 INTERFACE_COMPILE_DEFINITIONS "CURL_STATICLIB")
163 set_property(TARGET ${LIB_STATIC} APPEND PROPERTY COMPILE_OPTIONS "${CURL_CFLAGS}")
164 if(CURL_HIDES_PRIVATE_SYMBOLS)
165 set_property(TARGET ${LIB_STATIC} APPEND PROPERTY COMPILE_OPTIONS "${CURL_CFLAG_SYMBOLS_HIDE}")
166 set_property(TARGET ${LIB_STATIC} APPEND PROPERTY COMPILE_DEFINITIONS "CURL_HIDDEN_SYMBOLS")
167 endif()
168 if(CURL_HAS_LTO)
169 if(CMAKE_CONFIGURATION_TYPES)
170 set_target_properties(${LIB_STATIC} PROPERTIES
171 INTERPROCEDURAL_OPTIMIZATION_RELEASE TRUE
172 INTERPROCEDURAL_OPTIMIZATION_RELWITHDEBINFO TRUE)
173 else()
174 set_target_properties(${LIB_STATIC} PROPERTIES INTERPROCEDURAL_OPTIMIZATION TRUE)
175 endif()
176 endif()
177 if(CURL_CLANG_TIDY)
178 if(BUILD_SHARED_LIBS) # disable clang-tidy for static, and limit to the shared library, if both enabled
179 set_target_properties(${LIB_STATIC} PROPERTIES C_CLANG_TIDY "")
180 else()
181 set_target_properties(${LIB_STATIC} PROPERTIES UNITY_BUILD OFF)
182 endif()
183 endif()
184 if(CURL_ANALYZER_CFLAGS)
185 set_target_properties(${LIB_STATIC} PROPERTIES UNITY_BUILD OFF)
186 set_property(TARGET ${LIB_STATIC} APPEND PROPERTY COMPILE_OPTIONS ${CURL_ANALYZER_CFLAGS})
187 endif()
188 if(CURL_CODE_COVERAGE)
189 set_property(TARGET ${LIB_STATIC} APPEND PROPERTY COMPILE_DEFINITIONS ${CURL_COVERAGE_MACROS})
190 set_property(TARGET ${LIB_STATIC} APPEND PROPERTY COMPILE_OPTIONS ${CURL_COVERAGE_CFLAGS})
191 endif()
193 target_include_directories(${LIB_STATIC} INTERFACE
194 "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"
195 "$<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>")
196endif()
198if(BUILD_SHARED_LIBS)
199 list(APPEND libcurl_export ${LIB_SHARED})
200 add_library(${LIB_SHARED} SHARED ${LIB_SOURCE})
201 add_library(${PROJECT_NAME}::${LIB_SHARED} ALIAS ${LIB_SHARED})
202 if(WIN32)
203 set_property(TARGET ${LIB_SHARED} APPEND PROPERTY SOURCES "dllmain.c")
204 set_property(TARGET ${LIB_SHARED} APPEND PROPERTY SOURCES ${LIB_RCFILES})
205 if(CURL_HIDES_PRIVATE_SYMBOLS)
206 set_property(TARGET ${LIB_SHARED} APPEND PROPERTY SOURCES "${PROJECT_SOURCE_DIR}/lib/libcurl.def")
207 endif()
208 endif()
209 target_link_libraries(${LIB_SHARED} PRIVATE ${CURL_LIBS})
210 # Remove the "lib" prefix since the library is already named "libcurl".
211 set_target_properties(${LIB_SHARED} PROPERTIES
212 PREFIX "" OUTPUT_NAME "${LIBCURL_OUTPUT_NAME}"
213 IMPORT_PREFIX "" IMPORT_SUFFIX "${IMPORT_LIB_SUFFIX}${CMAKE_IMPORT_LIBRARY_SUFFIX}"
214 POSITION_INDEPENDENT_CODE ON)
215 set_property(TARGET ${LIB_SHARED} APPEND PROPERTY COMPILE_OPTIONS "${CURL_CFLAGS}")
216 if(CURL_HIDES_PRIVATE_SYMBOLS)
217 set_property(TARGET ${LIB_SHARED} APPEND PROPERTY COMPILE_OPTIONS "${CURL_CFLAG_SYMBOLS_HIDE}")
218 set_property(TARGET ${LIB_SHARED} APPEND PROPERTY COMPILE_DEFINITIONS "CURL_HIDDEN_SYMBOLS")
219 endif()
220 if(CURL_HAS_LTO)
221 if(CMAKE_CONFIGURATION_TYPES)
222 set_target_properties(${LIB_SHARED} PROPERTIES
223 INTERPROCEDURAL_OPTIMIZATION_RELEASE TRUE
224 INTERPROCEDURAL_OPTIMIZATION_RELWITHDEBINFO TRUE)
225 else()
226 set_target_properties(${LIB_SHARED} PROPERTIES INTERPROCEDURAL_OPTIMIZATION TRUE)
227 endif()
228 endif()
229 if(CURL_CLANG_TIDY)
230 set_target_properties(${LIB_SHARED} PROPERTIES UNITY_BUILD OFF)
231 endif()
232 if(CURL_ANALYZER_CFLAGS)
233 set_target_properties(${LIB_SHARED} PROPERTIES UNITY_BUILD OFF)
234 set_property(TARGET ${LIB_SHARED} APPEND PROPERTY COMPILE_OPTIONS ${CURL_ANALYZER_CFLAGS})
235 endif()
236 if(CURL_CODE_COVERAGE)
237 set_property(TARGET ${LIB_SHARED} APPEND PROPERTY COMPILE_DEFINITIONS ${CURL_COVERAGE_MACROS})
238 set_property(TARGET ${LIB_SHARED} APPEND PROPERTY COMPILE_OPTIONS ${CURL_COVERAGE_CFLAGS})
239 set_property(TARGET ${LIB_SHARED} APPEND PROPERTY LINK_OPTIONS ${CURL_COVERAGE_LDFLAGS})
240 endif()
242 target_include_directories(${LIB_SHARED} INTERFACE
243 "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"
244 "$<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>")
246 if(CMAKE_DLL_NAME_WITH_SOVERSION OR
247 CYGWIN OR
248 APPLE OR
249 AIX OR CMAKE_SYSTEM_NAME STREQUAL "AIX" OR
250 CMAKE_SYSTEM_NAME STREQUAL "Linux" OR
251 CMAKE_SYSTEM_NAME STREQUAL "SunOS" OR
252 CMAKE_SYSTEM_NAME STREQUAL "Haiku" OR
253 CMAKE_SYSTEM_NAME STREQUAL "OHOS" OR # OpenHarmony
254 # FreeBSD comes with the a.out and ELF flavors but a.out was supported
255 # up to v3.x and ELF from v3.x. I cannot imagine someone running CMake
256 # on those ancient systems.
257 CMAKE_SYSTEM_NAME STREQUAL "FreeBSD")
258 set(_soversion_default TRUE)
259 else()
260 set(_soversion_default FALSE)
261 endif()
263 option(CURL_LIBCURL_SOVERSION "Enable libcurl SOVERSION" ${_soversion_default})
264 option(CURL_LIBCURL_VERSIONED_SYMBOLS "Enable libcurl versioned symbols" OFF)
266 if(CURL_LIBCURL_SOVERSION OR CURL_LIBCURL_VERSIONED_SYMBOLS)
267 # Get VERSIONCHANGE, VERSIONADD, VERSIONDEL, VERSIONINFO variables
268 curl_transform_makefile_inc("Makefile.soname" "${CMAKE_CURRENT_BINARY_DIR}/Makefile.soname.cmake")
269 include("${CMAKE_CURRENT_BINARY_DIR}/Makefile.soname.cmake")
271 math(EXPR _cmakesoname "${VERSIONCHANGE} - ${VERSIONDEL}")
272 set(_cmakeversion "${_cmakesoname}.${VERSIONDEL}.${VERSIONADD}")
273 endif()
275 if(CURL_LIBCURL_SOVERSION)
276 set_target_properties(${LIB_SHARED} PROPERTIES
277 VERSION "${_cmakeversion}" SOVERSION "${_cmakesoname}")
278 endif()
280 ## Versioned symbols
282 if(CURL_LIBCURL_VERSIONED_SYMBOLS)
283 if(NOT DEFINED CURL_LIBCURL_VERSIONED_SYMBOLS_PREFIX)
284 # Default to prefixes used by autotools
285 if(CURL_WITH_MULTI_SSL)
286 set(CURL_LIBCURL_VERSIONED_SYMBOLS_PREFIX "MULTISSL_")
287 elseif(CURL_USE_OPENSSL)
288 set(CURL_LIBCURL_VERSIONED_SYMBOLS_PREFIX "OPENSSL_")
289 elseif(CURL_USE_MBEDTLS)
290 set(CURL_LIBCURL_VERSIONED_SYMBOLS_PREFIX "MBEDTLS_")
291 elseif(CURL_USE_WOLFSSL)
292 set(CURL_LIBCURL_VERSIONED_SYMBOLS_PREFIX "WOLFSSL_")
293 elseif(CURL_USE_GNUTLS)
294 set(CURL_LIBCURL_VERSIONED_SYMBOLS_PREFIX "GNUTLS_")
295 elseif(CURL_USE_RUSTLS)
296 set(CURL_LIBCURL_VERSIONED_SYMBOLS_PREFIX "RUSTLS_")
297 endif()
298 endif()
299 # Generate version script for the linker, for versioned symbols.
300 # Consumed variables:
301 # CURL_LIBCURL_VERSIONED_SYMBOLS_PREFIX
302 # CURL_LIBCURL_VERSIONED_SYMBOLS_SONAME
303 set(CURL_LIBCURL_VERSIONED_SYMBOLS_SONAME ${_cmakesoname})
304 configure_file(
305 "${CMAKE_CURRENT_SOURCE_DIR}/libcurl.vers.in"
306 "${CMAKE_CURRENT_BINARY_DIR}/libcurl.vers" @ONLY)
307 include(CMakePushCheckState)
308 include(CheckCSourceCompiles)
309 cmake_push_check_state()
310 set(CMAKE_REQUIRED_LINK_OPTIONS "-Wl,--version-script=${CMAKE_CURRENT_BINARY_DIR}/libcurl.vers")
311 check_c_source_compiles("int main(void) { return 0; }" HAVE_VERSIONED_SYMBOLS)
312 if(HAVE_VERSIONED_SYMBOLS)
313 set_property(TARGET ${LIB_SHARED} APPEND PROPERTY LINK_OPTIONS "${CMAKE_REQUIRED_LINK_OPTIONS}")
314 else()
315 message(WARNING "Versioned symbols requested, but not supported by the toolchain.")
316 endif()
317 cmake_pop_check_state()
318 endif()
319endif()
321add_library(${LIB_NAME} ALIAS ${LIB_SELECTED})
322add_library(${PROJECT_NAME}::${LIB_NAME} ALIAS ${LIB_SELECTED})
324if(CURL_ENABLE_EXPORT_TARGET)
325 if(NOT CURL_DISABLE_INSTALL AND BUILD_STATIC_LIBS)
326 install(TARGETS ${LIB_STATIC}
327 EXPORT ${TARGETS_EXPORT_NAME}
328 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
329 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
330 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
331 )
332 endif()
333 if(NOT CURL_DISABLE_INSTALL AND BUILD_SHARED_LIBS)
334 install(TARGETS ${LIB_SHARED}
335 EXPORT ${TARGETS_EXPORT_NAME}
336 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
337 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
338 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
339 )
340 endif()
342 export(TARGETS ${libcurl_export}
343 FILE "${PROJECT_BINARY_DIR}/libcurl-target.cmake"
344 NAMESPACE ${PROJECT_NAME}::
345 )
346endif()
348if(PERL_EXECUTABLE)
349 add_custom_target(curl-optiontable
350 COMMENT "Generating lib/easyoptions.c" VERBATIM USES_TERMINAL
351 COMMAND "${PERL_EXECUTABLE}" "${CMAKE_CURRENT_SOURCE_DIR}/optiontable.pl" "${PROJECT_SOURCE_DIR}/include/curl/curl.h"
352 > "${PROJECT_SOURCE_DIR}/lib/easyoptions.c"
353 DEPENDS "${CMAKE_CURRENT_SOURCE_DIR}/optiontable.pl" "${PROJECT_SOURCE_DIR}/include/curl/curl.h"
354 )
355endif()
Diagnostics4 git calls · 43 ms
CallStatusSizeTime043 ms
discover200152 B2 ms
git.upload-pack discover
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=ls-refs
git.upstream.dur_ms=2
git.response.bytes=152
git.server.agent=gitty/1.0
git.server.object_format=sha1
git.server.caps=agent ls-refs fetch object-format
git.server.fetch=shallow filter sideband-all
git.protocol.version=2
git.pkt.frames=8
git.pkt.data=6
git.pkt.flush=2
git.pkt.delim=0
git.pkt.bytes=152
git.pkt.payload.max=34
ls-refs200149 B · hit2 ms
git.upload-pack ls-refs
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=ls-refs
git.upstream.dur_ms=2
git.response.bytes=149
git.response.cache=HIT
git.response.duration_ms=2
git.protocol.version=2
git.pkt.frames=3
git.pkt.data=2
git.pkt.flush=1
git.pkt.delim=0
git.pkt.bytes=149
git.pkt.payload.max=78
git.ls_refs.count=2
git.ls_refs.head=refs/heads/master
fetchblob:none · deepen 10200287 KiB · hit22 ms
git.upload-pack fetch
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=fetch
git.upstream.dur_ms=3
git.response.bytes=293470
git.response.cache=HIT
git.response.duration_ms=22
git.fetch.filter=blob:none
git.fetch.filter.requested=tree:0
git.fetch.filter.fallback=blob:none
git.fetch.filter.learned=false
git.fetch.wants=31c911efe5652725e930f4d2e60c9060e5f6646d
git.fetch.haves.count=0
git.fetch.deepen=10
git.fetch.thin_pack=false
git.fetch.ofs_delta=true
git.protocol.version=2
git.pkt.frames=10
git.pkt.data=8
git.pkt.flush=1
git.pkt.delim=1
git.pkt.bytes=293470
git.pkt.payload.max=65516
git.sideband.band1.bytes=293354
git.sideband.band2.bytes=0
git.sideband.band3.bytes=0
git.pack.objects=87
git.pack.bytes=293354
git.pack.ofs_delta=0
git.pack.ref_delta=1
git.pack.chain.max=1
git.pack.trailer=6a646bcda6740bab42e321b51998b52ea15146c0
git.pack.full=86
Open pack map
fetch2004.1 KiB · hit19 ms
git.upload-pack fetch
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=fetch
git.upstream.dur_ms=19
git.response.bytes=4241
git.response.cache=HIT
git.response.duration_ms=19
git.fetch.wants=c202a6c6d752b512d1207b04d9fdacdcde92bae5
git.fetch.haves.count=0
git.fetch.deepen=0
git.fetch.thin_pack=false
git.fetch.ofs_delta=true
git.protocol.version=2
git.pkt.frames=3
git.pkt.data=2
git.pkt.flush=1
git.pkt.delim=0
git.pkt.bytes=4241
git.pkt.payload.max=4220
git.sideband.band1.bytes=4219
git.sideband.band2.bytes=0
git.sideband.band3.bytes=0

Each row is one HTTP round trip ply made to the git server for this page, on one timeline. discover asks what the server speaks, ls-refs lists branch tips, fetch brings objects by id. A hit was served by Workers Cache. Tap a row for its wire details.

Remote
https://5ad2236b39de4c8bd8f6270ea63f3ea9.artifacts.cloudflare.net/git/public-v0/curl.git
Ref
refs/heads/master
Commit
31c911efe5652725e930f4d2e60c9060e5f6646d
cf-ray
a5e2ee0f1ec177be
Request
ae06a85d…
Protocol
v2 · sha1
Agent
gitty/1.0
Filter
advertised
Fetch
shallow filter sideband-all
Capabilities
agent ls-refs fetch object-format