master
1#***************************************************************************
2# _ _ ____ _
3# Project ___| | | | _ \| |
4# / __| | | | |_) | |
5# | (__| |_| | _ <| |___
6# \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
13#
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
17#
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
20#
21# SPDX-License-Identifier: curl
22#
23###########################################################################
24# Find the libssh2 library
25#
26# Input variables:
27#
28# - `LIBSSH2_INCLUDE_DIR`: Absolute path to libssh2 include directory.
29# - `LIBSSH2_LIBRARY`: Absolute path to `libssh2` library.
30# - `LIBSSH2_USE_STATIC_LIBS`: Configure for static libssh2 libraries.
31#
32# Defines:
33#
34# - `LIBSSH2_FOUND`: System has libssh2.
35# - `LIBSSH2_VERSION`: Version of libssh2.
36# - `CURL::libssh2`: libssh2 library target.
38set(_libssh2_pc_requires "libssh2")
40if(NOT DEFINED LIBSSH2_INCLUDE_DIR AND
41 NOT DEFINED LIBSSH2_LIBRARY)
42 if(CURL_USE_PKGCONFIG)
43 find_package(PkgConfig QUIET)
44 pkg_check_modules(_libssh2 ${_libssh2_pc_requires})
45 endif()
46 if(NOT _libssh2_FOUND AND CURL_USE_CMAKECONFIG)
47 find_package(libssh2 CONFIG QUIET)
48 endif()
49endif()
51if(_libssh2_FOUND AND _libssh2_INCLUDE_DIRS)
52 set(Libssh2_FOUND TRUE)
53 set(LIBSSH2_FOUND TRUE)
54 set(LIBSSH2_VERSION ${_libssh2_VERSION})
55 if(LIBSSH2_USE_STATIC_LIBS)
56 set(_libssh2_CFLAGS "${_libssh2_STATIC_CFLAGS}")
57 set(_libssh2_INCLUDE_DIRS "${_libssh2_STATIC_INCLUDE_DIRS}")
58 set(_libssh2_LIBRARY_DIRS "${_libssh2_STATIC_LIBRARY_DIRS}")
59 set(_libssh2_LIBRARIES "${_libssh2_STATIC_LIBRARIES}")
60 endif()
61 message(STATUS "Found Libssh2 (via pkg-config): ${_libssh2_INCLUDE_DIRS} (found version \"${LIBSSH2_VERSION}\")")
62elseif(libssh2_CONFIG)
63 set(Libssh2_FOUND TRUE)
64 set(LIBSSH2_FOUND TRUE)
65 set(LIBSSH2_VERSION ${libssh2_VERSION})
66 if(LIBSSH2_USE_STATIC_LIBS)
67 set(_libssh2_LIBRARIES libssh2::libssh2_static)
68 else()
69 set(_libssh2_LIBRARIES libssh2::libssh2)
70 endif()
71 message(STATUS "Found Libssh2 (via CMake Config): ${libssh2_CONFIG} (found version \"${LIBSSH2_VERSION}\")")
72else()
73 find_path(LIBSSH2_INCLUDE_DIR NAMES "libssh2.h")
74 if(LIBSSH2_USE_STATIC_LIBS)
75 find_library(LIBSSH2_LIBRARY NAMES "ssh2_static" "libssh2_static" "ssh2" "libssh2")
76 else()
77 find_library(LIBSSH2_LIBRARY NAMES "ssh2" "libssh2")
78 endif()
80 unset(LIBSSH2_VERSION CACHE)
81 if(LIBSSH2_INCLUDE_DIR AND EXISTS "${LIBSSH2_INCLUDE_DIR}/libssh2.h")
82 set(_version_regex "#[\t ]*define[\t ]+LIBSSH2_VERSION[\t ]+\"([^\"]*)\"")
83 file(STRINGS "${LIBSSH2_INCLUDE_DIR}/libssh2.h" _version_str REGEX "${_version_regex}")
84 string(REGEX REPLACE "${_version_regex}" "\\1" _version_str "${_version_str}")
85 set(LIBSSH2_VERSION "${_version_str}")
86 unset(_version_regex)
87 unset(_version_str)
88 endif()
90 include(FindPackageHandleStandardArgs)
91 find_package_handle_standard_args(Libssh2
92 REQUIRED_VARS
93 LIBSSH2_INCLUDE_DIR
94 LIBSSH2_LIBRARY
95 VERSION_VAR
96 LIBSSH2_VERSION
97 )
99 if(LIBSSH2_FOUND)
100 set(_libssh2_INCLUDE_DIRS ${LIBSSH2_INCLUDE_DIR})
101 set(_libssh2_LIBRARIES ${LIBSSH2_LIBRARY})
102 endif()
104 mark_as_advanced(LIBSSH2_INCLUDE_DIR LIBSSH2_LIBRARY)
105endif()
107if(LIBSSH2_FOUND)
108 if(NOT TARGET CURL::libssh2)
109 add_library(CURL::libssh2 INTERFACE IMPORTED)
110 set_target_properties(CURL::libssh2 PROPERTIES
111 INTERFACE_LIBCURL_PC_MODULES "${_libssh2_pc_requires}"
112 INTERFACE_COMPILE_OPTIONS "${_libssh2_CFLAGS}"
113 INTERFACE_INCLUDE_DIRECTORIES "${_libssh2_INCLUDE_DIRS}"
114 INTERFACE_LINK_DIRECTORIES "${_libssh2_LIBRARY_DIRS}"
115 INTERFACE_LINK_LIBRARIES "${_libssh2_LIBRARIES}")
116 endif()
117endif()
Diagnostics4 git calls · 35 ms
CallStatusSizeTime035 ms
discover200152 B2 ms
git.upload-pack discover http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=ls-refs git.upstream.dur_ms=2 git.response.bytes=152 git.server.agent=gitty/1.0 git.server.object_format=sha1 git.server.caps=agent ls-refs fetch object-format git.server.fetch=shallow filter sideband-all git.protocol.version=2 git.pkt.frames=8 git.pkt.data=6 git.pkt.flush=2 git.pkt.delim=0 git.pkt.bytes=152 git.pkt.payload.max=34
ls-refs200149 B3 ms
git.upload-pack ls-refs http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=ls-refs git.upstream.dur_ms=3 git.response.bytes=149 git.response.cache=UPDATING git.response.duration_ms=3 git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=149 git.pkt.payload.max=78 git.ls_refs.count=2 git.ls_refs.head=refs/heads/master
fetchblob:none · deepen 10200287 KiB · hit3 ms
git.upload-pack fetch http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=2 git.response.bytes=293470 git.response.cache=HIT git.response.duration_ms=3 git.fetch.filter=blob:none git.fetch.filter.requested=tree:0 git.fetch.filter.fallback=blob:none git.fetch.filter.learned=false git.fetch.wants=31c911efe5652725e930f4d2e60c9060e5f6646d git.fetch.haves.count=0 git.fetch.deepen=10 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=10 git.pkt.data=8 git.pkt.flush=1 git.pkt.delim=1 git.pkt.bytes=293470 git.pkt.payload.max=65516 git.sideband.band1.bytes=293354 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0 git.pack.objects=87 git.pack.bytes=293354 git.pack.ofs_delta=0 git.pack.ref_delta=1 git.pack.chain.max=1 git.pack.trailer=6a646bcda6740bab42e321b51998b52ea15146c0 git.pack.full=86Open pack map
fetch2001.5 KiB · hit29 ms
git.upload-pack fetch http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=29 git.response.bytes=1587 git.response.cache=HIT git.response.duration_ms=29 git.fetch.wants=22481d67ae8e40a74e4315cbdbb5109f6b6413d0 git.fetch.haves.count=0 git.fetch.deepen=0 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=1587 git.pkt.payload.max=1566 git.sideband.band1.bytes=1565 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0
Each row is one HTTP round trip ply made to the git server for this page, on one timeline. discover asks what the server speaks, ls-refs lists branch tips, fetch brings objects by id. A hit was served by Workers Cache. Tap a row for its wire details.
- Remote
- https://5ad2236b39de4c8bd8f6270ea63f3ea9.artifacts.cloudflare.net/git/public-v0/curl.git
- Ref
- refs/heads/master
- Commit
- 31c911efe5652725e930f4d2e60c9060e5f6646d
- cf-ray
- a5e29f6fa8fa1293
- Request
- 2970dc6d…
- Protocol
- v2 · sha1
- Agent
- gitty/1.0
- Filter
- advertised
- Fetch
- shallow filter sideband-all
- Capabilities
- agent ls-refs fetch object-format