Artifactspublic-v0

curl

master
ply4 git calls258 ms291 KiB2 cachedprotocol v2
273 lines11 KiBRaw
1#***************************************************************************
2# _ _ ____ _
3# Project ___| | | | _ \| |
4# / __| | | | |_) | |
5# | (__| |_| | _ <| |___
6# \___|\___/|_| \_\_____|
7#
8# Copyright (C) David Shaw <dshaw@jabberwocky.com>
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
21# SPDX-License-Identifier: curl
23#***************************************************************************
24# LIBCURL_CHECK_CONFIG([DEFAULT-ACTION], [MINIMUM-VERSION],
25# [ACTION-IF-YES], [ACTION-IF-NO])
26# ----------------------------------------------------------
27# David Shaw <dshaw@jabberwocky.com> May-09-2006
29# Checks for libcurl. DEFAULT-ACTION is the string yes or no to
30# specify whether to default to --with-libcurl or --without-libcurl.
31# If not supplied, DEFAULT-ACTION is yes. MINIMUM-VERSION is the
32# minimum version of libcurl to accept. Pass the version as a regular
33# version number like 7.10.1. If not supplied, any version is
34# accepted. ACTION-IF-YES is a list of shell commands to run if
35# libcurl was successfully found and passed the various tests.
36# ACTION-IF-NO is a list of shell commands that are run otherwise.
37# Note that using --without-libcurl does run ACTION-IF-NO.
39# This macro #defines HAVE_LIBCURL if a working libcurl setup is
40# found, and sets @LIBCURL@ and @LIBCURL_CPPFLAGS@ to the necessary
41# values. Other useful defines are LIBCURL_FEATURE_xxx where xxx are
42# the various features supported by libcurl, and LIBCURL_PROTOCOL_yyy
43# where yyy are the various protocols supported by libcurl. Both xxx
44# and yyy are capitalized. See the list of AH_TEMPLATE macros at the top
45# of the macro for the complete list of possible defines. Shell
46# variables $libcurl_feature_xxx and $libcurl_protocol_yyy are also
47# defined to 'yes' for those features and protocols that were found.
48# Note that xxx and yyy keep the same capitalization as in the
49# curl-config list (e.g. it is "HTTP" and not "http").
51# Users may override the detected values by doing something like:
52# LIBCURL="-lcurl" LIBCURL_CPPFLAGS="-I/usr/myinclude" ./configure
54# For the sake of sanity, this macro assumes that any libcurl that is found is
55# after version 7.7.2, the first version that included the curl-config script.
56# Note that it is important for people packaging binary versions of libcurl to
57# include this script! Without curl-config, we can only guess what protocols
58# are available, or use curl_version_info to figure it out at runtime.
60AC_DEFUN([LIBCURL_CHECK_CONFIG],
62 AH_TEMPLATE([LIBCURL_FEATURE_SSL],[Defined if libcurl supports SSL])
63 AH_TEMPLATE([LIBCURL_FEATURE_KRB4],[Defined if libcurl supports KRB4])
64 AH_TEMPLATE([LIBCURL_FEATURE_IPV6],[Defined if libcurl supports IPv6])
65 AH_TEMPLATE([LIBCURL_FEATURE_LIBZ],[Defined if libcurl supports libz])
66 AH_TEMPLATE([LIBCURL_FEATURE_ASYNCHDNS],[Defined if libcurl supports AsynchDNS])
67 AH_TEMPLATE([LIBCURL_FEATURE_IDN],[Defined if libcurl supports IDN])
68 AH_TEMPLATE([LIBCURL_FEATURE_SSPI],[Defined if libcurl supports SSPI])
69 AH_TEMPLATE([LIBCURL_FEATURE_NTLM],[Defined if libcurl supports NTLM])
71 AH_TEMPLATE([LIBCURL_PROTOCOL_HTTP],[Defined if libcurl supports HTTP])
72 AH_TEMPLATE([LIBCURL_PROTOCOL_HTTPS],[Defined if libcurl supports HTTPS])
73 AH_TEMPLATE([LIBCURL_PROTOCOL_FTP],[Defined if libcurl supports FTP])
74 AH_TEMPLATE([LIBCURL_PROTOCOL_FTPS],[Defined if libcurl supports FTPS])
75 AH_TEMPLATE([LIBCURL_PROTOCOL_FILE],[Defined if libcurl supports FILE])
76 AH_TEMPLATE([LIBCURL_PROTOCOL_TELNET],[Defined if libcurl supports TELNET])
77 AH_TEMPLATE([LIBCURL_PROTOCOL_LDAP],[Defined if libcurl supports LDAP])
78 AH_TEMPLATE([LIBCURL_PROTOCOL_DICT],[Defined if libcurl supports DICT])
79 AH_TEMPLATE([LIBCURL_PROTOCOL_TFTP],[Defined if libcurl supports TFTP])
80 AH_TEMPLATE([LIBCURL_PROTOCOL_RTSP],[Defined if libcurl supports RTSP])
81 AH_TEMPLATE([LIBCURL_PROTOCOL_POP3],[Defined if libcurl supports POP3])
82 AH_TEMPLATE([LIBCURL_PROTOCOL_IMAP],[Defined if libcurl supports IMAP])
83 AH_TEMPLATE([LIBCURL_PROTOCOL_SMTP],[Defined if libcurl supports SMTP])
85 AC_ARG_WITH(libcurl,
86 AS_HELP_STRING([--with-libcurl=PREFIX],[look for the curl library in PREFIX/lib and headers in PREFIX/include]),
87 [_libcurl_with=$withval],[_libcurl_with=ifelse([$1],,[yes],[$1])])
89 if test "x$_libcurl_with" != "xno"; then
91 AC_PROG_AWK
93 _libcurl_version_parse="eval $AWK '{split(\$NF,A,\".\"); X=256*256*A[[1]]+256*A[[2]]+A[[3]]; print X;}'"
95 _libcurl_try_link=yes
97 if test -d "$_libcurl_with"; then
98 LIBCURL_CPPFLAGS="-I$withval/include"
99 _libcurl_ldflags="-L$withval/lib"
100 AC_PATH_PROG([_libcurl_config],[curl-config],[],["$withval/bin"])
101 else
102 AC_PATH_PROG([_libcurl_config],[curl-config],[],[$PATH])
103 fi
105 if test -n "$_libcurl_config"; then
106 AC_CACHE_CHECK([for the version of libcurl],
107 [libcurl_cv_lib_curl_version],
108 [libcurl_cv_lib_curl_version=`$_libcurl_config --version | $AWK '{print $[]2}'`])
110 _libcurl_version=`echo $libcurl_cv_lib_curl_version | $_libcurl_version_parse`
111 _libcurl_wanted=`echo ifelse([$2],,[0],[$2]) | $_libcurl_version_parse`
113 if test "$_libcurl_wanted" -gt 0; then
114 AC_CACHE_CHECK([for libcurl >= version $2],
115 [libcurl_cv_lib_version_ok],
116 [
117 if test "$_libcurl_version" -ge "$_libcurl_wanted"; then
118 libcurl_cv_lib_version_ok=yes
119 else
120 libcurl_cv_lib_version_ok=no
121 fi
122 ])
123 fi
125 if test "$_libcurl_wanted" -eq 0 || test "$libcurl_cv_lib_version_ok" = "yes"; then
126 if test -z "$LIBCURL_CPPFLAGS"; then
127 LIBCURL_CPPFLAGS=`$_libcurl_config --cflags`
128 fi
129 if test -z "$LIBCURL"; then
130 LIBCURL=`$_libcurl_config --libs`
132 dnl This is so silly, but Apple actually has a bug in their
133 dnl curl-config script. Fixed in Tiger, but there are still
134 dnl lots of Panther installs around.
135 case "${host}" in
136 powerpc-apple-darwin7*)
137 LIBCURL=`echo $LIBCURL | sed -e 's|-arch i386||g'`
138 ;;
139 esac
140 fi
142 dnl All curl-config scripts support --feature
143 _libcurl_features=`$_libcurl_config --feature`
145 dnl Is it modern enough to have --protocols? (7.12.4)
146 if test "$_libcurl_version" -ge 461828; then
147 _libcurl_protocols=`$_libcurl_config --protocols`
148 fi
149 else
150 _libcurl_try_link=no
151 fi
153 unset _libcurl_wanted
154 fi
156 if test "$_libcurl_try_link" = "yes"; then
158 dnl we did not find curl-config, so let's see if the user-supplied
159 dnl link line (or failing that, "-lcurl") is enough.
160 LIBCURL=${LIBCURL-"$_libcurl_ldflags -lcurl"}
162 AC_CACHE_CHECK([whether libcurl is usable],
163 [libcurl_cv_lib_curl_usable],
164 [
165 _libcurl_save_cppflags=$CPPFLAGS
166 CPPFLAGS="$LIBCURL_CPPFLAGS $CPPFLAGS"
167 _libcurl_save_libs=$LIBS
168 LIBS="$LIBCURL $LIBS"
170 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <curl/curl.h>]],[[
171 /* Try to use a few common options to force a failure if we are
172 missing symbols or cannot link. */
173 int x;
174 curl_easy_setopt(NULL,CURLOPT_URL,NULL);
175 x=CURL_ERROR_SIZE;
176 x=CURLOPT_WRITEFUNCTION;
177 x=CURLOPT_WRITEDATA;
178 x=CURLOPT_ERRORBUFFER;
179 x=CURLOPT_STDERR;
180 x=CURLOPT_VERBOSE;
181 if(x) {;}
182 ]])],libcurl_cv_lib_curl_usable=yes,libcurl_cv_lib_curl_usable=no)
184 CPPFLAGS=$_libcurl_save_cppflags
185 LIBS=$_libcurl_save_libs
186 unset _libcurl_save_cppflags
187 unset _libcurl_save_libs
188 ])
190 if test "$libcurl_cv_lib_curl_usable" = "yes"; then
192 dnl Does curl_free() exist in this version of libcurl?
193 dnl If not, fake it with free()
195 _libcurl_save_cppflags=$CPPFLAGS
196 CPPFLAGS="$CPPFLAGS $LIBCURL_CPPFLAGS"
197 _libcurl_save_libs=$LIBS
198 LIBS="$LIBS $LIBCURL"
200 AC_CHECK_DECL([curl_free],[],
201 [AC_DEFINE([curl_free],[free],
202 [Define curl_free() as free() if our version of curl lacks curl_free.])],
203 [[#include <curl/curl.h>]])
205 CPPFLAGS=$_libcurl_save_cppflags
206 LIBS=$_libcurl_save_libs
207 unset _libcurl_save_cppflags
208 unset _libcurl_save_libs
210 AC_DEFINE(HAVE_LIBCURL,1,
211 [Define to 1 if you have a functional curl library.])
212 AC_SUBST(LIBCURL_CPPFLAGS)
213 AC_SUBST(LIBCURL)
215 for _libcurl_feature in $_libcurl_features; do
216 AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_feature_$_libcurl_feature),[1])
217 eval AS_TR_SH(libcurl_feature_$_libcurl_feature)=yes
218 done
220 if test -z "$_libcurl_protocols"; then
222 dnl We do not have --protocols; assume that all
223 dnl protocols are available
224 _libcurl_protocols="HTTP FTP FILE TELNET LDAP DICT TFTP"
226 if test "$libcurl_feature_SSL" = "yes"; then
227 _libcurl_protocols="$_libcurl_protocols HTTPS"
229 dnl FTPS was not standards-compliant until version
230 dnl 7.11.0 (0x070b00 == 461568)
231 if test "$_libcurl_version" -ge 461568; then
232 _libcurl_protocols="$_libcurl_protocols FTPS"
233 fi
234 fi
236 dnl RTSP, IMAP, POP3 and SMTP were added in
237 dnl 7.20.0 (0x071400 == 463872)
238 if test "$_libcurl_version" -ge 463872; then
239 _libcurl_protocols="$_libcurl_protocols RTSP IMAP POP3 SMTP"
240 fi
241 fi
243 for _libcurl_protocol in $_libcurl_protocols; do
244 AC_DEFINE_UNQUOTED(AS_TR_CPP(libcurl_protocol_$_libcurl_protocol),[1])
245 eval AS_TR_SH(libcurl_protocol_$_libcurl_protocol)=yes
246 done
247 else
248 unset LIBCURL
249 unset LIBCURL_CPPFLAGS
250 fi
251 fi
253 unset _libcurl_try_link
254 unset _libcurl_version_parse
255 unset _libcurl_config
256 unset _libcurl_feature
257 unset _libcurl_features
258 unset _libcurl_protocol
259 unset _libcurl_protocols
260 unset _libcurl_version
261 unset _libcurl_ldflags
262 fi
264 if test "x$_libcurl_with" = "xno" || test "$libcurl_cv_lib_curl_usable" != "yes"; then
265 dnl This is the IF-NO path
266 ifelse([$4],,:,[$4])
267 else
268 dnl This is the IF-YES path
269 ifelse([$3],,:,[$3])
270 fi
272 unset _libcurl_with
273])
Diagnostics4 git calls · 258 ms
CallStatusSizeTime0258 ms
discover200152 B3 ms
git.upload-pack discover
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=fetch
git.upstream.dur_ms=2
git.response.bytes=152
git.server.agent=gitty/1.0
git.server.object_format=sha1
git.server.caps=agent ls-refs fetch object-format
git.server.fetch=shallow filter sideband-all
git.protocol.version=2
git.pkt.frames=8
git.pkt.data=6
git.pkt.flush=2
git.pkt.delim=0
git.pkt.bytes=152
git.pkt.payload.max=34
ls-refs200149 B · hit3 ms
git.upload-pack ls-refs
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=ls-refs
git.upstream.dur_ms=3
git.response.bytes=149
git.response.cache=HIT
git.response.duration_ms=3
git.protocol.version=2
git.pkt.frames=3
git.pkt.data=2
git.pkt.flush=1
git.pkt.delim=0
git.pkt.bytes=149
git.pkt.payload.max=78
git.ls_refs.count=2
git.ls_refs.head=refs/heads/master
fetchblob:none · deepen 10200287 KiB · hit2 ms
git.upload-pack fetch
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=fetch
git.upstream.dur_ms=253
git.response.bytes=293470
git.response.cache=HIT
git.response.duration_ms=2
git.fetch.filter=blob:none
git.fetch.filter.requested=tree:0
git.fetch.filter.fallback=blob:none
git.fetch.filter.learned=false
git.fetch.wants=31c911efe5652725e930f4d2e60c9060e5f6646d
git.fetch.haves.count=0
git.fetch.deepen=10
git.fetch.thin_pack=false
git.fetch.ofs_delta=true
git.protocol.version=2
git.pkt.frames=10
git.pkt.data=8
git.pkt.flush=1
git.pkt.delim=1
git.pkt.bytes=293470
git.pkt.payload.max=65516
git.sideband.band1.bytes=293354
git.sideband.band2.bytes=0
git.sideband.band3.bytes=0
git.pack.objects=87
git.pack.bytes=293354
git.pack.ofs_delta=0
git.pack.ref_delta=1
git.pack.chain.max=1
git.pack.trailer=6a646bcda6740bab42e321b51998b52ea15146c0
git.pack.full=86
Open pack map
fetch2003.6 KiB253 ms
git.upload-pack fetch
http.response.status_code=200
git.response.bytes=3724
git.response.cache=MISS
git.response.duration_ms=253
git.fetch.wants=7f8211bc9ac8514849097b9252fb8e96716adf99
git.fetch.haves.count=0
git.fetch.deepen=0
git.fetch.thin_pack=false
git.fetch.ofs_delta=true
git.protocol.version=2
git.pkt.frames=3
git.pkt.data=2
git.pkt.flush=1
git.pkt.delim=0
git.pkt.bytes=3724
git.pkt.payload.max=3703
git.sideband.band1.bytes=3702
git.sideband.band2.bytes=0
git.sideband.band3.bytes=0

Each row is one HTTP round trip ply made to the git server for this page, on one timeline. discover asks what the server speaks, ls-refs lists branch tips, fetch brings objects by id. A hit was served by Workers Cache. Tap a row for its wire details.

Remote
https://5ad2236b39de4c8bd8f6270ea63f3ea9.artifacts.cloudflare.net/git/public-v0/curl.git
Ref
refs/heads/master
Commit
31c911efe5652725e930f4d2e60c9060e5f6646d
cf-ray
a5e33bd3bfbadafe
Request
24b77b84…
Protocol
v2 · sha1
Agent
gitty/1.0
Filter
advertised
Fetch
shallow filter sideband-all
Capabilities
agent ls-refs fetch object-format