Artifactspublic-v0

curl

master
ply4 git calls30 ms288 KiB3 cachedprotocol v2
92 lines3.2 KiBRaw
1#***************************************************************************
2# _ _ ____ _
3# Project ___| | | | _ \| |
4# / __| | | | |_) | |
5# | (__| |_| | _ <| |___
6# \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
21# SPDX-License-Identifier: curl
23###########################################################################
24# Find the GnuTLS library
26# Input variables:
28# - `GNUTLS_INCLUDE_DIR`: Absolute path to GnuTLS include directory.
29# - `GNUTLS_LIBRARY`: Absolute path to `gnutls` library.
31# Defines:
33# - `GNUTLS_FOUND`: System has GnuTLS.
34# - `GNUTLS_VERSION`: Version of GnuTLS.
35# - `CURL::gnutls`: GnuTLS library target.
37set(_gnutls_pc_requires "gnutls")
39if(CURL_USE_PKGCONFIG AND
40 NOT DEFINED GNUTLS_INCLUDE_DIR AND
41 NOT DEFINED GNUTLS_LIBRARY)
42 find_package(PkgConfig QUIET)
43 pkg_check_modules(_gnutls ${_gnutls_pc_requires})
44endif()
46if(_gnutls_FOUND)
47 set(GnuTLS_FOUND TRUE)
48 set(GNUTLS_FOUND TRUE)
49 set(GNUTLS_VERSION ${_gnutls_VERSION})
50 message(STATUS "Found GnuTLS (via pkg-config): ${_gnutls_INCLUDE_DIRS} (found version \"${GNUTLS_VERSION}\")")
51else()
52 find_path(GNUTLS_INCLUDE_DIR NAMES "gnutls/gnutls.h")
53 find_library(GNUTLS_LIBRARY NAMES "gnutls" "libgnutls")
55 unset(GNUTLS_VERSION CACHE)
56 if(GNUTLS_INCLUDE_DIR AND EXISTS "${GNUTLS_INCLUDE_DIR}/gnutls/gnutls.h")
57 set(_version_regex "#[\t ]*define[\t ]+GNUTLS_VERSION[\t ]+\"([^\"]*)\"")
58 file(STRINGS "${GNUTLS_INCLUDE_DIR}/gnutls/gnutls.h" _version_str REGEX "${_version_regex}")
59 string(REGEX REPLACE "${_version_regex}" "\\1" _version_str "${_version_str}")
60 set(GNUTLS_VERSION "${_version_str}")
61 unset(_version_regex)
62 unset(_version_str)
63 endif()
65 include(FindPackageHandleStandardArgs)
66 find_package_handle_standard_args(GnuTLS
67 REQUIRED_VARS
68 GNUTLS_INCLUDE_DIR
69 GNUTLS_LIBRARY
70 VERSION_VAR
71 GNUTLS_VERSION
72 )
74 if(GNUTLS_FOUND)
75 set(_gnutls_INCLUDE_DIRS ${GNUTLS_INCLUDE_DIR})
76 set(_gnutls_LIBRARIES ${GNUTLS_LIBRARY})
77 endif()
79 mark_as_advanced(GNUTLS_INCLUDE_DIR GNUTLS_LIBRARY)
80endif()
82if(GNUTLS_FOUND)
83 if(NOT TARGET CURL::gnutls)
84 add_library(CURL::gnutls INTERFACE IMPORTED)
85 set_target_properties(CURL::gnutls PROPERTIES
86 INTERFACE_LIBCURL_PC_MODULES "${_gnutls_pc_requires}"
87 INTERFACE_COMPILE_OPTIONS "${_gnutls_CFLAGS}"
88 INTERFACE_INCLUDE_DIRECTORIES "${_gnutls_INCLUDE_DIRS}"
89 INTERFACE_LINK_DIRECTORIES "${_gnutls_LIBRARY_DIRS}"
90 INTERFACE_LINK_LIBRARIES "${_gnutls_LIBRARIES}")
91 endif()
92endif()
Diagnostics4 git calls · 30 ms
CallStatusSizeTime030 ms
discover200152 B2 ms
git.upload-pack discover
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=ls-refs
git.upstream.dur_ms=2
git.response.bytes=152
git.server.agent=gitty/1.0
git.server.object_format=sha1
git.server.caps=agent ls-refs fetch object-format
git.server.fetch=shallow filter sideband-all
git.protocol.version=2
git.pkt.frames=8
git.pkt.data=6
git.pkt.flush=2
git.pkt.delim=0
git.pkt.bytes=152
git.pkt.payload.max=34
ls-refs200149 B · hit2 ms
git.upload-pack ls-refs
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=ls-refs
git.upstream.dur_ms=2
git.response.bytes=149
git.response.cache=HIT
git.response.duration_ms=2
git.protocol.version=2
git.pkt.frames=3
git.pkt.data=2
git.pkt.flush=1
git.pkt.delim=0
git.pkt.bytes=149
git.pkt.payload.max=78
git.ls_refs.count=2
git.ls_refs.head=refs/heads/master
fetchblob:none · deepen 10200287 KiB · hit3 ms
git.upload-pack fetch
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=fetch
git.upstream.dur_ms=3
git.response.bytes=293470
git.response.cache=HIT
git.response.duration_ms=3
git.fetch.filter=blob:none
git.fetch.filter.requested=tree:0
git.fetch.filter.fallback=blob:none
git.fetch.filter.learned=false
git.fetch.wants=31c911efe5652725e930f4d2e60c9060e5f6646d
git.fetch.haves.count=0
git.fetch.deepen=10
git.fetch.thin_pack=false
git.fetch.ofs_delta=true
git.protocol.version=2
git.pkt.frames=10
git.pkt.data=8
git.pkt.flush=1
git.pkt.delim=1
git.pkt.bytes=293470
git.pkt.payload.max=65516
git.sideband.band1.bytes=293354
git.sideband.band2.bytes=0
git.sideband.band3.bytes=0
git.pack.objects=87
git.pack.bytes=293354
git.pack.ofs_delta=0
git.pack.ref_delta=1
git.pack.chain.max=1
git.pack.trailer=6a646bcda6740bab42e321b51998b52ea15146c0
git.pack.full=86
Open pack map
fetch2001.3 KiB · hit25 ms
git.upload-pack fetch
http.response.status_code=200
git.upstream.cf_ray=-
git.upstream.phase=fetch
git.upstream.dur_ms=25
git.response.bytes=1379
git.response.cache=HIT
git.response.duration_ms=25
git.fetch.wants=7f5b227dc2e6b6c1c455d8fcf9870180b1274430
git.fetch.haves.count=0
git.fetch.deepen=0
git.fetch.thin_pack=false
git.fetch.ofs_delta=true
git.protocol.version=2
git.pkt.frames=3
git.pkt.data=2
git.pkt.flush=1
git.pkt.delim=0
git.pkt.bytes=1379
git.pkt.payload.max=1358
git.sideband.band1.bytes=1357
git.sideband.band2.bytes=0
git.sideband.band3.bytes=0

Each row is one HTTP round trip ply made to the git server for this page, on one timeline. discover asks what the server speaks, ls-refs lists branch tips, fetch brings objects by id. A hit was served by Workers Cache. Tap a row for its wire details.

Remote
https://5ad2236b39de4c8bd8f6270ea63f3ea9.artifacts.cloudflare.net/git/public-v0/curl.git
Ref
refs/heads/master
Commit
31c911efe5652725e930f4d2e60c9060e5f6646d
cf-ray
a5e2e86e1a49ecfa
Request
83ddfc09…
Protocol
v2 · sha1
Agent
gitty/1.0
Filter
advertised
Fetch
shallow filter sideband-all
Capabilities
agent ls-refs fetch object-format