Artifactspublic-v0

curl

master
ply4 git calls26 ms289 KiB3 cachedprotocol v2
151 lines4.6 KiBRaw
1#***************************************************************************
2# _ _ ____ _
3# Project ___| | | | _ \| |
4# / __| | | | |_) | |
5# | (__| |_| | _ <| |___
6# \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
21# SPDX-License-Identifier: curl
23###########################################################################
24include(CheckCSourceCompiles)
25include(CheckCSourceRuns)
26include(CheckTypeSize)
28# #include header if condition is true
29macro(curl_add_header_include _check _header)
30 if(${_check})
31 set(_source_epilogue "${_source_epilogue}
32 #include <${_header}>")
33 endif()
34endmacro()
36set(_cmake_try_compile_target_type_save ${CMAKE_TRY_COMPILE_TARGET_TYPE})
37set(CMAKE_TRY_COMPILE_TARGET_TYPE "STATIC_LIBRARY")
39if(NOT DEFINED HAVE_STRUCT_SOCKADDR_STORAGE)
40 cmake_push_check_state()
41 set(CMAKE_EXTRA_INCLUDE_FILES "")
42 if(WIN32)
43 set(CMAKE_EXTRA_INCLUDE_FILES "winsock2.h")
44 list(APPEND CMAKE_REQUIRED_LIBRARIES "ws2_32")
45 else()
46 set(CMAKE_EXTRA_INCLUDE_FILES "sys/socket.h")
47 endif()
48 check_type_size("struct sockaddr_storage" SIZEOF_STRUCT_SOCKADDR_STORAGE)
49 set(HAVE_STRUCT_SOCKADDR_STORAGE ${HAVE_SIZEOF_STRUCT_SOCKADDR_STORAGE})
50 cmake_pop_check_state()
51endif()
53set(_source_epilogue "#undef inline")
54check_c_source_compiles("${_source_epilogue}
55 #ifdef _MSC_VER
56 #include <winsock2.h>
57 #endif
58 #ifndef _WIN32
59 #include <sys/time.h>
60 #endif
61 #include <time.h>
62 int main(void)
63 {
64 struct timeval ts;
65 ts.tv_sec = 0;
66 ts.tv_usec = 0;
67 (void)ts;
68 return 0;
69 }" HAVE_STRUCT_TIMEVAL)
71set(CMAKE_TRY_COMPILE_TARGET_TYPE ${_cmake_try_compile_target_type_save})
72unset(_cmake_try_compile_target_type_save)
74# Detect HAVE_GETADDRINFO_THREADSAFE
76if(WIN32)
77 set(HAVE_GETADDRINFO_THREADSAFE ${HAVE_GETADDRINFO})
78elseif(NOT HAVE_GETADDRINFO)
79 set(HAVE_GETADDRINFO_THREADSAFE FALSE)
80elseif(APPLE OR # Darwin 9+ / macOS 10.5+
81 AIX OR CMAKE_SYSTEM_NAME STREQUAL "AIX" OR # 5.2+
82 CMAKE_SYSTEM_NAME STREQUAL "DragonFlyBSD" OR # 2.2.0+
83 CMAKE_SYSTEM_NAME STREQUAL "FreeBSD" OR # 5.5+
84 CMAKE_SYSTEM_NAME STREQUAL "HP-UX" OR # 11.11+
85 CMAKE_SYSTEM_NAME STREQUAL "MidnightBSD" OR # all versions
86 CMAKE_SYSTEM_NAME STREQUAL "NetBSD" OR # 4+
87 CMAKE_SYSTEM_NAME STREQUAL "OpenBSD" OR # 5.4+
88 CMAKE_SYSTEM_NAME STREQUAL "SunOS")
89 set(HAVE_GETADDRINFO_THREADSAFE TRUE)
90elseif(BSD OR CMAKE_SYSTEM_NAME MATCHES "BSD")
91 set(HAVE_GETADDRINFO_THREADSAFE FALSE)
92endif()
94if(NOT DEFINED HAVE_GETADDRINFO_THREADSAFE)
95 set(_source_epilogue "#undef inline
96 #ifndef _WIN32
97 #include <sys/socket.h>
98 #include <sys/time.h>
99 #endif")
100 curl_add_header_include(HAVE_NETDB_H "netdb.h")
101 check_c_source_compiles("${_source_epilogue}
102 int main(void)
103 {
104 #ifndef h_errno
105 #error force compilation error
106 #endif
107 return 0;
108 }" HAVE_H_ERRNO)
110 if(NOT HAVE_H_ERRNO)
111 check_c_source_compiles("${_source_epilogue}
112 int main(void)
113 {
114 h_errno = 2;
115 return h_errno != 0 ? 1 : 0;
116 }" HAVE_H_ERRNO_ASSIGNABLE)
118 if(NOT HAVE_H_ERRNO_ASSIGNABLE)
119 check_c_source_compiles("${_source_epilogue}
120 int main(void)
121 {
122 #if defined(_POSIX_C_SOURCE) && (_POSIX_C_SOURCE >= 200809L)
123 #elif defined(_XOPEN_SOURCE) && (_XOPEN_SOURCE >= 700)
124 #else
125 #error force compilation error
126 #endif
127 return 0;
128 }" HAVE_H_ERRNO_SBS_ISSUE_7)
129 endif()
130 endif()
132 if(HAVE_H_ERRNO OR HAVE_H_ERRNO_ASSIGNABLE OR HAVE_H_ERRNO_SBS_ISSUE_7)
133 set(HAVE_GETADDRINFO_THREADSAFE TRUE)
134 endif()
135endif()
137if(NOT WIN32 AND NOT DEFINED HAVE_CLOCK_GETTIME_MONOTONIC_RAW)
138 set(_source_epilogue "#undef inline")
139 curl_add_header_include(HAVE_SYS_TYPES_H "sys/types.h")
140 check_c_source_compiles("${_source_epilogue}
141 #include <sys/time.h>
142 #include <time.h>
143 int main(void)
144 {
145 struct timespec ts;
146 (void)clock_gettime(CLOCK_MONOTONIC_RAW, &ts);
147 return 0;
148 }" HAVE_CLOCK_GETTIME_MONOTONIC_RAW)
149endif()
151unset(_source_epilogue)
Diagnostics4 git calls · 26 ms
CallStatusSizeTime026 ms
discover200152 B3 ms
git.upload-pack discover
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=fetch
git.upstream.dur_ms=3
git.response.bytes=152
git.server.agent=gitty/1.0
git.server.object_format=sha1
git.server.caps=agent ls-refs fetch object-format
git.server.fetch=shallow filter sideband-all
git.protocol.version=2
git.pkt.frames=8
git.pkt.data=6
git.pkt.flush=2
git.pkt.delim=0
git.pkt.bytes=152
git.pkt.payload.max=34
ls-refs200149 B · hit3 ms
git.upload-pack ls-refs
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=ls-refs
git.upstream.dur_ms=3
git.response.bytes=149
git.response.cache=HIT
git.response.duration_ms=3
git.protocol.version=2
git.pkt.frames=3
git.pkt.data=2
git.pkt.flush=1
git.pkt.delim=0
git.pkt.bytes=149
git.pkt.payload.max=78
git.ls_refs.count=2
git.ls_refs.head=refs/heads/master
fetchblob:none · deepen 10200287 KiB · hit3 ms
git.upload-pack fetch
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=fetch
git.upstream.dur_ms=20
git.response.bytes=293470
git.response.cache=HIT
git.response.duration_ms=3
git.fetch.filter=blob:none
git.fetch.filter.requested=tree:0
git.fetch.filter.fallback=blob:none
git.fetch.filter.learned=false
git.fetch.wants=31c911efe5652725e930f4d2e60c9060e5f6646d
git.fetch.haves.count=0
git.fetch.deepen=10
git.fetch.thin_pack=false
git.fetch.ofs_delta=true
git.protocol.version=2
git.pkt.frames=10
git.pkt.data=8
git.pkt.flush=1
git.pkt.delim=1
git.pkt.bytes=293470
git.pkt.payload.max=65516
git.sideband.band1.bytes=293354
git.sideband.band2.bytes=0
git.sideband.band3.bytes=0
git.pack.objects=87
git.pack.bytes=293354
git.pack.ofs_delta=0
git.pack.ref_delta=1
git.pack.chain.max=1
git.pack.trailer=6a646bcda6740bab42e321b51998b52ea15146c0
git.pack.full=86
Open pack map
fetch2001.7 KiB · hit20 ms
git.upload-pack fetch
http.response.status_code=200
git.response.bytes=1759
git.response.cache=HIT
git.response.duration_ms=20
git.fetch.wants=b0727d32e434c42ed47f47a72f7a47e293fd24f4
git.fetch.haves.count=0
git.fetch.deepen=0
git.fetch.thin_pack=false
git.fetch.ofs_delta=true
git.protocol.version=2
git.pkt.frames=3
git.pkt.data=2
git.pkt.flush=1
git.pkt.delim=0
git.pkt.bytes=1759
git.pkt.payload.max=1738
git.sideband.band1.bytes=1737
git.sideband.band2.bytes=0
git.sideband.band3.bytes=0

Each row is one HTTP round trip ply made to the git server for this page, on one timeline. discover asks what the server speaks, ls-refs lists branch tips, fetch brings objects by id. A hit was served by Workers Cache. Tap a row for its wire details.

Remote
https://5ad2236b39de4c8bd8f6270ea63f3ea9.artifacts.cloudflare.net/git/public-v0/curl.git
Ref
refs/heads/master
Commit
31c911efe5652725e930f4d2e60c9060e5f6646d
cf-ray
a5e30f7fea71bdc9
Request
63e397f7…
Protocol
v2 · sha1
Agent
gitty/1.0
Filter
advertised
Fetch
shallow filter sideband-all
Capabilities
agent ls-refs fetch object-format