master
1#***************************************************************************
2# _ _ ____ _
3# Project ___| | | | _ \| |
4# / __| | | | |_) | |
5# | (__| |_| | _ <| |___
6# \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
13#
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
17#
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
20#
21# SPDX-License-Identifier: curl
22#
23###########################################################################
24# Find the Rustls library
25#
26# Input variables:
27#
28# - `RUSTLS_INCLUDE_DIR`: Absolute path to Rustls include directory.
29# - `RUSTLS_LIBRARY`: Absolute path to `rustls` library.
30#
31# Defines:
32#
33# - `RUSTLS_FOUND`: System has Rustls.
34# - `RUSTLS_VERSION`: Version of Rustls.
35# - `CURL::rustls`: Rustls library target.
37set(_rustls_pc_requires "rustls")
39if(CURL_USE_PKGCONFIG AND
40 NOT DEFINED RUSTLS_INCLUDE_DIR AND
41 NOT DEFINED RUSTLS_LIBRARY)
42 find_package(PkgConfig QUIET)
43 pkg_check_modules(_rustls ${_rustls_pc_requires})
44endif()
46if(_rustls_FOUND)
47 set(Rustls_FOUND TRUE)
48 set(RUSTLS_FOUND TRUE)
49 set(RUSTLS_VERSION ${_rustls_VERSION})
50 message(STATUS "Found Rustls (via pkg-config): ${_rustls_INCLUDE_DIRS} (found version \"${RUSTLS_VERSION}\")")
51else()
52 set(_rustls_pc_requires "") # Depend on pkg-config only when found via pkg-config
54 find_path(RUSTLS_INCLUDE_DIR NAMES "rustls.h")
55 find_library(RUSTLS_LIBRARY NAMES "rustls")
57 include(FindPackageHandleStandardArgs)
58 find_package_handle_standard_args(Rustls
59 REQUIRED_VARS
60 RUSTLS_INCLUDE_DIR
61 RUSTLS_LIBRARY
62 )
64 if(RUSTLS_FOUND)
65 set(_rustls_INCLUDE_DIRS ${RUSTLS_INCLUDE_DIR})
66 set(_rustls_LIBRARIES ${RUSTLS_LIBRARY})
67 endif()
69 mark_as_advanced(RUSTLS_INCLUDE_DIR RUSTLS_LIBRARY)
70endif()
72if(RUSTLS_FOUND)
73 if(APPLE)
74 find_library(SECURITY_FRAMEWORK NAMES "Security")
75 mark_as_advanced(SECURITY_FRAMEWORK)
76 if(NOT SECURITY_FRAMEWORK)
77 message(FATAL_ERROR "Security framework not found")
78 endif()
79 list(APPEND _rustls_LIBRARIES "-framework Security")
81 find_library(FOUNDATION_FRAMEWORK NAMES "Foundation")
82 mark_as_advanced(FOUNDATION_FRAMEWORK)
83 if(NOT FOUNDATION_FRAMEWORK)
84 message(FATAL_ERROR "Foundation framework not found")
85 endif()
86 list(APPEND _rustls_LIBRARIES "-framework Foundation")
87 elseif(NOT WIN32)
88 find_library(PTHREAD_LIBRARY NAMES "pthread")
89 if(PTHREAD_LIBRARY)
90 list(APPEND _rustls_LIBRARIES ${PTHREAD_LIBRARY})
91 endif()
92 mark_as_advanced(PTHREAD_LIBRARY)
94 find_library(DL_LIBRARY NAMES "dl")
95 if(DL_LIBRARY)
96 list(APPEND _rustls_LIBRARIES ${DL_LIBRARY})
97 endif()
98 mark_as_advanced(DL_LIBRARY)
100 find_library(MATH_LIBRARY NAMES "m")
101 if(MATH_LIBRARY)
102 list(APPEND _rustls_LIBRARIES ${MATH_LIBRARY})
103 endif()
104 mark_as_advanced(MATH_LIBRARY)
105 endif()
107 if(NOT TARGET CURL::rustls)
108 add_library(CURL::rustls INTERFACE IMPORTED)
109 set_target_properties(CURL::rustls PROPERTIES
110 INTERFACE_LIBCURL_PC_MODULES "${_rustls_pc_requires}"
111 INTERFACE_COMPILE_OPTIONS "${_rustls_CFLAGS}"
112 INTERFACE_INCLUDE_DIRECTORIES "${_rustls_INCLUDE_DIRS}"
113 INTERFACE_LINK_DIRECTORIES "${_rustls_LIBRARY_DIRS}"
114 INTERFACE_LINK_LIBRARIES "${_rustls_LIBRARIES}")
115 endif()
116endif()
Diagnostics4 git calls · 300 ms
CallStatusSizeTime0300 ms
discover200152 B2 ms
git.upload-pack discover http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=3 git.response.bytes=152 git.server.agent=gitty/1.0 git.server.object_format=sha1 git.server.caps=agent ls-refs fetch object-format git.server.fetch=shallow filter sideband-all git.protocol.version=2 git.pkt.frames=8 git.pkt.data=6 git.pkt.flush=2 git.pkt.delim=0 git.pkt.bytes=152 git.pkt.payload.max=34
ls-refs200149 B · hit2 ms
git.upload-pack ls-refs http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=ls-refs git.upstream.dur_ms=2 git.response.bytes=149 git.response.cache=HIT git.response.duration_ms=2 git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=149 git.pkt.payload.max=78 git.ls_refs.count=2 git.ls_refs.head=refs/heads/master
fetchblob:none · deepen 10200287 KiB · hit4 ms
git.upload-pack fetch http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=294 git.response.bytes=293470 git.response.cache=HIT git.response.duration_ms=4 git.fetch.filter=blob:none git.fetch.filter.requested=tree:0 git.fetch.filter.fallback=blob:none git.fetch.filter.learned=false git.fetch.wants=31c911efe5652725e930f4d2e60c9060e5f6646d git.fetch.haves.count=0 git.fetch.deepen=10 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=10 git.pkt.data=8 git.pkt.flush=1 git.pkt.delim=1 git.pkt.bytes=293470 git.pkt.payload.max=65516 git.sideband.band1.bytes=293354 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0 git.pack.objects=87 git.pack.bytes=293354 git.pack.ofs_delta=0 git.pack.ref_delta=1 git.pack.chain.max=1 git.pack.trailer=6a646bcda6740bab42e321b51998b52ea15146c0 git.pack.full=86Open pack map
fetch2001.4 KiB294 ms
git.upload-pack fetch http.response.status_code=200 git.response.bytes=1468 git.response.cache=MISS git.response.duration_ms=294 git.fetch.wants=1e07565189f727158ca7b1b3340e2455a6bd4759 git.fetch.haves.count=0 git.fetch.deepen=0 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=1468 git.pkt.payload.max=1447 git.sideband.band1.bytes=1446 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0
Each row is one HTTP round trip ply made to the git server for this page, on one timeline. discover asks what the server speaks, ls-refs lists branch tips, fetch brings objects by id. A hit was served by Workers Cache. Tap a row for its wire details.
- Remote
- https://5ad2236b39de4c8bd8f6270ea63f3ea9.artifacts.cloudflare.net/git/public-v0/curl.git
- Ref
- refs/heads/master
- Commit
- 31c911efe5652725e930f4d2e60c9060e5f6646d
- cf-ray
- a5e25b7aed98224d
- Request
- 0136a596…
- Protocol
- v2 · sha1
- Agent
- gitty/1.0
- Filter
- advertised
- Fetch
- shallow filter sideband-all
- Capabilities
- agent ls-refs fetch object-format