master
1#***************************************************************************
2# _ _ ____ _
3# Project ___| | | | _ \| |
4# / __| | | | |_) | |
5# | (__| |_| | _ <| |___
6# \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
13#
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
17#
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
20#
21# SPDX-License-Identifier: curl
22#
23###########################################################################
24# Find the quiche library
25#
26# Input variables:
27#
28# - `QUICHE_INCLUDE_DIR`: Absolute path to quiche include directory.
29# - `QUICHE_LIBRARY`: Absolute path to `quiche` library.
30#
31# Defines:
32#
33# - `QUICHE_FOUND`: System has quiche.
34# - `QUICHE_VERSION`: Version of quiche.
35# - `CURL::quiche`: quiche library target.
37set(_quiche_pc_requires "quiche")
39if(CURL_USE_PKGCONFIG AND
40 NOT DEFINED QUICHE_INCLUDE_DIR AND
41 NOT DEFINED QUICHE_LIBRARY)
42 find_package(PkgConfig QUIET)
43 pkg_check_modules(_quiche ${_quiche_pc_requires})
44endif()
46if(_quiche_FOUND)
47 set(Quiche_FOUND TRUE)
48 set(QUICHE_FOUND TRUE)
49 set(QUICHE_VERSION ${_quiche_VERSION})
50 message(STATUS "Found Quiche (via pkg-config): ${_quiche_INCLUDE_DIRS} (found version \"${QUICHE_VERSION}\")")
51else()
52 find_path(QUICHE_INCLUDE_DIR NAMES "quiche.h")
53 find_library(QUICHE_LIBRARY NAMES "quiche")
55 include(FindPackageHandleStandardArgs)
56 find_package_handle_standard_args(Quiche
57 REQUIRED_VARS
58 QUICHE_INCLUDE_DIR
59 QUICHE_LIBRARY
60 )
62 if(QUICHE_FOUND)
63 set(_quiche_INCLUDE_DIRS ${QUICHE_INCLUDE_DIR})
64 set(_quiche_LIBRARIES ${QUICHE_LIBRARY})
65 endif()
67 mark_as_advanced(QUICHE_INCLUDE_DIR QUICHE_LIBRARY)
68endif()
70if(QUICHE_FOUND)
71 if(NOT TARGET CURL::quiche)
72 add_library(CURL::quiche INTERFACE IMPORTED)
73 set_target_properties(CURL::quiche PROPERTIES
74 INTERFACE_LIBCURL_PC_MODULES "${_quiche_pc_requires}"
75 INTERFACE_COMPILE_OPTIONS "${_quiche_CFLAGS}"
76 INTERFACE_INCLUDE_DIRECTORIES "${_quiche_INCLUDE_DIRS}"
77 INTERFACE_LINK_DIRECTORIES "${_quiche_LIBRARY_DIRS}"
78 INTERFACE_LINK_LIBRARIES "${_quiche_LIBRARIES}")
79 endif()
80endif()
Diagnostics4 git calls · 160 ms
CallStatusSizeTime0160 ms
discover200152 B3 ms
git.upload-pack discover http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=2 git.response.bytes=152 git.server.agent=gitty/1.0 git.server.object_format=sha1 git.server.caps=agent ls-refs fetch object-format git.server.fetch=shallow filter sideband-all git.protocol.version=2 git.pkt.frames=8 git.pkt.data=6 git.pkt.flush=2 git.pkt.delim=0 git.pkt.bytes=152 git.pkt.payload.max=34
ls-refs200149 B · hit3 ms
git.upload-pack ls-refs http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=ls-refs git.upstream.dur_ms=3 git.response.bytes=149 git.response.cache=HIT git.response.duration_ms=3 git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=149 git.pkt.payload.max=78 git.ls_refs.count=2 git.ls_refs.head=refs/heads/master
fetchblob:none · deepen 10200287 KiB · hit3 ms
git.upload-pack fetch http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=154 git.response.bytes=293470 git.response.cache=HIT git.response.duration_ms=3 git.fetch.filter=blob:none git.fetch.filter.requested=tree:0 git.fetch.filter.fallback=blob:none git.fetch.filter.learned=false git.fetch.wants=31c911efe5652725e930f4d2e60c9060e5f6646d git.fetch.haves.count=0 git.fetch.deepen=10 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=10 git.pkt.data=8 git.pkt.flush=1 git.pkt.delim=1 git.pkt.bytes=293470 git.pkt.payload.max=65516 git.sideband.band1.bytes=293354 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0 git.pack.objects=87 git.pack.bytes=293354 git.pack.ofs_delta=0 git.pack.ref_delta=1 git.pack.chain.max=1 git.pack.trailer=6a646bcda6740bab42e321b51998b52ea15146c0 git.pack.full=86Open pack map
fetch2001.2 KiB154 ms
git.upload-pack fetch http.response.status_code=200 git.response.bytes=1200 git.response.cache=MISS git.response.duration_ms=154 git.fetch.wants=137679b5b358a605c7180f072ee2ad1bcc83f800 git.fetch.haves.count=0 git.fetch.deepen=0 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=1200 git.pkt.payload.max=1179 git.sideband.band1.bytes=1178 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0
Each row is one HTTP round trip ply made to the git server for this page, on one timeline. discover asks what the server speaks, ls-refs lists branch tips, fetch brings objects by id. A hit was served by Workers Cache. Tap a row for its wire details.
- Remote
- https://5ad2236b39de4c8bd8f6270ea63f3ea9.artifacts.cloudflare.net/git/public-v0/curl.git
- Ref
- refs/heads/master
- Commit
- 31c911efe5652725e930f4d2e60c9060e5f6646d
- cf-ray
- a5e2fe939c46f3c9
- Request
- a4766bb6…
- Protocol
- v2 · sha1
- Agent
- gitty/1.0
- Filter
- advertised
- Fetch
- shallow filter sideband-all
- Capabilities
- agent ls-refs fetch object-format