master
1#***************************************************************************
2# _ _ ____ _
3# Project ___| | | | _ \| |
4# / __| | | | |_) | |
5# | (__| |_| | _ <| |___
6# \___|\___/|_| \_\_____|
7#
8# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
9#
10# This software is licensed as described in the file COPYING, which
11# you should have received as part of this distribution. The terms
12# are also available at https://curl.se/docs/copyright.html.
13#
14# You may opt to use, copy, modify, merge, publish, distribute and/or sell
15# copies of the Software, and permit persons to whom the Software is
16# furnished to do so, under the terms of the COPYING file.
17#
18# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
19# KIND, either express or implied.
20#
21# SPDX-License-Identifier: curl
22#
23###########################################################################
24# Find the brotli library
25#
26# Input variables:
27#
28# - `BROTLI_INCLUDE_DIR`: Absolute path to brotli include directory.
29# - `BROTLICOMMON_LIBRARY`: Absolute path to `brotlicommon` library.
30# - `BROTLIDEC_LIBRARY`: Absolute path to `brotlidec` library.
31# - `BROTLI_USE_STATIC_LIBS`: Configure for static brotli libraries.
32#
33# Defines:
34#
35# - `BROTLI_FOUND`: System has brotli.
36# - `BROTLI_VERSION`: Version of brotli.
37# - `CURL::brotli`: brotli library target.
39set(_brotli_pc_requires "libbrotlidec" "libbrotlicommon") # order is significant: brotlidec then brotlicommon
41if(CURL_USE_PKGCONFIG AND
42 NOT DEFINED BROTLI_INCLUDE_DIR AND
43 NOT DEFINED BROTLICOMMON_LIBRARY AND
44 NOT DEFINED BROTLIDEC_LIBRARY)
45 find_package(PkgConfig QUIET)
46 pkg_check_modules(_brotli ${_brotli_pc_requires})
47endif()
49if(_brotli_FOUND)
50 set(Brotli_FOUND TRUE)
51 set(BROTLI_FOUND TRUE)
52 set(BROTLI_VERSION ${_brotli_libbrotlicommon_VERSION})
53 if(BROTLI_USE_STATIC_LIBS)
54 set(_brotli_CFLAGS "${_brotli_STATIC_CFLAGS}")
55 set(_brotli_INCLUDE_DIRS "${_brotli_STATIC_INCLUDE_DIRS}")
56 set(_brotli_LIBRARY_DIRS "${_brotli_STATIC_LIBRARY_DIRS}")
57 set(_brotli_LIBRARIES "${_brotli_STATIC_LIBRARIES}")
58 endif()
59 message(STATUS "Found Brotli (via pkg-config): ${_brotli_INCLUDE_DIRS} (found version \"${BROTLI_VERSION}\")")
60else()
61 find_path(BROTLI_INCLUDE_DIR "brotli/decode.h")
62 if(BROTLI_USE_STATIC_LIBS)
63 find_library(BROTLICOMMON_LIBRARY NAMES "brotlicommon-static" "brotlicommon")
64 find_library(BROTLIDEC_LIBRARY NAMES "brotlidec-static" "brotlidec")
65 else()
66 find_library(BROTLICOMMON_LIBRARY NAMES "brotlicommon")
67 find_library(BROTLIDEC_LIBRARY NAMES "brotlidec")
68 endif()
70 include(FindPackageHandleStandardArgs)
71 find_package_handle_standard_args(Brotli
72 REQUIRED_VARS
73 BROTLI_INCLUDE_DIR
74 BROTLIDEC_LIBRARY
75 BROTLICOMMON_LIBRARY
76 )
78 if(BROTLI_FOUND)
79 set(_brotli_INCLUDE_DIRS ${BROTLI_INCLUDE_DIR})
80 set(_brotli_LIBRARIES ${BROTLIDEC_LIBRARY} ${BROTLICOMMON_LIBRARY})
81 endif()
83 mark_as_advanced(BROTLI_INCLUDE_DIR BROTLIDEC_LIBRARY BROTLICOMMON_LIBRARY)
84endif()
86if(BROTLI_FOUND)
87 if(NOT TARGET CURL::brotli)
88 add_library(CURL::brotli INTERFACE IMPORTED)
89 set_target_properties(CURL::brotli PROPERTIES
90 INTERFACE_LIBCURL_PC_MODULES "${_brotli_pc_requires}"
91 INTERFACE_COMPILE_OPTIONS "${_brotli_CFLAGS}"
92 INTERFACE_INCLUDE_DIRECTORIES "${_brotli_INCLUDE_DIRS}"
93 INTERFACE_LINK_DIRECTORIES "${_brotli_LIBRARY_DIRS}"
94 INTERFACE_LINK_LIBRARIES "${_brotli_LIBRARIES}")
95 endif()
96endif()
Diagnostics4 git calls · 29 ms
CallStatusSizeTime029 ms
discover200152 B4 ms
git.upload-pack discover http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=2 git.response.bytes=152 git.server.agent=gitty/1.0 git.server.object_format=sha1 git.server.caps=agent ls-refs fetch object-format git.server.fetch=shallow filter sideband-all git.protocol.version=2 git.pkt.frames=8 git.pkt.data=6 git.pkt.flush=2 git.pkt.delim=0 git.pkt.bytes=152 git.pkt.payload.max=34
ls-refs200149 B · hit3 ms
git.upload-pack ls-refs http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=ls-refs git.upstream.dur_ms=3 git.response.bytes=149 git.response.cache=HIT git.response.duration_ms=3 git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=149 git.pkt.payload.max=78 git.ls_refs.count=2 git.ls_refs.head=refs/heads/master
fetchblob:none · deepen 10200287 KiB · hit2 ms
git.upload-pack fetch http.response.status_code=200 git.upstream.cf_ray=- git.upstream.phase=fetch git.upstream.dur_ms=23 git.response.bytes=293470 git.response.cache=HIT git.response.duration_ms=2 git.fetch.filter=blob:none git.fetch.filter.requested=tree:0 git.fetch.filter.fallback=blob:none git.fetch.filter.learned=false git.fetch.wants=31c911efe5652725e930f4d2e60c9060e5f6646d git.fetch.haves.count=0 git.fetch.deepen=10 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=10 git.pkt.data=8 git.pkt.flush=1 git.pkt.delim=1 git.pkt.bytes=293470 git.pkt.payload.max=65516 git.sideband.band1.bytes=293354 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0 git.pack.objects=87 git.pack.bytes=293354 git.pack.ofs_delta=0 git.pack.ref_delta=1 git.pack.chain.max=1 git.pack.trailer=6a646bcda6740bab42e321b51998b52ea15146c0 git.pack.full=86Open pack map
fetch2001.4 KiB · hit23 ms
git.upload-pack fetch http.response.status_code=200 git.response.bytes=1419 git.response.cache=HIT git.response.duration_ms=23 git.fetch.wants=bd3363cce0ab68a30b9ea056a4dd615f3368ca24 git.fetch.haves.count=0 git.fetch.deepen=0 git.fetch.thin_pack=false git.fetch.ofs_delta=true git.protocol.version=2 git.pkt.frames=3 git.pkt.data=2 git.pkt.flush=1 git.pkt.delim=0 git.pkt.bytes=1419 git.pkt.payload.max=1398 git.sideband.band1.bytes=1397 git.sideband.band2.bytes=0 git.sideband.band3.bytes=0
Each row is one HTTP round trip ply made to the git server for this page, on one timeline. discover asks what the server speaks, ls-refs lists branch tips, fetch brings objects by id. A hit was served by Workers Cache. Tap a row for its wire details.
- Remote
- https://5ad2236b39de4c8bd8f6270ea63f3ea9.artifacts.cloudflare.net/git/public-v0/curl.git
- Ref
- refs/heads/master
- Commit
- 31c911efe5652725e930f4d2e60c9060e5f6646d
- cf-ray
- a5e31b6d9d1b8682
- Request
- e3a5020f…
- Protocol
- v2 · sha1
- Agent
- gitty/1.0
- Filter
- advertised
- Fetch
- shallow filter sideband-all
- Capabilities
- agent ls-refs fetch object-format