master
1#***************************************************************************
2# _ _ ____ _
3# Project ___| | | | _ \| |
4# / __| | | | |_) | |
5# | (__| |_| | _ <| |___
6# \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
13#
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
17#
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
20#
21# SPDX-License-Identifier: curl
22#
23###########################################################################
24# Find the GSS Kerberos library
25#
26# This module accepts optional COMPONENTS to control the GSS library flavor:
27#
28# - Apple
29#
30# Input variables:
31#
32# - `GSS_ROOT_DIR`: Absolute path to the root installation of GSS. (also supported as environment)
33#
34# Defines:
35#
36# - `GSS_FOUND`: System has GSS.
37# - `GSS_VERSION`: Version of GSS.
38# - `CURL::gss`: GSS library target.
39# - `INTERFACE_CURL_GSS_FLAVOR`: Custom property. "Apple", "GNU" or "MIT" if detected.
41set(_gnu_modname "gss")
42set(_mit_modname "mit-krb5-gssapi")
44include(CheckIncludeFile)
45include(CheckIncludeFiles)
46include(CheckTypeSize)
48set(_gss_root_hints "${GSS_ROOT_DIR}" "$ENV{GSS_ROOT_DIR}")
50set(_gss_CFLAGS "")
51set(_gss_LIBRARY_DIRS "")
53if(NOT APPLE AND GSS_FIND_COMPONENTS STREQUAL "Apple")
54 set(GSS_FIND_COMPONENTS "")
55endif()
57# Try to find library using system pkg-config if user did not specify root dir
58if(NOT GSS_ROOT_DIR AND NOT "$ENV{GSS_ROOT_DIR}" AND NOT GSS_FIND_COMPONENTS STREQUAL "Apple")
59 if(CURL_USE_PKGCONFIG)
60 find_package(PkgConfig QUIET)
61 pkg_search_module(_gss ${_mit_modname} ${_gnu_modname})
62 list(APPEND _gss_root_hints "${_gss_PREFIX}")
63 set(_gss_version "${_gss_VERSION}")
64 endif()
65 if(WIN32)
66 list(APPEND _gss_root_hints "[HKEY_LOCAL_MACHINE\\SOFTWARE\\MIT\\Kerberos;InstallDir]")
67 endif()
68endif()
70if(NOT _gss_FOUND) # Not found by pkg-config. Let us take more traditional approach.
71 if(GSS_FIND_COMPONENTS STREQUAL "Apple")
72 find_path(_gss_INCLUDE_DIRS NAMES "GSS/gssapi.h" PATH_SUFFIXES "include")
73 find_library(_gss_LIBRARIES NAMES "GSS")
75 if(_gss_INCLUDE_DIRS AND _gss_LIBRARIES)
76 message(STATUS "Found AppleGSS: ${_gss_INCLUDE_DIRS}")
77 set(_gss_flavor "Apple")
78 endif()
79 else()
80 find_file(_gss_configure_script NAMES "krb5-config" PATH_SUFFIXES "bin" HINTS ${_gss_root_hints}
81 NO_CMAKE_PATH NO_CMAKE_ENVIRONMENT_PATH)
82 # If not found in user-supplied directories, maybe system knows better
83 find_file(_gss_configure_script NAMES "krb5-config" PATH_SUFFIXES "bin")
85 if(_gss_configure_script)
87 set(_gss_INCLUDE_DIRS "")
88 set(_gss_LIBRARIES "")
90 execute_process(COMMAND ${_gss_configure_script} "--cflags" "gssapi"
91 OUTPUT_VARIABLE _gss_cflags_raw
92 RESULT_VARIABLE _gss_configure_failed
93 OUTPUT_STRIP_TRAILING_WHITESPACE)
94 message(STATUS "FindGSS krb5-config --cflags: ${_gss_cflags_raw}")
96 if(NOT _gss_configure_failed) # 0 means success
97 # Should also work in an odd case when multiple directories are given.
98 string(STRIP "${_gss_cflags_raw}" _gss_cflags_raw)
99 string(REGEX REPLACE " +-(I)" ";-\\1" _gss_cflags_raw "${_gss_cflags_raw}")
100 string(REGEX REPLACE " +-([^I][^ \\t;]*)" ";-\\1" _gss_cflags_raw "${_gss_cflags_raw}")
102 foreach(_flag IN LISTS _gss_cflags_raw)
103 if(_flag MATCHES "^-I")
104 string(REGEX REPLACE "^-I" "" _flag "${_flag}")
105 list(APPEND _gss_INCLUDE_DIRS "${_flag}")
106 else()
107 list(APPEND _gss_CFLAGS "${_flag}")
108 endif()
109 endforeach()
110 endif()
112 execute_process(COMMAND ${_gss_configure_script} "--libs" "gssapi"
113 OUTPUT_VARIABLE _gss_lib_flags
114 RESULT_VARIABLE _gss_configure_failed
115 OUTPUT_STRIP_TRAILING_WHITESPACE)
116 message(STATUS "FindGSS krb5-config --libs: ${_gss_lib_flags}")
118 if(NOT _gss_configure_failed) # 0 means success
119 # This script gives us libraries and link directories.
120 string(STRIP "${_gss_lib_flags}" _gss_lib_flags)
121 string(REGEX REPLACE " +-(L|l)" ";-\\1" _gss_lib_flags "${_gss_lib_flags}")
122 string(REGEX REPLACE " +-([^Ll][^ \\t;]*)" ";-\\1" _gss_lib_flags "${_gss_lib_flags}")
124 foreach(_flag IN LISTS _gss_lib_flags)
125 if(_flag MATCHES "^-l")
126 string(REGEX REPLACE "^-l" "" _flag "${_flag}")
127 list(APPEND _gss_LIBRARIES "${_flag}")
128 elseif(_flag MATCHES "^-L")
129 string(REGEX REPLACE "^-L" "" _flag "${_flag}")
130 list(APPEND _gss_LIBRARY_DIRS "${_flag}")
131 endif()
132 endforeach()
133 endif()
135 execute_process(COMMAND ${_gss_configure_script} "--version"
136 OUTPUT_VARIABLE _gss_version
137 RESULT_VARIABLE _gss_configure_failed
138 OUTPUT_STRIP_TRAILING_WHITESPACE)
140 # Older versions may not have the "--version" parameter. In this case we do not care.
141 if(_gss_configure_failed)
142 set(_gss_version 0)
143 else()
144 # Strip prefix string to leave the version number only
145 string(REPLACE "Kerberos 5 release " "" _gss_version "${_gss_version}")
146 endif()
148 execute_process(COMMAND ${_gss_configure_script} "--vendor"
149 OUTPUT_VARIABLE _gss_vendor
150 RESULT_VARIABLE _gss_configure_failed
151 OUTPUT_STRIP_TRAILING_WHITESPACE)
153 # Older versions may not have the "--vendor" parameter. In this case we do not care.
154 if(NOT _gss_configure_failed AND NOT _gss_vendor MATCHES "Heimdal|heimdal")
155 set(_gss_flavor "MIT") # assume a default, should not really matter
156 endif()
158 else() # Either there is no config script or we are on a platform that does not provide one (Windows?)
160 find_path(_gss_INCLUDE_DIRS NAMES "gssapi/gssapi.h" HINTS ${_gss_root_hints} PATH_SUFFIXES "include" "inc")
162 if(_gss_INCLUDE_DIRS) # We have found something
163 set(_gss_libdir_suffixes "")
165 cmake_push_check_state()
166 list(APPEND CMAKE_REQUIRED_INCLUDES "${_gss_INCLUDE_DIRS}")
167 check_include_files("gssapi/gssapi_generic.h;gssapi/gssapi_krb5.h" _gss_have_mit_headers)
168 cmake_pop_check_state()
170 if(_gss_have_mit_headers)
171 set(_gss_flavor "MIT")
172 if(WIN32)
173 if(CMAKE_SIZEOF_VOID_P EQUAL 8)
174 list(APPEND _gss_libdir_suffixes "lib/AMD64")
175 set(_gss_libname "gssapi64")
176 else()
177 list(APPEND _gss_libdir_suffixes "lib/i386")
178 set(_gss_libname "gssapi32")
179 endif()
180 else()
181 list(APPEND _gss_libdir_suffixes "lib" "lib64") # those suffixes are not checked for HINTS
182 set(_gss_libname "gssapi_krb5")
183 endif()
184 endif()
185 else()
186 find_path(_gss_INCLUDE_DIRS NAMES "gss.h" HINTS ${_gss_root_hints} PATH_SUFFIXES "include")
188 if(_gss_INCLUDE_DIRS)
189 set(_gss_flavor "GNU")
190 set(_gss_pc_requires ${_gnu_modname})
191 set(_gss_libname "gss")
192 endif()
193 endif()
195 # If we have headers, look up libraries
196 if(_gss_flavor)
197 set(_gss_libdir_hints ${_gss_root_hints})
198 if(CMAKE_VERSION VERSION_GREATER_EQUAL 3.20)
199 cmake_path(GET _gss_INCLUDE_DIRS PARENT_PATH _gss_calculated_potential_root)
200 else()
201 get_filename_component(_gss_calculated_potential_root "${_gss_INCLUDE_DIRS}" DIRECTORY)
202 endif()
203 list(APPEND _gss_libdir_hints ${_gss_calculated_potential_root})
205 find_library(_gss_LIBRARIES NAMES ${_gss_libname} HINTS ${_gss_libdir_hints} PATH_SUFFIXES ${_gss_libdir_suffixes})
206 endif()
207 endif()
208 endif()
209 if(NOT _gss_flavor)
210 message(FATAL_ERROR "MIT, GNU or Apple GSS is required")
211 endif()
212else()
213 if(_gss_MODULE_NAME STREQUAL _gnu_modname)
214 set(_gss_flavor "GNU")
215 set(_gss_pc_requires ${_gnu_modname})
216 elseif(_gss_MODULE_NAME STREQUAL _mit_modname)
217 set(_gss_flavor "MIT")
218 set(_gss_pc_requires ${_mit_modname})
219 else()
220 message(FATAL_ERROR "MIT, GNU or Apple GSS is required")
221 endif()
222 message(STATUS "Found GSS/${_gss_flavor} (via pkg-config): ${_gss_INCLUDE_DIRS} (found version \"${_gss_version}\")")
223endif()
225set(GSS_VERSION ${_gss_version})
227if(NOT GSS_VERSION)
228 if(_gss_flavor STREQUAL "MIT" AND WIN32)
229 if(CMAKE_VERSION VERSION_GREATER_EQUAL 3.24)
230 cmake_host_system_information(RESULT _mit_version QUERY WINDOWS_REGISTRY
231 "HKLM/SOFTWARE/MIT/Kerberos/SDK/CurrentVersion" VALUE "VersionString")
232 else()
233 get_filename_component(_mit_version
234 "[HKEY_LOCAL_MACHINE\\SOFTWARE\\MIT\\Kerberos\\SDK\\CurrentVersion;VersionString]" NAME CACHE)
235 endif()
236 set(GSS_VERSION "${_mit_version}")
237 elseif(_gss_flavor STREQUAL "GNU")
238 if(_gss_INCLUDE_DIRS AND EXISTS "${_gss_INCLUDE_DIRS}/gss.h")
239 set(_version_regex "#[\t ]*define[\t ]+GSS_VERSION[\t ]+\"([^\"]*)\"")
240 file(STRINGS "${_gss_INCLUDE_DIRS}/gss.h" _version_str REGEX "${_version_regex}")
241 string(REGEX REPLACE "${_version_regex}" "\\1" _version_str "${_version_str}")
242 set(GSS_VERSION "${_version_str}")
243 unset(_version_regex)
244 unset(_version_str)
245 endif()
246 endif()
247endif()
249include(FindPackageHandleStandardArgs)
250find_package_handle_standard_args(GSS
251 REQUIRED_VARS
252 _gss_flavor
253 _gss_LIBRARIES
254 VERSION_VAR
255 GSS_VERSION
256 FAIL_MESSAGE
257 "Could NOT find GSS, try to set the absolute path to GSS installation root directory in the environment variable GSS_ROOT_DIR"
258)
260mark_as_advanced(
261 _gss_CFLAGS
262 _gss_FOUND
263 _gss_INCLUDE_DIRS
264 _gss_LIBRARIES
265 _gss_LIBRARY_DIRS
266 _gss_MODULE_NAME
267 _gss_PREFIX
268 _gss_version
269)
271if(GSS_FOUND)
272 if(NOT TARGET CURL::gss)
273 add_library(CURL::gss INTERFACE IMPORTED)
274 set_target_properties(CURL::gss PROPERTIES
275 INTERFACE_CURL_GSS_FLAVOR "${_gss_flavor}"
276 INTERFACE_LIBCURL_PC_MODULES "${_gss_pc_requires}"
277 INTERFACE_COMPILE_OPTIONS "${_gss_CFLAGS}"
278 INTERFACE_INCLUDE_DIRECTORIES "${_gss_INCLUDE_DIRS}"
279 INTERFACE_LINK_DIRECTORIES "${_gss_LIBRARY_DIRS}"
280 INTERFACE_LINK_LIBRARIES "${_gss_LIBRARIES}")
281 endif()
282endif()
Diagnostics4 git calls · 60 ms
CallStatusSizeTime060 ms
discover200152 B3 ms
git.upload-pack discover http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=2 git.response.bytes=152 git.server.agent=gitty/1.0 git.server.object_format=sha1 git.server.caps=agent ls-refs fetch object-format git.server.fetch=shallow filter sideband-all git.protocol.version=2 git.pkt.frames=8 git.pkt.data=6 git.pkt.flush=2 git.pkt.delim=0 git.pkt.bytes=152 git.pkt.payload.max=34
ls-refs200149 B · hit2 ms
git.upload-pack ls-refs http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=ls-refs git.upstream.dur_ms=2 git.response.bytes=149 git.response.cache=HIT git.response.duration_ms=2 git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=149 git.pkt.payload.max=78 git.ls_refs.count=2 git.ls_refs.head=refs/heads/master
fetchblob:none · deepen 10200287 KiB · hit2 ms
git.upload-pack fetch http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=55 git.response.bytes=293470 git.response.cache=HIT git.response.duration_ms=2 git.fetch.filter=blob:none git.fetch.filter.requested=tree:0 git.fetch.filter.fallback=blob:none git.fetch.filter.learned=false git.fetch.wants=31c911efe5652725e930f4d2e60c9060e5f6646d git.fetch.haves.count=0 git.fetch.deepen=10 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=10 git.pkt.data=8 git.pkt.flush=1 git.pkt.delim=1 git.pkt.bytes=293470 git.pkt.payload.max=65516 git.sideband.band1.bytes=293354 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0 git.pack.objects=87 git.pack.bytes=293354 git.pack.ofs_delta=0 git.pack.ref_delta=1 git.pack.chain.max=1 git.pack.trailer=6a646bcda6740bab42e321b51998b52ea15146c0 git.pack.full=86Open pack map
fetch2003.5 KiB · hit55 ms
git.upload-pack fetch http.response.status_code=200 git.response.bytes=3572 git.response.cache=HIT git.response.duration_ms=55 git.fetch.wants=46d768699de6b6d22dbdaa1e436fd572f1251e7a git.fetch.haves.count=0 git.fetch.deepen=0 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=3572 git.pkt.payload.max=3551 git.sideband.band1.bytes=3550 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0
Each row is one HTTP round trip ply made to the git server for this page, on one timeline. discover asks what the server speaks, ls-refs lists branch tips, fetch brings objects by id. A hit was served by Workers Cache. Tap a row for its wire details.
- Remote
- https://5ad2236b39de4c8bd8f6270ea63f3ea9.artifacts.cloudflare.net/git/public-v0/curl.git
- Ref
- refs/heads/master
- Commit
- 31c911efe5652725e930f4d2e60c9060e5f6646d
- cf-ray
- a5e2e58eca562947
- Request
- cc0a4ff8…
- Protocol
- v2 · sha1
- Agent
- gitty/1.0
- Filter
- advertised
- Fetch
- shallow filter sideband-all
- Capabilities
- agent ls-refs fetch object-format