Artifactspublic-v0

curl

master
ply4 git calls137 ms289 KiB2 cachedprotocol v2
92 lines4.4 KiBRaw
1#***************************************************************************
2# _ _ ____ _
3# Project ___| | | | _ \| |
4# / __| | | | |_) | |
5# | (__| |_| | _ <| |___
6# \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
21# SPDX-License-Identifier: curl
23###########################################################################
24add_custom_target(curl-examples)
26# Get check_PROGRAMS, COMPLICATED_MAY_BUILD, COMPLICATED_EXAMPLES variables
27curl_transform_makefile_inc("Makefile.inc" "${CMAKE_CURRENT_BINARY_DIR}/Makefile.inc.cmake")
28include("${CMAKE_CURRENT_BINARY_DIR}/Makefile.inc.cmake")
30set(_with_deps "")
31set(_all_src "")
32set(_all_canary "")
33set(_all "all")
34foreach(_target IN LISTS COMPLICATED_MAY_BUILD check_PROGRAMS _all) # keep 'COMPLICATED_MAY_BUILD' first, and '_all' last
35 # Strip .c suffix from COMPLICATED_MAY_BUILD items
36 if(CMAKE_VERSION VERSION_GREATER_EQUAL 3.20)
37 cmake_path(GET _target STEM _target)
38 else()
39 get_filename_component(_target "${_target}" NAME_WE)
40 endif()
41 set(_more_libs "")
42 set(_target_name "curl-example-${_target}")
43 if(_target STREQUAL "all")
44 add_library(${_target_name} OBJECT EXCLUDE_FROM_ALL ${_all_src})
45 if(CMAKE_C_COMPILER_ID STREQUAL "MSVC") # MSVC but exclude clang-cl
46 # CMake generates a static library for the OBJECT target. Silence these 'lib.exe' warnings:
47 # warning LNK4006: main already defined in ....obj; second definition ignored
48 # warning LNK4221: This object file does not define any previously undefined public symbols,
49 # [...] not be used by any link operation that consumes this library
50 set_target_properties(${_target_name} PROPERTIES STATIC_LIBRARY_OPTIONS "-ignore:4006;-ignore:4221")
51 endif()
52 if(_with_deps)
53 set(_more_libs ${CURL_LIBS}) # If any examples required dependencies, link them
54 endif()
55 add_custom_target(curl-examples-build) # Special target to compile all tests quickly and build a single test to probe linkage
56 add_dependencies(curl-examples-build ${_target_name} ${_all_canary}) # Include a full build of a single test
57 else()
58 # Check if the example requires a build option. Then check if that build option is enabled.
59 # If it is, link all dependencies to the example.
60 set(_requires_regex "/\\* Requires: ([A-Z0-9_]+) \\*/")
61 file(STRINGS "${_target}.c" _req REGEX "${_requires_regex}")
62 string(REGEX REPLACE "${_requires_regex}" "\\1" _req "${_req}")
63 if(_req)
64 if(${${_req}})
65 string(APPEND _with_deps " ${_target}:${_req}")
66 set(_more_libs ${CURL_LIBS})
67 else()
68 continue() # Option required, but not found
69 endif()
70 endif()
71 set(_all_canary ${_target_name}) # Save the last test for the curl-examples-build target
72 list(APPEND _all_src "${_target}.c")
73 add_executable(${_target_name} EXCLUDE_FROM_ALL "${_target}.c")
74 add_dependencies(curl-examples ${_target_name})
75 endif()
76 target_link_libraries(${_target_name} ${LIB_SELECTED} ${CURL_NETWORK_AND_TIME_LIBS} ${_more_libs})
77 target_compile_definitions(${_target_name} PRIVATE "CURL_NO_OLDIES" "$<$<BOOL:${WIN32}>:WIN32_LEAN_AND_MEAN>")
78 if(CURL_ANALYZER_CFLAGS)
79 set_property(TARGET ${_target_name} APPEND PROPERTY COMPILE_OPTIONS ${CURL_ANALYZER_CFLAGS})
80 endif()
81 set_target_properties(${_target_name} PROPERTIES OUTPUT_NAME "${_target}" PROJECT_LABEL "Example ${_target}" UNITY_BUILD OFF)
82endforeach()
84if(_with_deps)
85 message(STATUS "Enabled examples with dependencies:${_with_deps}")
86endif()
88if(CURL_BUILD_EVERYTHING STREQUAL "QUICK")
89 set_target_properties(curl-examples-build PROPERTIES EXCLUDE_FROM_ALL FALSE)
90elseif(CURL_BUILD_EVERYTHING AND NOT CURL_BUILD_EVERYTHING STREQUAL "NOEXAMPLES")
91 set_target_properties(curl-examples PROPERTIES EXCLUDE_FROM_ALL FALSE)
92endif()
Diagnostics4 git calls · 137 ms
CallStatusSizeTime0137 ms
discover200152 B3 ms
git.upload-pack discover
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=ls-refs
git.upstream.dur_ms=3
git.response.bytes=152
git.server.agent=gitty/1.0
git.server.object_format=sha1
git.server.caps=agent ls-refs fetch object-format
git.server.fetch=shallow filter sideband-all
git.protocol.version=2
git.pkt.frames=8
git.pkt.data=6
git.pkt.flush=2
git.pkt.delim=0
git.pkt.bytes=152
git.pkt.payload.max=34
ls-refs200149 B · hit3 ms
git.upload-pack ls-refs
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=ls-refs
git.upstream.dur_ms=3
git.response.bytes=149
git.response.cache=HIT
git.response.duration_ms=3
git.protocol.version=2
git.pkt.frames=3
git.pkt.data=2
git.pkt.flush=1
git.pkt.delim=0
git.pkt.bytes=149
git.pkt.payload.max=78
git.ls_refs.count=2
git.ls_refs.head=refs/heads/master
fetchblob:none · deepen 10200287 KiB · hit3 ms
git.upload-pack fetch
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=fetch
git.upstream.dur_ms=2
git.response.bytes=293470
git.response.cache=HIT
git.response.duration_ms=3
git.fetch.filter=blob:none
git.fetch.filter.requested=tree:0
git.fetch.filter.fallback=blob:none
git.fetch.filter.learned=false
git.fetch.wants=31c911efe5652725e930f4d2e60c9060e5f6646d
git.fetch.haves.count=0
git.fetch.deepen=10
git.fetch.thin_pack=false
git.fetch.ofs_delta=true
git.protocol.version=2
git.pkt.frames=10
git.pkt.data=8
git.pkt.flush=1
git.pkt.delim=1
git.pkt.bytes=293470
git.pkt.payload.max=65516
git.sideband.band1.bytes=293354
git.sideband.band2.bytes=0
git.sideband.band3.bytes=0
git.pack.objects=87
git.pack.bytes=293354
git.pack.ofs_delta=0
git.pack.ref_delta=1
git.pack.chain.max=1
git.pack.trailer=6a646bcda6740bab42e321b51998b52ea15146c0
git.pack.full=86
Open pack map
fetch2002.0 KiB131 ms
git.upload-pack fetch
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=fetch
git.upstream.dur_ms=131
git.response.bytes=2013
git.response.cache=MISS
git.response.duration_ms=131
git.fetch.wants=dc3313d6a27580de6cc14b7df1075211615cfb22
git.fetch.haves.count=0
git.fetch.deepen=0
git.fetch.thin_pack=false
git.fetch.ofs_delta=true
git.protocol.version=2
git.pkt.frames=3
git.pkt.data=2
git.pkt.flush=1
git.pkt.delim=0
git.pkt.bytes=2013
git.pkt.payload.max=1992
git.sideband.band1.bytes=1991
git.sideband.band2.bytes=0
git.sideband.band3.bytes=0

Each row is one HTTP round trip ply made to the git server for this page, on one timeline. discover asks what the server speaks, ls-refs lists branch tips, fetch brings objects by id. A hit was served by Workers Cache. Tap a row for its wire details.

Remote
https://5ad2236b39de4c8bd8f6270ea63f3ea9.artifacts.cloudflare.net/git/public-v0/curl.git
Ref
refs/heads/master
Commit
31c911efe5652725e930f4d2e60c9060e5f6646d
cf-ray
a5e2d89a8e4814c2
Request
57a2c623…
Protocol
v2 · sha1
Agent
gitty/1.0
Filter
advertised
Fetch
shallow filter sideband-all
Capabilities
agent ls-refs fetch object-format