master
1#***************************************************************************
2# _ _ ____ _
3# Project ___| | | | _ \| |
4# / __| | | | |_) | |
5# | (__| |_| | _ <| |___
6# \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
13#
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
17#
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
20#
21# SPDX-License-Identifier: curl
22#
23###########################################################################
24# Find the nghttp3 library
25#
26# Input variables:
27#
28# - `NGHTTP3_INCLUDE_DIR`: Absolute path to nghttp3 include directory.
29# - `NGHTTP3_LIBRARY`: Absolute path to `nghttp3` library.
30# - `NGHTTP3_USE_STATIC_LIBS`: Configure for static nghttp3 libraries.
31#
32# Defines:
33#
34# - `NGHTTP3_FOUND`: System has nghttp3.
35# - `NGHTTP3_VERSION`: Version of nghttp3.
36# - `CURL::nghttp3`: nghttp3 library target.
38set(_nghttp3_pc_requires "libnghttp3")
40if(NOT DEFINED NGHTTP3_INCLUDE_DIR AND
41 NOT DEFINED NGHTTP3_LIBRARY)
42 if(CURL_USE_PKGCONFIG)
43 find_package(PkgConfig QUIET)
44 pkg_check_modules(_nghttp3 ${_nghttp3_pc_requires})
45 endif()
46 if(NOT _nghttp3_FOUND AND CURL_USE_CMAKECONFIG)
47 find_package(nghttp3 CONFIG QUIET)
48 endif()
49endif()
51if(_nghttp3_FOUND)
52 set(NGHTTP3_FOUND TRUE)
53 set(NGHTTP3_VERSION ${_nghttp3_VERSION})
54 if(NGHTTP3_USE_STATIC_LIBS)
55 set(_nghttp3_CFLAGS "${_nghttp3_STATIC_CFLAGS}")
56 set(_nghttp3_INCLUDE_DIRS "${_nghttp3_STATIC_INCLUDE_DIRS}")
57 set(_nghttp3_LIBRARY_DIRS "${_nghttp3_STATIC_LIBRARY_DIRS}")
58 set(_nghttp3_LIBRARIES "${_nghttp3_STATIC_LIBRARIES}")
59 endif()
60 message(STATUS "Found NGHTTP3 (via pkg-config): ${_nghttp3_INCLUDE_DIRS} (found version \"${NGHTTP3_VERSION}\")")
61elseif(nghttp3_CONFIG)
62 set(NGHTTP3_FOUND TRUE)
63 set(NGHTTP3_VERSION ${nghttp3_VERSION})
64 if(NGHTTP3_USE_STATIC_LIBS OR NOT TARGET nghttp3::nghttp3)
65 set(_nghttp3_LIBRARIES nghttp3::nghttp3_static)
66 else()
67 set(_nghttp3_LIBRARIES nghttp3::nghttp3)
68 endif()
69 message(STATUS "Found NGHTTP3 (via CMake Config): ${nghttp3_CONFIG} (found version \"${NGHTTP3_VERSION}\")")
70else()
71 find_path(NGHTTP3_INCLUDE_DIR NAMES "nghttp3/nghttp3.h")
72 if(NGHTTP3_USE_STATIC_LIBS)
73 set(_nghttp3_CFLAGS "-DNGHTTP3_STATICLIB")
74 find_library(NGHTTP3_LIBRARY NAMES "nghttp3_static" "nghttp3")
75 else()
76 find_library(NGHTTP3_LIBRARY NAMES "nghttp3")
77 endif()
79 unset(NGHTTP3_VERSION CACHE)
80 if(NGHTTP3_INCLUDE_DIR AND EXISTS "${NGHTTP3_INCLUDE_DIR}/nghttp3/version.h")
81 set(_version_regex "#[\t ]*define[\t ]+NGHTTP3_VERSION[\t ]+\"([^\"]*)\"")
82 file(STRINGS "${NGHTTP3_INCLUDE_DIR}/nghttp3/version.h" _version_str REGEX "${_version_regex}")
83 string(REGEX REPLACE "${_version_regex}" "\\1" _version_str "${_version_str}")
84 set(NGHTTP3_VERSION "${_version_str}")
85 unset(_version_regex)
86 unset(_version_str)
87 endif()
89 include(FindPackageHandleStandardArgs)
90 find_package_handle_standard_args(NGHTTP3
91 REQUIRED_VARS
92 NGHTTP3_INCLUDE_DIR
93 NGHTTP3_LIBRARY
94 VERSION_VAR
95 NGHTTP3_VERSION
96 )
98 if(NGHTTP3_FOUND)
99 set(_nghttp3_INCLUDE_DIRS ${NGHTTP3_INCLUDE_DIR})
100 set(_nghttp3_LIBRARIES ${NGHTTP3_LIBRARY})
101 endif()
103 mark_as_advanced(NGHTTP3_INCLUDE_DIR NGHTTP3_LIBRARY)
104endif()
106if(NGHTTP3_FOUND)
107 if(NOT TARGET CURL::nghttp3)
108 add_library(CURL::nghttp3 INTERFACE IMPORTED)
109 set_target_properties(CURL::nghttp3 PROPERTIES
110 INTERFACE_LIBCURL_PC_MODULES "${_nghttp3_pc_requires}"
111 INTERFACE_COMPILE_OPTIONS "${_nghttp3_CFLAGS}"
112 INTERFACE_INCLUDE_DIRECTORIES "${_nghttp3_INCLUDE_DIRS}"
113 INTERFACE_LINK_DIRECTORIES "${_nghttp3_LIBRARY_DIRS}"
114 INTERFACE_LINK_LIBRARIES "${_nghttp3_LIBRARIES}")
115 endif()
116endif()
Diagnostics4 git calls · 27 ms
CallStatusSizeTime027 ms
discover200152 B2 ms
git.upload-pack discover http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=ls-refs git.upstream.dur_ms=2 git.response.bytes=152 git.server.agent=gitty/1.0 git.server.object_format=sha1 git.server.caps=agent ls-refs fetch object-format git.server.fetch=shallow filter sideband-all git.protocol.version=2 git.pkt.frames=8 git.pkt.data=6 git.pkt.flush=2 git.pkt.delim=0 git.pkt.bytes=152 git.pkt.payload.max=34
ls-refs200149 B · hit3 ms
git.upload-pack ls-refs http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=ls-refs git.upstream.dur_ms=3 git.response.bytes=149 git.response.cache=HIT git.response.duration_ms=3 git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=149 git.pkt.payload.max=78 git.ls_refs.count=2 git.ls_refs.head=refs/heads/master
fetchblob:none · deepen 10200287 KiB · hit2 ms
git.upload-pack fetch http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=2 git.response.bytes=293470 git.response.cache=HIT git.response.duration_ms=2 git.fetch.filter=blob:none git.fetch.filter.requested=tree:0 git.fetch.filter.fallback=blob:none git.fetch.filter.learned=false git.fetch.wants=31c911efe5652725e930f4d2e60c9060e5f6646d git.fetch.haves.count=0 git.fetch.deepen=10 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=10 git.pkt.data=8 git.pkt.flush=1 git.pkt.delim=1 git.pkt.bytes=293470 git.pkt.payload.max=65516 git.sideband.band1.bytes=293354 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0 git.pack.objects=87 git.pack.bytes=293354 git.pack.ofs_delta=0 git.pack.ref_delta=1 git.pack.chain.max=1 git.pack.trailer=6a646bcda6740bab42e321b51998b52ea15146c0 git.pack.full=86Open pack map
fetch2001.6 KiB · hit22 ms
git.upload-pack fetch http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=22 git.response.bytes=1596 git.response.cache=HIT git.response.duration_ms=22 git.fetch.wants=ed671b7a492974c1c4bf19490f7380336c721bc6 git.fetch.haves.count=0 git.fetch.deepen=0 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=1596 git.pkt.payload.max=1575 git.sideband.band1.bytes=1574 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0
Each row is one HTTP round trip ply made to the git server for this page, on one timeline. discover asks what the server speaks, ls-refs lists branch tips, fetch brings objects by id. A hit was served by Workers Cache. Tap a row for its wire details.
- Remote
- https://5ad2236b39de4c8bd8f6270ea63f3ea9.artifacts.cloudflare.net/git/public-v0/curl.git
- Ref
- refs/heads/master
- Commit
- 31c911efe5652725e930f4d2e60c9060e5f6646d
- cf-ray
- a5e2c5dbde434afc
- Request
- df48fce3…
- Protocol
- v2 · sha1
- Agent
- gitty/1.0
- Filter
- advertised
- Fetch
- shallow filter sideband-all
- Capabilities
- agent ls-refs fetch object-format